Documentatie/Calc-functies/TYPE.FOUT

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/ERROR.TYPE and the translation is 100% complete.

    TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren

    Other languages:


    Functienaam:

    TYPE.FOUT

    Categorie:

    Werkblad

    Samenvatting:

    Genereert een codenummer dat het type fout in het argument vertegenwoordigt.

    Syntaxis:

    TYPE.FOUT(Expressie)

    Retourneert:

    Retourneert een positief geheel getal in het bereik [1, 7] als het argument één van de zeven gedefinieerde foutcondities vertegenwoordigt. Retourneert de fout #N/B als het argument geen fout vertegenwoordigt of een fout vertegenwoordigt buiten de set van zeven veelvoorkomende fouten die zijn toegewezen aan fouttypen.

    De toewijzing van de fouten van Calc aan de zeven fouttypen wordt weergegeven in de volgende tabel.

    Toewijzing fouten aan fouttypen
    Fout Retourneert
    Fout:511 (ontbrekende variabele)
    [tdf#154167][tdf#154915] #LEEG!     		1
    #DELING.DOOR.0! 2
    #WAARDE! 3
    #VERW! 4
    #NAAM? 5
    #GETAL! 6
    #N/B 7
    Geen fout of
    fout die niet wordt weergegeven in de bovenstaande lijst     		#N/B
    • Tot LibreOffice 7.5 (inbegrepen), toen Expressie resulteerde in Fout:511, was het resultaat van TYPE.FOUT 1. Dit resultaat was niet in overeenstemming met de ODF-norm. Dit is gecorrigeerd voor LibreOffice 7.6. Zie de voorbeelden hieronder.
    • Tot LibreOffice 7.5 (inbegrepen) was er geen formule die resulteerde in de #LEEG! fout. In plaats daarvan genereerde het foutgeval 'geen kruispuntverwijzing' een #VERW! foutcode. Dit is gecorrigeerd voor LibreOffice 7.6. Zie de voorbeelden hieronder.

    Argumenten:

    Expressie is een expressie of een verwijzing naar een cel die een expressie bevat, waarvan het fouttype moet worden bepaald.

    Aanvullende details:

    • De waarde van het gehele getal van het fouttype kan u helpen om op maat gemaakte foutberichten te genereren die nuttig zijn voor de beoogde gebruikers van uw werkblad.
    • TYPE.FOUT verspreidt geen fouten, in tegenstelling tot de meeste andere functies.
    • Andere spreadsheethulpmiddelen kunnen andere foutcodes genereren dan Calc voor dezelfde formule. Calc kan bijvoorbeeld een deel van zijn eigen "Fout:nnn" foutcodes gebruiken, terwijl andere implementaties de #GETAL! fout voor dezelfde formules. Wees daarom voorzichtig als u compatibiliteit nodig hebt.
    • Voor formules die "Fout:nnn" foutcodes genereren, Calc's TYPE.FOUT retourneert #N/B, hetzelfde resultaat als voor niet-fouten. Andere implementaties maken onderscheid tussen deze twee gevallen en genereren verschillende resultaten. Wees daarom voorzichtig als u compatibiliteit nodig hebt.
    • Andere implementaties accepteren foutcodes die rechtstreeks zijn ingetypt als tekenreeksen voor Expressie, waarbij dezelfde TYPE.FOUT resultaat als een werkelijk/reëel Expressie. Dit helpt bij het testen van formules met TYPE.FOUT. LibreOffice Calc ondersteunt dit gebruik van Expressie niet volledig. Met andere woorden, Expressie wordt niet verwacht dat het op zichzelf een foutcodereeks is, maar eerder het resultaat van een expressie of een verwijzing naar een expressie.
    • Andere spreadsheettools genereren andere numerieke resultaten dan [1...7] voor TYPE.FOUT. Wees daarom voorzichtig als u compatibiliteit nodig hebt.
    • Als de functie TYPE.FOUT wordt gebruikt als voorwaarde voor een functieaanroep ALS en de aanroep TYPE.FOUT #N/B retourneert, de functie ALS ook #N/B. Gebruik ISFOUT om dit te voorkomen, zoals weergegeven in het laatste voorbeeld hieronder.

    Voorbeelden:

    De volgende tabel wordt gebruikt als gegevens (met resultaten en formules) voor de onderstaande voorbeelden.

    Gegevens voor voorbeelden
    A B C D E
    1 Retourneert Beschrijving Formule
    2 Fout:511 Ontbrekend argument =WORTEL()
    3 Fout:502 =WORTEL(-2)
    4 3,14 π =PI()
    5 10
    6 2 1 4
    7 5 0
    8 3 A5:D6 intersectie met A6:B7 [1] =SOM(A5:D6!A6:B7)
    9 #LEEG! Geen intersectie =SOM(A5:A6!B6:B7)
    10 #VERW! ⇐ kopie =B10 =#VERW!10
    1. ↑ Het spatieteken wordt in sommige spreadsheetgereedschappen gebruikt als snijpuntoperator.
    Formule Beschrijving Retourneert
    =TYPE.FOUT(A2)

    =TYPE.FOUT(WORTEL())

    		Fout:511 Ontbrekend argument 1 (LO < 7.6) #N/B
    =TYPE.FOUT(A9)

    =TYPE.FOUT(SOM(A5:A6!B6:B7))

    		#LEEG! Geen intersectie 1
    =TYPE.FOUT(B6/D7)

    =TYPE.FOUT(1/0)

    		#DELING.DOOR.0! Delen door nul 2
    =TYPE.FOUT( "string" + 0 ) #WAARDE! Geen (geldige) waarde 3
    =TYPE.FOUT(A10) #VERW! Geen geldige referentie 4
    =TYPE.FOUT(onbekende_naam) #NAAM? Ongeldige naam 5
    =TYPE.FOUT(1000^500) #GETAL! Overflow / ongeldige numerieke waarde 6
    =TYPE.FOUT(NB()) #N/B Waarde niet beschikbaar / niet gevonden 7
    =TYPE.FOUT(A3)

    =TYPE.FOUT(WORTEL(-2))

    Aangezien de functie WORTEL niet een negatief argument verwacht, is er een fout Fout:502. Deze fout is niet aan een specifiek fouttype toegewezen.

    		#N/B
    =TYPE.FOUT(D6) Er is geen fout in de aangeven cel. #N/B

    =ALS(ISFOUT(A5/A6);   ALS(TYPE.FOUT(A5/A6)=2;   "*** Kan niet delen door 0 ***");   A5/A6)

    Als de deling kan worden uitgevoerd, wordt het resultaat weergegeven. Als de waarde van de noemer nul (of leeg) is, wordt in plaats daarvan een user-friendly-foutbericht weergegeven. Andere potentiële fouten worden niet opgevangen door deze formule/dit voorbeeld.

    		10/2=5

    =ALS(ISFOUT(A5/D7);   ALS(TYPE.FOUT(A5/D7)=2;   "*** Kan niet delen door 0 ***");   A5/D7)

    		*** Kan niet delen door 0 ***

    Gerelateerde LibreOffice-functies:

    TYPEFOUT

    ALS

    ALS.FOUT

    ALS.NB

    ISFOUT2

    ISFOUT

    ISNB

    ISGETAL

    ISTEKST

    NB

    ODF standaard:

    Section 6.13.11, part 2

    Gerelateerde (of gelijkwaardige) Excel-functies:

    ERROR.TYPE


    Retrieved from "https://wiki.documentfoundation.org/index.php?title=Documentation/Calc_Functions/ERROR.TYPE/nl&oldid=713384"