Dokumentation/Calc Funktionen/INDIREKT

TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende

• Start
• Entwicklung
• Gestaltung
• QA
• Events
• Dokumentation
• Webseite
• Lokalisierung
• Barrierefreiheit
• Marketing
• Diversität
• Wiki Hilfe

• Dokumentation Start
• Handbücher
• Andere Quellen
• FAQ
• HowTo
• Makros
• Doku Entwicklung

Calc Funktionen Start | Liste der Funktionen | Abkürzungen

Funktionsname:

INDIREKT

Kategorie:

Tabelle

Zusammenfassung:

Erzeugt eine Referenz aus einer Text-Entsprechung dieser Referenz. Die Referenz kann eine einzelne Zelle oder ein Zellbereich sein oder kann optional auch eine Referenz auf ein Arbeitsblatt mit oder ohne Dateinamen haben.

Ein optionales Argument steuert, ob die Formel-Syntax Calc A1 oder Excel R1C1 verwendet wird (siehe die Hilfe-Seite Formel für weitere Infos).

Die Funktion ADRESSE wird verwendet, um die Referenz auf die interessante Zelle dynamisch in Form eines Textes zu bestimmen. Der Ergebnistext kann an die Funktion INDIREKT übergeben werden, um den Zellinhalt zu erhalten. Der Text, der an INDIREKT übergeben wird, kann auch über andere Methoden als die Funktion ADRESSE ermittelt werden.

Syntax:

INDIREKT(Referenz[; A1])

Rückgabewerte:

Gibt eine Referenz auf eine oder mehr Zellen aufgrund der angegebenen Argumente zurück.

Argumente:

Referenz ist ein Text oder eine Referenz auf eine Zelle, die diesen Text enthält. Dieser Text entspricht der Referenz.

A1 ist ein logischer Wert oder eine Referenz auf eine Zelle mit dem logischen Wert. Dieser bestimmt die Formel-Syntax, die im zurückzugebenden Wert angewendet wird. Falls A1 auf 0 oder FALSCH gesetzt wird, wird die Formel-Syntax Excel R1C1 verwendet. Falls A1 fehlt oder auf einen anderen (numerischen) Wert gesetzt wird, wird die Formel-Syntax Calc A1 verwendet.

• Falls A1 nicht numerisch (und nicht logisch) ist, dann meldet INDIREKT einen #WERT! Fehler.
• Falls die Kombination aus Referenz und A1 keinem gültigen Wert entspricht, dann meldet INDIREKT einen #BEZUG! Fehler.
• Falls der Aufruf der Funktion INDIREKT einem externen Link folgt, dann erfolgt eine geeignete Meldung beim Öffnen der Tabelle mit einer Warnung, dass die automatische Aktualisierung des externen Links abgeschaltet wurde. Gleichzeitig erfolgt eine Fehlermeldung Fehler:540 in der betroffenen Zelle. Bitte bestätigen Sie die Meldung Aktualisierung erlauben, um diese Links zu aktualisieren.

Zusätzliche Informationen:

• INDIREKT ist eine volatile Funktion. D. h. dass Calc die von INDIREKT zurückgegebene Referenz aktualisiert, sobald irgendeine Zelle über Daten ▸ Berechnen ▸ Neu berechnen aktualisiert wird, F9 gedrückt wird oder eine Eingabe erfolgt.
• Calcs Funktionen ADRESSE und INDIREKT sind eng miteinander verwandt. ADRESSE gibt einen Zellbezug zurück, der als Argument an INDIREKT übergeben werden kann, um den Inhalt der referenzierten Zelle zu erhalten.
• Falls an INDIREKT ein Text übergeben wird, der von ADRESSE ermittelt wird, muss für die beiden Funktionen die selbe Einstellung für das Argument A1 verwendet werden. Bei einer unterschiedlichen Formel-Syntax entstehen Fehler.
• Im ODF vor Version 1.2 beinhaltet die Spezifikation für die Funktion INDIREKT kein Argument A1 um zwischen der Formel-Syntax Calc A1 und Excel R1C1 zu unterscheiden. Wenn ein Dokument im ODF 1.0/1.1 Format gespeichert wird, werden Aufrufe der Funktion INDIREKT ohne Konversion gespeichert. Das kann zu folgenden Fehlern in diesen Funktionsaufrufen führen.
• Microsoft EXCEL interpretiert einige Zellbezüge anders als Calc, daher ist diese Funktion nicht immer portierbar. Zum Beispiel ist die Formel =INDIREKT("Tabelle2.A1") in Calc gültig (wobei das Trennzeichen nach dem Arbeitsblattnamen der Punkt "." ist), aber die für EXCEL benötigte Form lautet =INDIREKT("Tabelle2!A1") (wobei das Trennzeichen nach dem Arbeitsblattnamen das Ausrufezeichen "!" ist).
• Falls eine EXCEL-Tabelle indirekte Adressen aus Text-Funktionen berechnet, werden die Tabellen-Adressen nicht automatisch übersetzt. Z. Bsp. wird die EXCEL-Adresse in =INDIREKT("'[Dateiname]Tabellenname'!"&B1) nicht in die Calc Adresse in =INDIREKT("'Dateiname#Tabellenname'."&B1) übertragen.

Beispiele:

Beispielsdaten

	A	B	C	D
1	1	2	6	=INDIREKT("R[2]C[-1]"; 0)
2	3	4	5
3			7	B2
4	"meinZellbereich": A1:B2			⇐ benannter Bereich

Formel	Beschreibung	Ergebnis
=INDIREKT("B2")	Äquivalent zu =B2. Man beachte das Verwenden der Anführungszeichen um den Text.	4
=INDIREKT("B" & "2")	Äquivalent zu =B2.	4
=INDIREKT(D3)	Äquivalent zu =B2. Man beachte das Fehlen der Anführungszeichen. Das Argument ist ein Zellbezug.	4
=INDIREKT(B2)	Man beachte das Fehlen der Anführungszeichen. Da die referenzierte Zelle keine Zelladresse beinhaltet ist das Ergebnis ein Fehler.	#BEZUG!
=INDIREKT("B2"; 99)	Äquivalent zu =B2. Das Argument A1 ist eine Zahl ungleich Null. Das ist genauso als würde sie fehlen.	4
=SUMME(INDIREKT("A1:B2"))	Zunächst wird eine Referenz auf den Zellbereich A1:B2 zurückgegeben. Das entspricht der Rückgabe der vier Zahlen in diesen Zellen.	10
=SUMME(INDIREKT("meinZellbereich"))	Zunächst wird eine Referenz auf den Zellbereich A1:B2 zurückgegeben. Das entspricht der Rückgabe der vier Zahlen in diesen Zellen.	10
=INDIREKT("R2C3"; 0)	Man beachte die Verwendung der Anführungszeichen um einen Text und die Zahl 0 im Argument A1. Es wird dier Inhalt der Zelle R2C3 (C2) zurückgegeben.	5
=INDIREKT("R[2]C[-1]"; 0) wobei die Formel in Zelle D1 steht.	Das Argument A1 ist 0, daher wird R[2]C[-1] in R1C1-Formel Syntax angegeben, in diesem Fall relativ zu Zelle D1; 2 Zeilen runter und -1 Spalte nach rechts, so wird eine Referenz zu Zelle C3 erreicht.	7
=SUMME(INDIREKT("a1:" & ADRESSE(1;3)))	Die Summe der Zellen in dem Bereich von A1 zur Zelle, deren Adresse durch Zeile 1 und Spalte 3 definert wird (C1).	9

Ähnliche LibreOffice Funktionen:

ADRESSE

SPALTE

ZEILE

ODF Standard:

Kapitel 6.14.7, Teil 2.

Betroffene (oder ähnliche) EXCEL-Funktionen:

INDIRECT