Documentatie/Calc-functies/ALS.VOORWAARDEN
TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren
Functienaam:
ALS.VOORWAARDEN
Categorie:
Logisch
Samenvatting:
Bepaalt op basis van meerdere voorwaarden die als argumenten zijn doorgegeven, de eerste voorwaarde waaraan wordt voldaan en retourneert het resultaat dat overeenkomt met die voorwaarde.
Syntaxis:
ALS.VOORWAARDEN(Test1; Resultaat1 [; Test2; Resultaat2][; ... ; [Test127; Resultaat127]])
Retourneert:
Retourneert een waarde waarvan het type afhangt van de aard van het geselecteerde argument.
Argumenten:
Test1, Test2, ..., Test127 zijn uitdrukkingen of verwijzingen naar cellen die uitdrukkingen bevatten, die kunnen worden geëvalueerd tot een logische waarde WAAR of ONWAAR. Als een uitdrukking wordt geëvalueerd tot een getal in plaats van een logische waarde, wordt de waarde 0 (nul) behandeld als ONWAAR , terwijl elke waarde die niet nul is, wordt behandeld als WAAR. Elk van de vergelijkende operatoren van Calc = (gelijk aan), <> (ongelijkheid), > (groter dan), >= (groter dan of gelijk aan), < (kleiner dan) en <= (kleiner dan of gelijk aan) kan zijn gebruikt om voorwaarden te creëren in de Test n-argumenten. Elk Test n-argument moet een bijbehorend Resultaat n-argument hebben.
Resultaat1, Resultaat2, ..., Resultaat127 zijn uitdrukkingen of verwijzingen naar cellen die uitdrukkingen bevatten, die de resultaten opleveren die moeten worden geretourneerd wanneer het overeenkomstige Test n-argument het eerste is dat wordt geëvalueerd als WAAR.
- Als een Test n-argument niet kan worden geëvalueerd als een logische waarde, rapporteert ALS.VOORWAARDEN een fout #WAARDE!
- Als een Test n-argument wordt geëvalueerd als de logische waarde WAAR, maar er is geen corresponderend argument Resultaat n, dan rapporteert ALS.VOORWAARDEN een fout#N/B.
- Als geen argument Test n wordt geëvalueerd als WAAR, rapporteert ALS.VOORWAARDEN een fout #N/B.
Aanvullende details:
Details specifiek voor de functie ALS.VOORWAARDEN
- De functie ALS.VOORWAARDEN kan vaak worden gebruikt als een beter leesbaar alternatief voor het maken van een formule met behulp van meerdere geneste functieaanroepen ALS.
- In tegenstelling tot de functie SCHAKELEN, biedt ALS.VOORWAARDEN geen "ingebouwde" standaardwaarde die kan worden gebruikt wanneer alle andere expressies onwaar zijn. Als u echter een dergelijke standaardwaarde wilt opgeven, kunt u WAAR invoeren als de laatste uitdrukking, gevolgd door een waarde die u als standaardresultaat wilt gebruiken.
- De formule
=ALS.VOORWAARDEN(Test1; Resultaat1; Test2; Resultaat3; Test3; Resultaat3)wordt uitgevoerd zoals beschreven door de volgende pseudocode:
- ALS Test1 WAAR is
- DAN Resultaat1
- ANDERS
- ALS Test2 WAAR is
- DAN Resultaat2
- ANDERS
- ALS Test3 WAAR is
- DAN Resultaat3
- ANDERS
- #N/B
- Een gevolg van deze uitvoeringsvolgorde is dat zodra ALS.VOORWAARDEN een Test n-argument vindt dat waar is, het het corresponderende argument Resultaat n evalueert en retourneert, zonder verdere test of resultaatargumenten te verwerken. De formule
=ALS.VOORWAARDEN(WAAR(); "Eerste resultaat"; 3/0; "Tweede resultaat")retourneert bijvoorbeeld de tekenreeks "Eerste resultaat" – terwijl3/0zou naar verwachting een fout #DELING.DOOR.0! geven, in dit geval niet, omdat geen poging wordt gedaan tot deling.
Algemene informatie over de logische functies van Calc
 |
