Dokumentation/Calc Funktionen/PIVOTDATENZUORDNEN
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende
Funktionsname:
PIVOTDATENZUORDNEN
Kategorie:
Tabelle
Zusammenfassung:
Bestimmt einen Wert innerhalb einer Pivottabelle unter Verwendung der speziellen Identifizierungskategorie für den Wert (statt dem Zellbezug). Da der Wert über Feld- und Artikelname angesprochen wird, wird der korrekte Wert zurückgegeben, auch wenn die darunterliegenden Daten oder das Layout der Pivottabelle geändert wird. PIVOTDATENZUORDNEN kann auch in einer Formel verwendet werden, wenn die Pivot Ergebnisse woanders in der Tabelle benötigt werden.
 |
Anmerkung:
|
Syntax:
Zwei unterschiedliche Syntaxdefinitionen können genutzt werden.
- erste Syntax
- PIVOTDATENZUORDNEN(Datenfeld; Pivottabelle[; Feld 1; Artikel 1][; ... [Feld 126; Artikel 126]])
- zweite Syntax
- PIVOTDATENZUORDNEN(Pivottabelle; Bedingungen)
Calc bevorzugt die zweite Syntax, falls exakt zwei Argumente angegeben werden und das erste Argument eine Referenz auf eine existierende Pivottabelle ist. die erste Syntax wird für andere Fälle verwendet. Der Funktionsassistent nutzt die erste Syntax.
ODF 1.2 empfiehlt die erste als die "präferierte" Syntax, wobei die zweite Syntax aus "Kompatibilitätsgründen" angeboten wird.
Rückgabewerte:
Gibt einen Wert aus der angegebenen Pivottabelle zurück. Der Typ des Rückgabewertes hängt von der Natur der in der Pivottabelle angezeigten Daten ab.
Argumente:
Erste Syntax
Datenfeld ist ein Text (in Anführungszeichen) oder eine Referenz auf eine Zelle, die den Text enthält. Dieser Text zeigt auf das genutzte Datenfeld in der Pivottabelle. Das benötigte Feld aus der darunterliegenden Datenquelle (z.Bsp. "Verkaufszahlen") oder der Name des Datenfeldes selbst (z. Bsp. "Summe - Verkaufszahlen") wird eingegeben. Falls die Pivottabelle mehr als ein Datenfeld hat, dann wird der geforderte Feldname angegeben. Sogar wenn die Pivottabelle nur ein Datenfeld hat, muss das Argument korrekt angegeben werden.
Pivottabelle ist eine Referenz auf eine Zelle oder einen Zellbereich, der im Ergebnisbereich der Pivottabelle liegt. Vorsicht: es kann in jeder Tabelle mehrere Pivottabellen geben.Der Name des benannten Bereiches kann in diesem Argument angegeben werden. Es wird empfohlen, immer die Zelle links oben anzugeben. Damit sind die ausgewählten Zellen immer innerhalb der Pivottabelle, auch wenn das Layout geändert wird.
Feld n ist ein Text (in Anführungszeichen) oder eine Referenz auf eine Zelle, die den Text enthält. Dieser Text identifiziert eines der Felder aus der Pivottabelle, die für die Berechnung einer Zwischensumme benötigt werden (z. Bsp. "Vertreter" oder "Gebiet"). Für jedes Feld n muss ein passender Artikel n existieren.
Artikel n ist ein Text (in Anführungszeichen) oder eine Referenz auf eine Zelle, die den Text enthält. Dieser Text bezieht sich auf ein Feld n, das gebraucht wird, um eine Zwischensumme zu errechnen (z. Bsp. "Fritz" oder "Nord"). Für eine Zahl als Artikel kann Artikel n auch diese Zahl sein.
- Falls nur die ersten beiden Argumente (Datenfeld und Pivottabelle) eingegeben werden, dann gibt PIVOTDATENZUORDNEN das Gesamtergebnis aus der Pivottabelle zurück.
- Jedes Paar aus Feld n / Artikel n fügt eine Bedingung hinzu, die das Ergebnis erfüllen muss. Die Sortierung von Feld n und Artikel n ist nicht signifikant. Die Namen von Feld n und Artikel n sind nicht case-sensitiv.
- Falls die Pivottabelle nur ein einziges Ergebnis enthält, das alle Bedingungen erfüllt, oder eine Zwischensumme, die alle Treffer aufsummiert, wird dieses Ergebnis zurückgegeben. Falls kein passendes Ergebnis existiert oder mehrere passende Ergebnisse ohne Zwischensumme existieren, dann gibt PIVOTDATENZUORDNEN einen #BEZUG! zurück.
- Es gibt mehrere andere Bedingungen, die PIVOTDATENZUORDNEN veranlassen, einen #BEZUG! Fehler zurückzugeben. So zum Beispiel: das Datenfeld entspricht keinem der Datenfelder aus der Pivottabelle; die Pivottabelle referenziert keine Zelle oder keinen Zellbereich aus der Pivottabelle; ein Feld n entspricht keinem Feld aus der Pivottabelle; ein Artikel n ist keine gültige Option für das entsprechende Feld n; ein Feld n hat keinen entsprechenden Artikel n.
Zweite Syntax
Pivottabelle hat die gleiche Bedeutung wie in der ersten Syntax.
Bedingungen ist ein Text (in doppelten Anführungszeichen) oder eine Referenz auf eine Zelle, die den Text enthält, der die aus der Pivottabelle zu entnehmenden Daten spezifiziert. Der Text gibt eine Liste an Bedingungen und die Einträge können wo nötig einzelne Zitate enthalten. Einträge in der Liste sind nicht case-sensitiv und deren Sortierung ist nicht signifikant.
- Einer der Einträge in der Bedingungsliste kann ein Name sein, der anzeigt, welches Datenfeld aus der Pivottabelle gebraucht wird. Dieses Feld aus der darunterliegenden Datenquelle (z. Bsp. "Verkaufszahlen") oder der Name des Datnefeldes selbst (z. Bsp. "Summe - Verkaufszahlen") wird eingegeben. Der Name des Datenfeldes kann fehlen, falls die Pivottabelle nur ein Datenfeld enthält, andernfalls muss es vorhanden sein.
- Jeder der anderen Einträge in der Liste gibt eine Bedingung an, normalerweise in der Form Feld[Artikel] (z. Bsp. "Verkäufer[Hans]" oder "Gebiet[Süd]"). Falls der Artikelname in der gesamten Pivottabelle eindeutig sein, dann kann der Feldname und die eckigen Klammren entfallen.
- Falls die Bedingungen auf eine leere Zeichenkette gesetzt sind, dann gibt PIVOTDATENZUORDNEN die Gesamtsumme der Pivottabelle an.
Für die zweite Syntax meldet PIVOTDATENZUORDNEN unter ähnlichen Umständen einen #BEZUG! Fehler wie die aus der ersten Syntax.
Zusätzliche Informationen:
Nichts
Beispiele:
Die folgende Pivottabelle wird als Basis für die folgenden Beispiele verwendet.
| Formel | Beschreibung | Ergebnis |
|---|---|---|
| =PIVOTDATENZUORDNEN("Summe - Verkaufszahlen"; $A$1) | Hier gibt die Funktion die Gesamtsumme aus der Pivottabelle zurück. Unter Verwendung der zweiten Syntax wären die äquivalenten Formeln =PIVOTDATENZUORDNEN($A$1; "") und =PIVOTDATENZUORDNEN($A$1; "Summe - Verkaufszahlen"). |
408765 |
| =PIVOTDATENZUORDNEN("Verkaufszahlen"; $A$1; "Employee"; "Fritz") | Hier gibt die Funktion die Zwischensumme für den Vertreter "Fritz" zurück. Unter Verwendung der zweiten Syntax wären die äquivalenten Formeln =PIVOTDATENZUORDNEN($A$1; "Verkaufzahlen Vertreter[Fritz]") und =PIVOTDATENZUORDNEN($A$1; "Fritz"). |
105453 |
| =PIVOTDATENZUORDNEN("Verkaufszahlen"; $A$1; "Category"; "Tennis") | Hier gibt die Funktion die Zwischensumme für die Kategorie "Tennis" zurück. Unter Verwendung der zweiten Syntax wären die äquivalenten Formeln =PIVOTDATENZUORDNEN($A$1; "Verkaufszahlen Kategorie[Tennis]") und =PIVOTDATENZUORDNEN($A$1; "Tennis"). |
142699 |
| =PIVOTDATENZUORDNEN("Verkaufszahlen"; $A$1; "Vertreter"; "hans"; "Kategorie"; "Segeln") | Hier gibt die Funktion die Zwischensumme für den Vertreter "Hans" und der Kategorie "Segeln" zurück. Unter Verwendung der zweiten Syntax wären die äquivalenten Formeln =PIVOTDATENZUORDNEN($A$1; Vertreter[Hans] Kategorie[Segeln] "Verkaufzahlen ") und =PIVOTDATENZUORDNEN($A$1; "Hans Segeln"). |
14060 |
Ähnliche LibreOffice Funktionen:
Nichts.
ODF Standard:
Betroffene (oder ähnliche) EXCEL-Funktionen:
GETPIVOTDATA