Dokumentation/Calc Funktionen/WENNS
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende
Funktionsname:
WENNS
Kategorie:
Logisch
Zusammenfassung:
Die Funktion bestimmt aus mehreren mitgegebenen Bedingungen die erste Bedingung, die zutrifft und meldet das dazugehörige Ergebnis zurück.
Syntax:
WENNS(Ausdruck 1; Ergebnis 1 [; Ausdruck 2; Ergebnis 2][ ...[Ausdruck 127; Ergebnis 127]])
Rückgabewerte:
Gibt einen Wert zurück, dessen Typ von der Natur des gewählten Ergebnisses abhängt.
Argumente:
Ausdruck 1, Ausdruck 2, ..., Ausdruck 127 sind Ausdrücke oder Referenzen auf eine Zelle die den auf WAHR oder FALSCH zu überprüfenden Ausdruck enthält. Falls der Ausdruck eine Zahl anstatt eines logischen Wertes enthält, dann wird der Wert 0 (Null) als FALSCH gewertet, während jede andere Zahl als WAHR gewertet wird. Jeder Vergleichsoperator aus Calc = (Gleichheit), <> (Ungleichheit), > (größer als), >= (größer als oder gleich), < (kleiner als) und <= (kleiner oder gleich) kann Bedingungen im Ausdruck n erzeugen. Jeder Ausdruck n muss ein Ergebnis n haben.
Ergebnis 1, Ergebnis 2, ..., Ergebnis 127 sind Ausdrücke oder Referenzen auf eine Zelle die das zurückzugebende Ergebnis enthält. Ein Ergebnis, das zurückgegeben wird, wenn der dazugehörige Ausdruck n der erste Ausdruck ist, auf den WAHR zutrifft.
- Falls ein Ausdruck n nicht als logischer Wert ausgedrückt werden kann, dann meldet WENNS einen #WERT! Fehler.
- Falls ein Ausdruck n als WAHR gilt, aber kein Ergebnis n vorhanden ist, dann meldet WENNS einen #NV Fehler.
- Falls kein Ausdruck n als WAHR gilt, dann meldet WENNS einen #NV Fehler.
Zusätzliche Informationen:
Spezifische Eigenheiten der Funktion WENNS
- Die Funktion WENNS kann oft als leichter lesbare Alternative für eine Funktion, die viele verschachtelte WENN Funktionsaufrufe hat, verwendet werden.
- Im Gegensatz zur Funktion SCHALTER hat WENNS keinen eingebauten Standardwert, der greift, wenn alle anderen Ausdrücke als FALSCH gelten. Um trotzdem einen solchen Standardwert zur Verfügung zu stellen, kann als letzter Ausdruck WAHR angegeben werden, gefolgt von einem Wert, der als Standardwert gelten soll.
- Die Formel
=WENNS(Ausdruck1; Ergebnis1; Ausdruck2; Ergebnis2; Ausdruck3; Ergebnis3)wird wie folgender Pseudocode ausgeführt:
- WENN Ausdruck1 is WAHR
- THEN Ergebnis1
- ELSE
- WENN Ausdruck2 is WAHR
- THEN Ergebnis2
- ELSE
- WENN Ausdruck3 is WAHR
- THEN Ergebnis3
- ELSE
- #NV
- Eine Konsequenz aus dieser Ausführungsreihenfolge ist die Tatsache, dass wenn WENNS einmal einen Ausdruck findet, der als WAHR gilt, das entsprechende Ergebnis n auswertet und zurückgibt, ohne weitere Ausdrücke oder Ergebnisse auszuwerten. Zum Beispiel gibt die Formel
=WENNS(WAHR(); "Erstes Ergebnis"; 3/0; "Zweites Ergebnis")die Zeichenkette "Erstes Ergebnis" zurück - und obwohl3/0einen #DIV/0! Fehler erzeugen würde, wird diese Division in diesem Fall erst gar nicht ausgeführt.
Allgemeine Informationen über die logischen Funktionen in Calc
 |
