Documentatie/Calc-functies/INDIRECT
TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren
Functienaam:
INDIRECT
Categorie:
Werkblad
Samenvatting:
Maakt een verwijzing op basis van een tekenreeks van die verwijzing. De verwijzing kan naar een enkele cel of naar een reeks cellen zijn en kan optioneel ook een werkbladreferentie bevatten, met of zonder bestandsnaam.
Een optioneel argument bepaalt of de invoertekenreeks de formulesyntaxis van Calc A1 of Excel R1C1 gebruikt
(zie de Formula helppagina voor details).
De functie ADRES wordt gebruikt om dynamisch de verwijzing van een van belang zijnde cel te bepalen, in de vorm van een string. De resulterende string kan vervolgens worden doorgegeven aan de functie INDIRECT om de inhoud van de cel op te halen. De tekenreeks die aan INDIRECT wordt doorgegeven, hoeft echter niet te worden gemaakt met de functie ADRES.
Syntaxis:
INDIRECT(Verwijzing[; A1])
Retourneert:
Retourneert een verwijzing naar één of meer cellen, gebaseerd op de opgegeven argumenten.
Argumenten:
Verwijzing is een tekenreeks of een verwijzing naar een cel die een tekenreeks bevat, wat een weergave is van de tekenreeks van de verwijzing.
A1 is een logische waarde of een verwijzing naar een cel die een logische waarde bevat, die de syntaxis van de formule bepaalt die in de geretourneerde tekenreeks moet worden gebruikt.
Als A1 is ingesteld op 0 of ONWAAR, wordt de Excel R1C1-formule syntaxis gebruikt.
Als A1 wordt weggelaten of op een andere numerieke waarde wordt ingesteld, wordt de syntaxis van de Calc A1-formule gebruikt.
- Als A1 niet-numeriek (en niet-logisch) is, dan retourneert INDIRECT als fout #WAARDE!
- Als de combinatie van de Verwijzing en A1 argumenten niet overeenkomen met een geldige referentie, dan retourneert INDIRECT als fout #VERW!
- Als de functie-aanroep INDIRECT betrekking heeft op een externe koppeling, dan kan het zijn dat u bij het openen van uw werkblad een passend bericht ontvangt met de waarschuwing dat het automatisch bijwerken van externe koppelingen is uitgeschakeld. Tegelijkertijd wordt Fout:540 weergegeven in de betreffende cel. Klik op de knop om het bijwerken van deze koppelingen in te schakelen.
Aanvullende details:
- INDIRECT is een vluchtige functie. Dit betekent dat Calc de door INDIRECT geretourneerde verwijzing zal bijwerken wanneer een cel wordt bijgewerkt door ▸ ▸ te selecteren of op F9 te drukken of op een invoergebeurtenis.
- Calc's ADRES en INDIRECT functies zijn nauw verwant. ADRES retourneert een celverwijzing als tekst, die als argument kan worden doorgegeven aan INDIRECT om de inhoud van de cel waarnaar wordt verwezen op te halen.
- Als u een tekenreeks doorgeeft aan INDIRECT die is gegenereerd door ADRES, zorg ervoor dat de twee functies dezelfde instelling gebruiken voor het A1 argument. Als de twee functies een verschillende formulesyntaxis aannemen, kunnen er fouten optreden.
- In versies van de ODF ouder dan 1.2 bevatte de specificatie voor de functie INDIRECT niet het argument A1 om onderscheid te maken tussen de formulesyntaxis van
Calc A1enExcel R1C1. Bij het opslaan van een document in ODF 1.0/1.1-formaat worden oproepen naar de functie INDIRECT zonder conversie opgeslagen. Dit kan ertoe leiden dat er volgende fouten verschijnen voor die functieaanroepen. - Microsoft Excel geeft sommige celverwijzingen anders weer dan Calc, dus deze functie is niet altijd overdraagbaar. De formule
=INDIRECT("Blad2.A1")is bijvoorbeeld geldig in Calc (waarbij het scheidingsteken voor de naam van het werkblad de punt "." is.), maar de vereiste vorm in Excel is=INDIRECT("Blad2!A1")(waarbij het scheidingsteken voor de naam van het werkblad het uitroepteken "!" is). - Als u een Excel-werkblad opent die indirecte adressen gebruikt die zijn berekend op basis van tekenreeksfuncties, worden de bladadressen niet automatisch vertaald. Het Excel-adres in
=INDIRECT("'[bestandsnaam]bladnaam'!"&B1)wordt bijvoorbeeld niet geconverteerd naar het Calc-adres in=INDIRECT("'bestandsnaam#bladnaam'."&B1).
Voorbeelden:
| A | B | C | D | |
|---|---|---|---|---|
| 1 | 1 | 2 | 6 | =INDIRECT("R[2]C[-1]"; 0)
|
| 2 | 3 | 4 | 5 | |
| 3 | 7 | B2 | ||
| 4 | "MijnCelBereik": A1:B2
|
⇐ genoemd bereik
| ||
| Formule | Beschrijving | Retourneert |
|---|---|---|
| =INDIRECT("B2") | Gelijk aan =B2. Let op het gebruik van aanhalingstekens, die een tekenreeks omsluiten.
|
4 |
| =INDIRECT("B" & "2") | Gelijk aan =B2.
|
4 |
| =INDIRECT(D3) | Gelijk aan =B2. Let op het ontbreken van aanhalingstekens; Het argument is een celverwijzing.
|
4 |
| =INDIRECT(B2) | Let op het ontbreken van aanhalingstekens. Aangezien de cel waarnaar wordt verwezen geen tekenreeks bevat die een celadres vertegenwoordigt, is het resultaat een fout. | #VERW! |
| =INDIRECT("B2"; 99) | Gelijk aan =B2. Het argument A1 is een numerieke waarde die niet nul is, gelijk aan weggelaten.
|
4 |
| =SOM(INDIRECT("A1:B2")) | Eerst retourneren van een verwijzing naar het celbereik A1:B2. De formule retourneert daarom de som van de vier getallen in deze cellen. | 10 |
| =SOM(INDIRECT("MijnCelBereik")) | Eerst retourneren van een verwijzing naar het celbereik A1:B2. De formule retourneert daarom de som van de vier getallen in deze cellen. | 10 |
| =INDIRECT("R2C3"; 0) | Let op het gebruik van aanhalingstekens, een tekenreeks en de waarde nul voor het argument A1. Retourneer de inhoud van cel R2C3 (C2).
|
5 |
=INDIRECT("R[2]C[-1]"; 0)
waarbij de formule is ingevoerd in cel D1. |
Het argument A1 is 0, dus R[2]C[-1] wordt geëvalueerd in de syntaxis R1C1-formule, in dit geval ten opzichte van cel D1; 2 rijen naar beneden en -1 kolom breed, zodat er een verwijzing naar cel C3 ontstaat.
|
7 |
| =SOM(INDIRECT("a1:" & ADRES(1;3))) | Tel de cellen op in het bereik van cel A1 tot de cel waarvan het adres wordt gedefinieerd door rij 1 en kolom 3 (C1). | 9 |
Gerelateerde LibreOffice-functies:
ODF standaard:
Gerelateerde (of gelijkwaardige) Excel-functies:
INDIRECT