Documentatie/Calc-functies/DRAAITABEL.OPHALEN

From The Document Foundation Wiki
Jump to navigation Jump to search
This page is a translated version of the page Documentation/Calc Functions/GETPIVOTDATA and the translation is 100% complete.
Other languages:
English • ‎Nederlands



Functienaam:

DRAAITABEL.OPHALEN

Categorie:

Werkblad

Samenvatting:

Bepaalt een waarde binnen een draaitabel door de specifieke identificerende categorieën voor die waarde te gebruiken (in plaats van een celverwijzing). Omdat de waarde wordt geadresseerd met veld- en itemnamen, wordt de juiste waarde geretourneerd wanneer de onderliggende gegevens of lay-out van de draaitabel verandert. DRAAITABEL.OPHALEN kan in een formule worden gebruikt wanneer u de draaitabelresultaten elders in uw werkblad moet openen.

Note pin.svg

Note:
Het valt buiten het bestek van deze wikipagina om een volledige beschrijving te geven van de draaitabelfunctionaliteit van Calc. Algemene informatie over draaitabellen is te vinden op Wikipedia's Pivot table-pagina. Voor specifieke informatie over draaitabellen in Calc, bezoek onze Nederlandse documentatie-pagina en zie Hoofdstuk 8 (Draaitabellen gebruiken) in de nieuwste Calc-gids.

Syntaxis:

Er kunnen twee verschillende syntaxisdefinities worden gebruikt:

Eerste syntaxis
DRAAITABEL.OPHALEN(Gegevensveld; Draaitabel[; Veldnaam; Item 1][; ... [Veldnaam; Item 126]])
DRAAITABEL.OPHALEN(Draaitabel; Beperkingen)

Calc neemt de tweede syntaxis aan als er precies twee argumenten worden gegeven en het eerste argument een verwijzing is naar een bestaande draaitabel; de eerste syntaxis wordt in andere gevallen aangenomen. De Functie-assistent gebruikt de eerste syntaxis.

ODF 1.2 beschouwt de eerste als de "voorkeurs-" syntaxis, terwijl de tweede is bedoeld voor "compatibiliteit".

Retourneert:

Retourneert een waarde uit de opgegeven draaitabel. Het type waarde dat wordt geretourneerd, is afhankelijk van de aard van de gegevens die in de draaitabel worden weergegeven.

Argumenten:

Eerste syntaxis

Gegevensveld is een tekenreeks (tussen aanhalingstekens) of een verwijzing naar een cel die die tekenreeks bevat, die aangeeft welk gegevensveld van de draaitabel moet worden gebruikt. Voer de vereiste veldnaam in uit de onderliggende gegevensbron (bijvoorbeeld "Verkoopwaarde") of de naam van het gegevensveld zelf (bijvoorbeeld "Som – Verkoopwaarde"). Als de draaitabel meer dan één gegevensveld heeft, voert u de vereiste veldnaam in. Zelfs als de draaitabel slechts één gegevensveld heeft, moet u dit argument toch correct invoeren.

Draaitabel is een verwijzing naar een cel of een celbereik dat binnen het resultatengebied van de relevante draaitabel ligt, rekening houdend met het feit dat een werkblad meerdere draaitabellen kan bevatten. De naam van een benoemd bereik kan in dit argument worden doorgegeven. Het wordt aanbevolen dat u altijd de cel in de linkerbovenhoek van het gebied gebruikt, om ervoor te zorgen dat de gekozen cel(len) altijd in de draaitabel zullen staan, zelfs als de lay-out verandert.

Veldaam n is een tekenreeks (tussen aanhalingstekens) of een verwijzing naar een cel die die tekenreeks bevat, die één van de velden van de draaitabel identificeert die moeten worden vergeleken om een gedeeltelijke som te berekenen (bijvoorbeeld , "Werknemer" of "Regio"). Voor elk argument Veldnaam n moet er een overeenkomend argument Item n zijn.