NB:
|
Calc gebruikt de getallen 0 (ONWAAR) en 1 (WAAR) om logische waarden weer te geven. Voer bijvoorbeeld 1 in in een cel met de standaard algemene getalopmaak. Selecteer vervolgens ▸ op de Menubalk om het dialoogvenster Cellen opmaken weer te geven, selecteer de optie Booleaanse waarde in het gedeelteCategorie van het tabblad Getallen en klik op de knop . Merk op dat het getal 1 nu wordt weergegeven als WAAR. Om terug te keren naar het weergeven van het getal 1, herhaalt u het proces maar selecteert u Getal in plaats van Booleaanse waarde.
Om een logische waarde in een cel in te voeren, typt u gewoon WAAR of ONWAAR (hoofdletterongevoelig) in de cel. Calc zal de logische waarde herkennen, deze in hoofdletters weergeven en de opmaak van de cel wijzigen in de opmaak die past bij Booleaanse waarden.
Calc-functies die een logisch resultaat produceren, geven een getal terug, of 0 of 1. In het geval van een formule die zo'n logische functie eenvoudig aanroept en zich in een cel bevindt die de standaard algemene getalopmaak heeft, wordt de cel overgeschakeld naar de opmaak van de Booleaanse waarde en de geretourneerde waarde wordt weergegeven als ONWAAR of WAAR. Bijvoorbeeld =WAAR() retourneert de waarde 1, die wordt weergegeven als WAAR; als u de opmaak vervolgens wijzigt in een numerieke opmaak, wordt het weergegeven als het getal 1.
Calc-functies die op een logisch resultaat testen, evalueren altijd de te testen uitdrukking en controleren of deze gelijk is aan 0. De waarde 0 wordt als ONWAAR beschouwd en elke andere waarde wordt als WAAR genomen. Bijvoorbeeld, =NIET(0) geeft WAAR terug en =NIET(57,89) geeft ONWAAR terug.
In tegenstelling tot Calc heeft Microsoft Excel een apart type voor logische waarden - het zijn geen getallen maar worden soms geconverteerd naar getallen. Wees daarom voorzichtig als u compatibiliteit nodig heeft.
Voorbeelden:
| Formule | Beschrijving | Retourneert |
|---|---|---|
| =ALS.VOORWAARDEN(A1>5; 100; A1<=5; "te klein") | Hier retourneert de functie het getal 100 als A1 groter is dan 5 en anders de tekst "te klein". De formule =ALS(A1>5; 100; WAAR(); "te klein") is equivalent.
|
100 of "te klein" |
| =ALS.VOORWAARDEN(A1=1; "Jan"; A1=2; "Feb"; A1=3; "Mrt"; A1=4; "Apr"; A1=5; "Mei"; A1=6; "Jun"; A1=7; "Jul"; A1=8; "Aug"; A1=9; "Sep"; A1=10; "Okt"; A1=11; "Nov"; A1=12; "Dec")
waarbij cel A1 bevat de formule =MAAND(VANDAAG()) en de datum van vandaag is 2021-11-28. |
De formule extraheert de maandwaarde van de datum van vandaag als een geheel getal en converteert het getal vervolgens naar een tekenreeks die een afkorting van drie tekens van de maand oplevert. | Nov |
| =ALS.VOORWAARDEN(A1; A2; A3; A4)
waarbij cellen A1:A4 respectievelijk de getallen 0, 123, -1 en 456 bevatten. |
Hier evalueert de functie het eerste argument als onwaar en negeert het tweede argument. Het derde argument wordt geëvalueerd als waar en de waarde 456 wordt geretourneerd. | 456 |
Gerelateerde LibreOffice-functies:
ODF standaard:
Geen
Gerelateerde (of gelijkwaardige) Excel-functies:
IFS