Anmerkung:
|
Calc verwendet die Zahlen 0 (FALSCH) und 1 (WAHR) um logische Werte auszudrücken. Geben Sie zum Beispiel 1 in eine Zelle im allgemeinen Zahlenformat ein. Gehen Sie dann auf ▸ in der Menüleiste, wählen Sie Wahrheitswert im Feld Kategorie des Tabs Zahlen und klicken auf . Beachten Sie, das die Zahl 1 jetzt als WAHR angezeigt wird. Um die Anzeige zurückzustellen, wiederholen Sie den Vorgang, wählen Sie aber Dezimalzahl anstatt Wahrheitswert.
Um einen logischen Wert in eine Zelle einzugeben, tippen Sie einfach WAHR oder FALSCH (case-insensitive) in die Zelle ein. Calc erkennt den logischen Wert, zeigt ihn in Großbuchstaben an und ändert die Formatierung der Zelle auf Wahrheitswert.
Calc Funktionen, die einen Wahrheitswert erzeugen, geben ihn als Zahl, entweder 0 oder 1, zurück. Im Fall einer Formel, die eine solche logische Funktion aufruft und in einer Zelle mit einer Formatierung zur Dezimalzahl wird die Formatierung der Zelle auf einen Wahrheitswert geändert. Dabei wird der Rückgabewert als FALSCH oder WAHR angezeigt. Zum Beispiel gibt =WAHR() den Wert 1 zurück. Dieser wird als WAHR angezeigt. Falls Sie die Formatierung der Zelle auf Dezimalzahl ändern, wird die Zahl 1 angezeigt.
Calc Funktionen, die auf einen Wahrheitswert testen, tun dies immer, in dem Sie den Ausdruck auf den Wert 0 testen. Der Wert 0 wird als FALSCH angesehen. Jeder andere Wert wird als WAHR angesehen. Zum Beispiel gibt =NICHT(0) WAHR zurück, während =NICHT(57.89) FALSCH zurückgibt.
Im Gegensatz zu Calc hat Microsoft EXCEL einen seperaten Typ für logische Werte - sie sind keine Zahlen sondern werden manchmal in Zahlen umgewandelt. Also Vorsicht bei Kompatibilitätsbedarf.
Beispiele:
| Formel | Beschreibung | Ergebnis |
|---|---|---|
| =WENNS(A1>5; 100; A1<=5; "zu klein") | Hier gibt die Funktion die Zahl zurück, falls A1 größer als 5 ist. Ansonsten wird "zu klein" zurückgegeben. Die Formel =WENN(A1>5; 100; WAHR(); "zu klein") gilt als äquivalent.
|
100 oder "zu klein" |
| =WENNS(A1=1; "Jan"; A1=2; "Feb"; A1=3; "Mär"; A1=4; "Apr"; A1=5; "Mai"; A1=6; "Jun"; A1=7; "Jul"; A1=8; "Aug"; A1=9; "Sep"; A1=10; "Okt"; A1=11; "Nov"; A1=12; "Dez")
wobei Zelle A1 die Formel =MONAT(HEUTE()) enthält und heute der 28.11.2021 ist. |
Die Formel holt den Monat als eine Ganzzahl aus dem heutigen Datum und konvertiert die Zahl in eine Zeichenkette mit einer dreistelligen Abkürzung für den Monat. | Nov |
| =WENNS(A1; A2; A3; A4)
wobei die Zellen A1:A4 die Zahlen 0, 123, -1 und 456 enthalten. |
Hier erkennt die Funktion das erste Argument als FALSCH und ignoriert das zweite Argument. Das dritte Argument wird als WAHR erkannt und der Wert 456 zurückgegeben. | 456 |
Ähnliche LibreOffice Funktionen:
ODF Standard:
Nichts.
Betroffene (oder ähnliche) EXCEL-Funktionen:
IFS