Item n is een tekenreeks (tussen aanhalingstekens) of een verwijzing naar een cel die die tekenreeks bevat, die overeenkomt met een waarde van Veld n die moet worden gebruikt om een gedeeltelijke som te berekenen (bijvoorbeeld "Frits" of "Noord"). Voor een item dat een getal is, kan Item n ook die numerieke waarde zijn.

  • Als u alleen de eerste twee argumenten invoert (Gegevensveld en Draaitabel), dan retourneert DRAAITABEL.OPHALEN het totale resultaat van de draaitabel.
  • Elk paar argumenten Veldnaam n / Item n voegt een beperking toe waaraan het resultaat moet voldoen. De volgorde van de paren Veldnaam n / Item n' is niet significant. Veldnaam n en Item n namen zijn niet hoofdlettergevoelig.
  • Als de draaitabel slechts één resultaatwaarde bevat die aan alle beperkingen voldoet of een subtotaalresultaat dat alle overeenkomende waarden samenvat, wordt dat resultaat geretourneerd. Als er geen overeenkomend resultaat is of als er meerdere zijn zonder subtotaal, retourneert DRAAITABEL.OPHALEN de fout #VERW!.
  • Er zijn verschillende andere voorwaarden die ertoe leiden dat DRAAITABEL.OPHALEN de fout #VERW! weergeeft. Deze omvatten: het argument Gegevensveld komt niet overeen met één van de gegevensveldnamen van de draaitabel; het argument Draaitabel verwijst niet naar een cel of celbereik binnen de draaitabel; een argument Veldnaam n komt niet overeen met één van de veldnamen van de draaitabel; een argument Item n' is geen geldige optie voor de waarde van de corresponderende Veldnaam n'; een argument Veldnaam n' heeft geen corresponderend argument Item n'.

Tweede syntaxis

Draaitabel heeft dezelfde betekenis als in de eerste syntaxis.

Beperkingen is een tekenreeks (tussen dubbele aanhalingstekens) of een verwijzing naar een cel die die tekenreeks bevat, die de gegevens specificeert die uit de draaitabel moeten worden geëxtraheerd. De tekenreeks biedt een door spaties gescheiden lijst met beperkingen en vermeldingen kunnen waar nodig enkele aanhalingstekens bevatten. Vermeldingen in de lijst zijn niet hoofdlettergevoelig en hun volgorde is niet significant.

  • Eén van de items in de lijst met beperkingen kan een naam zijn die aangeeft welk gegevensveld van de draaitabel moet worden gebruikt. Voer de vereiste veldnaam in uit de onderliggende gegevensbron (bijvoorbeeld "Verkoopwaarde") of de naam van het gegevensveld zelf (bijvoorbeeld "Som – Verkoopwaarde"). De naam van het gegevensveld kan worden weggelaten als de draaitabel slechts één gegevensveld bevat, anders moet het aanwezig zijn.
  • Elk van de andere items in de lijst specificeert een beperking, normaal gesproken in de vorm Veldnaam[Item] (bijvoorbeeld "Werknemer[Hans]" of "Regio [Zuid]"). Als de itemnaam echter uniek is voor alle velden in de draaitabel, kunnen de veldnaam en vierkante haken worden weggelaten.
  • Als Beperkingen is ingesteld op de lege tekenreeks, retourneert DRAAITABEL.OPHALEN het totale resultaat van de draaitabel.

Voor de tweede syntaxis rapporteert DRAAITABEL.OPHALEN een fout #VERW! in vergelijkbare omstandigheden als beschreven voor de eerste syntaxis.

Aanvullende details:

Geen

Voorbeelden:

De volgende draaitabel wordt gebruikt als basis voor de volgende voorbeelden.

Sample-pivot-table-data.png
Formule Beschrijving Retourneert
=DRAAITABEL.OPHALEN("Som - Sales Value"; $A$1) Hier retourneert de functie het eindtotaal van de draaitabel. Als u de tweede syntaxis gebruikt, zijn equivalente formules =DRAAITABEL.OPHALEN($A$1; "") en =DRAAITABEL.OPHALEN($A$1; "Som - Sales Value"). 408765
=DRAAITABEL.OPHALEN("Sales Value"; $A$1; "Employee"; "Fritz") Hier retourneert de functie de som van de verkopen van werknemer "Fritz". Als u de tweede syntaxis gebruikt, zijn equivalente formules =DRAAITABEL.OPHALEN($A$1; "Sales Value Employee[Fritz]") en =DRAAITABEL.OPHALEN($A$1; "Fritz") 105453
=DRAAITABEL.OPHALEN("Sales Value"; $A$1; "Category"; "Tennis") Hier retourneert de functie de som van de verkopen voor de categorie "Tennis". Als u de tweede syntaxis gebruikt, zijn equivalente formules =DRAAITABEL.OPHALEN($A$1; "Sales Value Category[Tennis]") en =DRAAITABEL.OPHALEN($A$1; "Tennis") 142699
=DRAAITABEL.OPHALEN("sales value"; $A$1; "employee"; "hans"; "category"; "sailing") Hier retourneert de functie de som van de verkopen voor werknemer "Hans" in de categorie "Sailing". Bij gebruik van de tweede syntaxis zouden equivalente formules zijn: =DRAAITABEL.OPHALEN($A$1; "Employee[Hans] Category[Sailing] Sales Value") en =DRAAITABEL.OPHALEN($A$1; "Hans Sailing ") 14060

Gerelateerde LibreOffice-functies:

Geen.

ODF standaard:

Section 6.14.4, part 2

Gelijkwaardige Excel-functies:

DRAAITABEL.OPHALEN