Documentation/Calc Functions/ISERR

From The Document Foundation Wiki
Jump to navigation Jump to search
Other languages:
English • ‎Nederlands



Function name:

ISERR

Category:

Information

Summary:

Determines if a specified cell or expression evaluates to an error type other than #N/A.

Syntax:

ISERR(Value)

Returns:

Returns TRUE if the argument evaluates to an error value other than the value not available error (#N/A) and returns FALSE otherwise.

Arguments:

Value is an expression, or a reference to a cell containing an expression, that is to be tested for an error condition (other than #N/A).

Additional details:

  • ISERR does not propagate errors. If Value evaluates to an error other than #N/A, then ISERR returns TRUE. If Value evaluates to a #N/A error, then ISERR returns FALSE.
  • Use the ISERROR function to test for any errors including #N/A. The formula =ISERR(X) is equivalent to the formula =IF(ISNA(X); FALSE(); ISERROR(X)).
  • Use ISERR in conjunction with the IF function to test for errors and take different actions in normal and error conditions.

Examples:

Formula Description Returns
=ISERR(12.34) Here the function returns the logical value FALSE. FALSE
=ISERR("Hello world!") Here the function returns the logical value FALSE. FALSE
=ISERR(TRUE()) Here the function returns the logical value FALSE. FALSE
=ISERR(2021-12-18) Here the function returns the logical value FALSE. FALSE
=ISERR(D1) where cell D1 contains the formula =1/0. Here cell D1 contains a #DIV/0! error and so the function returns the logical value TRUE. TRUE
=ISERR(D2) where cell D2 contains the formula =SQRT(-7). Here cell D2 contains an invalid argument error (Err:502) and so ISERR returns the logical value TRUE. TRUE
=ISERR(D3) where cell D3 contains the formula =NA(). Here cell D3 contains a #N/A error and so ISERR returns the logical value FALSE. FALSE

Related LibreOffice functions:

ERROR.TYPE

ISERROR

ISNUMBER

ISTEXT

NA

ODF standard:

Section 6.13.15, part 2

Equivalent Excel functions:

ISERR