Documentatie/Calc-functies/ALS.NB

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/IFNA and the translation is 100% complete.
    Other languages:


    Functienaam:

    ALS.NB

    Categorie:

    Logisch

    Samenvatting:

    Evalueert één argument en als er geen foutcode #N/B wordt gevonden, wordt de waarde van dat argument geretourneerd. Als er een foutcode #N/B wordt gevonden, wordt een tweede argument geëvalueerd en wordt de waarde ervan geretourneerd.

    Syntaxis:

    ALS.NB(Waarde; Alternatieve waarde)

    Retourneert:

    Retourneert een waarde waarvan het type afhangt van het argument dat is geselecteerd als de retourwaarde.

    Argumenten:

    Waarde is een uitdrukking of een verwijzing naar een cel die een uitdrukking bevat, die wordt geëvalueerd en geretourneerd als er geen foutcode #N/B wordt gevonden.

    Alternatieve waarde is een uitdrukking of een verwijzing naar een cel die een uitdrukking bevat, die alleen wordt geëvalueerd en geretourneerd als er een fout #N/B is gevonden tijdens de evaluatie van Waarde.

    • De functie ALS.NB evalueert Alternatieve waarde niet als de evaluatie van Waarde foutloos, dus zonder #N/B, verloopt. De formule =ALS.NB(23; 1/0) geeft bijvoorbeeld 23 terug. Terwijl van 1/0 kan worden verwacht dat het een foutcode #DELING.DOOR.0! geeft, in dit geval wordt geen poging gedaan tot deling.

    Aanvullende details:

    Details specifiek voor de functie ALS.NB

    =ALS.NB(X; Y) is semantisch gelijk aan =ALS(ISNB(X); Y; X), behalve dat het eerste geval efficiënter is omdat X maar één keer wordt berekend.


    Algemene informatie over de logische functies van Calc

    Note pin.svg

    NB:
    Voor het gemak wordt de informatie in deze subsectie herhaald op alle pagina's die de logische functies van Calc beschrijven.

    Calc gebruikt de getallen 0 (ONWAAR) en 1 (WAAR) om logische waarden weer te geven. Voer bijvoorbeeld 1 in in een cel met de standaard algemene getalopmaak. Selecteer vervolgens Opmaak ▸ Cellen op de Menubalk om het dialoogvenster Cellen opmaken weer te geven, selecteer de optie Booleaanse waarde in het gedeelteCategorie van het tabblad Getallen en klik op de knop OK. Merk op dat het getal 1 nu wordt weergegeven als WAAR. Om terug te keren naar het weergeven van het getal 1, herhaalt u het proces maar selecteert u Getal in plaats van Booleaanse waarde.

    Om een logische waarde in een cel in te voeren, typt u gewoon WAAR of ONWAAR (hoofdletterongevoelig) in de cel. Calc zal de logische waarde herkennen, deze in hoofdletters weergeven en de opmaak van de cel wijzigen in de opmaak die past bij Booleaanse waarden.

    Calc-functies die een logisch resultaat produceren, geven een getal terug, of 0 of 1. In het geval van een formule die zo'n logische functie eenvoudig aanroept en zich in een cel bevindt die de standaard algemene getalopmaak heeft, wordt de cel overgeschakeld naar de opmaak van de Booleaanse waarde en de geretourneerde waarde wordt weergegeven als ONWAAR of WAAR. Bijvoorbeeld =WAAR() retourneert de waarde 1, die wordt weergegeven als WAAR; als u de opmaak vervolgens wijzigt in een numerieke opmaak, wordt het weergegeven als het getal 1.

    Calc-functies die op een logisch resultaat testen, evalueren altijd de te testen uitdrukking en controleren of deze gelijk is aan 0. De waarde 0 wordt als ONWAAR beschouwd en elke andere waarde wordt als WAAR genomen. Bijvoorbeeld, =NIET(0) geeft WAAR terug en =NIET(57,89) geeft ONWAAR terug.

    In tegenstelling tot Calc heeft Microsoft Excel een apart type voor logische waarden - het zijn geen getallen maar worden soms geconverteerd naar getallen. Wees daarom voorzichtig als u compatibiliteit nodig heeft.

    Voorbeelden:

    Gegevens voor voorbeelden
    A B C D
    1 DEF MNO =VERT.ZOEKEN("ABC"; A1:B3; 2; ONWAAR())
    2 GHI PQR  -1
    3 JKL STU =VERT.ZOEKEN("XYZ"; A1:B3; 2; ONWAAR())
    Formule Beschrijving Retourneert
    =ALS.NB(2; 5) Hier bevat het eerste argument geen foutcode #N/B en dus retourneert de functie 2. 2
    =ALS.NB(WORTEL(−2); 23) Hier bevat het eerste argument een ongeldig argument (Fout:502) maar geen foutcode #N/B en dus retourneert de functie de Fout:502. Fout:502
    =ALS.NB(D1; D2) In de bovenstaande gegevenstabel resulteert de formule in D1 in #N/A}}, dus de ALS.NB functie retourneert de waarde van het tweede argument. −1
    =ALS.NB(D1; D3) De formule in D1 resulteert in #N/B, dus de ALS.NB functie retourneert de waarde van het tweede argument, wat ook resulteert in #N/A}}. #N/B

    Gerelateerde LibreOffice-functies:

    EN

    ONWAAR

    ALS

    ALS.FOUT

    ALS.VOORWAARDEN

    ISNB

    NIET

    OF

    SCHAKELEN

    WAAR

    EX.OF

    ODF standaard:

    Section 6.15.6, part 2

    Gerelateerde (of gelijkwaardige) Excel-functies:

    IFNA sinds v.2013