Documentatie/Calc-functies/TYPE.FOUT

From The Document Foundation Wiki
Jump to navigation Jump to search
This page is a translated version of the page Documentation/Calc Functions/ERROR.TYPE and the translation is 100% complete.
Other languages:
English • ‎Nederlands



Functienaam:

TYPE.FOUT

Categorie:

Werkblad

Samenvatting:

Genereert een codenummer dat het type fout in het argument vertegenwoordigt.

Syntaxis:

TYPE.FOUT(Uitdrukking)

Retourneert:

Retourneert een positief geheel getal in het bereik [1, 7] als het argument één van de zeven gedefinieerde foutcondities vertegenwoordigt. Retourneert de fout #N/B als het argument geen fout vertegenwoordigt of een fout vertegenwoordigt buiten de set van zeven veelvoorkomende fouten die zijn toegewezen aan fouttypen.

De toewijzing van de fouten van Calc aan de zeven fouttypen wordt weergegeven in de volgende tabel.

Toewijzing fouten aan fouttypen
Fout Retourneert
Fout:511 (ontbrekende variabele) 1
#DIV/0! 2
#WAARDE! 3
#VERW! 4
#NAAM? 5
#GETAL! 6
#N/B 7
Geen fout of fout die niet wordt weergegeven in bovenstaande lijst #N/B

Argumenten:

Uitdrukking is een uitdrukking of een verwijzing naar een cel die een uitdrukking bevat, waarvan het fouttype moet worden bepaald.

Aanvullende details:

  • De waarde van het gehele getal van het fouttype kan u helpen om op maat gemaakte foutberichten te genereren die nuttig zijn voor de beoogde gebruikers van uw werkblad.
  • Als de functie TYPE.FOUT wordt gebruikt als voorwaarde voor een functieaanroep ALS en de aanroep TYPE.FOUT #N/B retourneert, retourneert de functie ALS ook #N/B. Gebruik ISFOUT om dit te voorkomen, zoals weergegeven in het laatste voorbeeld hieronder.

Voorbeelden:

Formule Beschrijving Retourneert
=TYPE.FOUT(E1) waarbij cel E1 de formule =WORTEL() bevat. Aangezien de functie WORTEL een enkel numeriek argument verwacht, bevat cel E1 de fout Fout:511 (ontbrekende variabele). Daarom retourneert TYPE.FOUT de waarde 1. 1
=TYPE.FOUT(#DIV/0!) Hier retourneert de functie 2, het type van de fout #DIV/0!. 2
=TYPE.FOUT(#WAARDE!) Hier retourneert de functie 3, het type van de fout #WAARDEǃ. 3
=TYPE.FOUT(#VERW!) Hier retourneert de functie 4, het type van de fout #VERWǃ. 4
=TYPE.FOUT(#NAAM?) Hier retourneert de functie 5, het type van de fout #NAAM?. 5
=TYPE.FOUT(#GETAL!) Hier retourneert de functie 6, het type van de fout #GETALǃ. 6
=TYPE.FOUT(#N/B) Hier retourneert de functie 7, het type van de fout #N/B. De formule =TYPE.fOUT(NB()) geeft ook 7 terug. 7
=TYPE.FOUT(E2) waarbij cel E2 de formule =WORTEL(-2) bevat. Aangezien de functie WORTEL een niet-negatief argument verwacht, bevat cel E2 de fout Fout:502 (ongeldig argument). Aangezien deze fout echter niet één van de fouten is die aan een specifiek fouttype zijn toegewezen, retourneert TYPE.FOUT de fout #N/B. #N/B
=TYPE.FOUT(E3) waarbij cel E3 de formule =PI() bevat. Aangezien er geen fout is in de opgegeven cel, retourneert TYPE.FOUT de fout #N/B. #N/B
=ALS(ISFOUT(A1/A2); ALS(TYPE.FOUT(A1/A2)=2; "*** Fout - kan niet delen door 0. ***"); A1/A2) waarbij cellen A1 en A2 bevatten respectievelijk de getallen 10 en 2. Hier is de formule ontworpen om de inhoud van cel A1 te delen door de inhoud van cel A2. De formule gebruikt echter de ALS en ISFOUT zorgt ervoor dat als cel A2 0 bevat, de deling niet wordt uitgevoerd en in plaats daarvan een gebruiksvriendelijke foutmelding wordt weergegeven. Met het beschreven voorbeeld retourneert de formule de waarde 5. Als het getal in cel A2 echter wordt gewijzigd in 0, wordt de foutmelding "*** Fout - kan niet gedeeld door 0. ***" weergegeven. 5

Gerelateerde LibreOffice-functies:

TYPEFOUT

ALS

ISFOUT

NB

ODF standaard:

Section 6.13.11, part 2

Gelijkwaardige Excel-functies:

TYPE.FOUT