Dokumentation/Calc Funktionen/ISPMT

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/ISPMT and the translation is 100% complete.
    Other languages:

    Funktionsname:

    ISPMT

    Kategorie:

    Finanzmathematik

    Zusammenfassung:

    Berechnet die Zinsen für einen angegebenen Zeitraum einer festverzinslichen Anlage bzw. Darlehens unter der Voraussetzung einer gleichbleibenden Tilgung. Die fälligen Zinsen hängen vom Barwert ab und sinken während der Laufzeit.

    Syntax:

    ISPMT(Zinssatz; Periode; Gesamtzahl der Perioden; Nennwert)

    Rückgabewerte:

    Gibt den Zinsanteil einer speziellen Periode für die Anlage bzw. das Darlehen als Dezimalzahl zurück. Der Rückgabewert ist für Zahlungen negativ und positiv für Anlagen. Die zurückgegebene Zahl ist in der selben Währung wie die angegebene investierte Summe.

    Argumente:

    Zinsatz ist eine Dezimalzahl (ein Prozentsatz wie z. Bsp. 2,5 % oder ein Dezimalbruch wie 0,025) oder eine Referenz auf eine Zelle mit dem periodischen Zinssatz. Der Zinssatz wird üblicherweise jährlich angegeben. Es sollte auch darauf geachtet werden, solche Daten auf die gesamte Laufzeit umzulegen.

    Periode ist eine positive Dezimalzahl oder eine Referenz auf eine Zelle mit der Zahl. Diese Zahl gibt die Periode an, für die die Abschreibung berechnet wird.

    Gesamtzahl der Perioden ist eine Dezimalzahl ungelich 0 oder die Referenz auf eine Zelle mit der Anzahl der Perioden im Zeitraum.

    Investment ist eine Dezimalzahl oder eine Referenz auf eine Zelle, welche die Zahl enthält. Diese Zahl ist der Barwert der geliehenen oder angelegten Summe.

    • Falls irgendein Argument nicht numerisch ist, dann gibt ISPMT einen #WERT!-Fehler zurück.
    • Falls Gesamtzahl der Perioden 0,0 ist, dann gibt ISPMT einen #ZAHL!-Fehler zurück.

    Zusätzliche Informationen:

    • ISPMT berechnet die Zinszahlung für eine Periode mit der Formel:
    [math]\displaystyle{ \text{ISPMT}~=~Investment ~ \times ~ Zinssatz ~ \times ~ \left( \frac{Periode}{Gesamtzahl~der~Perioden} ~-~ 1\right) }[/math]
    • Eine Konsequenz aus der Verwendung dieser Funktion ist die Tatsache, dass die Periode der Funktion ISPMT beachtet werden sollte.
    1. Falls der Tilgungsplan die Zinszahlung für die erste Periode aus dem kompletten Nennwert verlangt (dieser muss gleich [math]\displaystyle{ -Nennwert \times Zinssatz }[/math] sein), dann sollte die Periode für die erste Periode auf 0 gesetzt werden. In anderen Worten liegt in diesem Fall die erwarteten Werte für die Periode im Bereich 0 ≤ PeriodeGesamtzahl der Perioden – 1.
    2. Falls ein anderer Tilgungsplan angewendet wird, so dass die erste Tilgung vor der ersten Zinszahlung geleistet wird, dann sollte die Periode auf 1 für die erste Periode gesetzt werden. In anderen Worten liegt in diesem Fall die erwarteten Werte für die Periode im Bereich 1 ≤ PeriodeGesamtzahl der Perioden.
    • Für ein Investment dieser Art ist die konstante Tilgung [math]\displaystyle{ \frac {Investment}{Gesamtzahl~der~Perioden} }[/math] Währungseinheiten.
    • Beachten Sie, dass ISPMT eine konstante Tilgung, aber variable Zinsen unterstellt. Das ist der Unterschied zur Funktion ZINSZ, wo die Annuität (Zinsen plus Tilgung) konstant ist.

    Beispiele:

    Bearbeitetes Beispiel für einen kompletten Rückzahlungsplan

    John entscheidet sich, $8.000 für einen Zeitraum von 12 Monaten bei einem jährlichen Zins von 4 % zu leihen. Es gibt keine Restschuld am Ende der Laufzeit. Das Darlehen ist darauf ausgelegt, dass die monatlichen Zinszahlungen vom Barwert am Ende des vorangegangenen Monats berechnet werden.Die folgende Tabelle zeigt seinen Tilgungsplan.

    A B C D
    1 Darlehenssumme $8.000
    2 jährliche Rate 4%
    3
    4 Monat Restwert Nennwert ISPMT
    5 1 $8.000,00 -$666,67 −26,67
    6 2 $7.333,33 -$666,67 −24,44
    7 3 $6.666,67 -$666,67 −22,22
    8 4 $6.000,00 -$666,67 −20,00
    9 5 $5.333,33 -$666,67 −17,78
    10 6 $4.666,67 -$666,67 −15,56
    11 7 $4.000,00 -$666,67 −13,33
    12 8 $3.333,33 -$666,67 −11,11
    13 9 $2.666,67 -$666,67 −8,89
    14 10 $2.000,00 -$666,67 −6,67
    15 11 $1.333,33 -$666,67 −4,44
    16 12 $666,67 -$666,67 −2,22
    17
    18 SUMME -$8.000,00 −173,33

    Die Zellen B5:D16 enthalten die folgenden Formeln:

    • Zelle B5 enthält die Formel =$B$1.
    • Zelle B6 enthält die Formel = $B5 + $C6, Zelle B7 die Formel = $B6 + $C7 und so weiter für die Zellen B8:B16.
    • Die Zellen C5:C16 enthalten alle die Formel =-$B$1/$A$16.
    • Zelle D5 enthält die Formel =ISPMT($B$2/12; $A5-1; $A$16; $B$1); Zelle D6 enthält die Formel =ISPMT($B$2/12; $A6-1; $A$16; $B$1) und so weiter für die Zellen D7:D16.

    Die Daten in der obigen Tabelle haben folgende entscheidende Eigenschaften:

    • In allen Aufrufen der Funktion ISPMT ist das erste Argument $B$2/12. Die Division durch 12 macht aus dem jährlichen Zinssatz ein monatliches Äquivalent um zur Länge der Periode zu passen.
    • In allen Aufrufen der Funktion ISPMT ist das zweite Argument wie das der aktuellen Periode minus 1. Dieser Ansatz stellt sicher, dass der ZIns in der ersten (und den folgenden) Periode(n) aus dem Barwert der vorangehenden Periode berechnet wird.
    • Beachten Sie, dass der $-Vorsatz in Zelle B1 bewirkt, dass die Werte in den Zellen B5:C16 auch als Währung angezeigt werden. Die Werte aus der Funktion ISPMT in den Zellen D5:D16 werden nicht automatisch als Währung dargestellt.
    • Der Wert −173,33 in Zelle D18 ist berechnet als Summe der Werte in den Zellen D5:D16 und stellt damit den kompletten Zinsbetrag aus der gesamten Laufzeit des Darlehens dar.

    andere Beispiele

    Formel Beschreibung Ergebnis
    =ISPMT(0,01; 1; 24; 120000)

    Hier berechnet die Funktion die Zinsen aus dem ersten Monat für ein Darlehen in Höhe von 120.000 Währungseinheiten mit einer Laufzeit von zwei Jahren, monatlicher Zahlweise, konstanter Tilgung und einem jährlichen Zinssatz von 12%. Für dieses Beispiel wird angenommen, dass der Zins für den ersten Monat nach der ersten Tilgung ($5.000) berechnet wird. Die Funktion gibt dafür −1.150 Währungseinheiten zurück.

    −1150
    =ISPMT(0,01; 18; 24; 120000)

    Hier berechnet die Funktion die Zinsen aus dem achtzehnten Monat für ein Darlehen in Höhe von 120.000 Währungseinheiten mit einer Laufzeit von zwei Jahren, monatlicher Zahlweise, konstanter Tilgung und einem jährlichen Zinssatz von 12%. Für dieses Beispiel wird angenommen, dass der Zins für den ersten Monat nach der ersten Tilgung ($5.000) berechnet wird. Die Funktion gibt dafür −300 Währungseinheiten zurück.

    −300
    =ISPMT(0,01; 24; 24; 120000)

    Hier berechnet die Funktion die Zinsen aus dem letzten Monat für ein Darlehen in Höhe von 120.000 Währungseinheiten mit einer Laufzeit von zwei Jahren, monatlicher Zahlweise, konstanter Tilgung und einem jährlichen Zinssatz von 12%. Für dieses Beispiel wird angenommen, dass der Zins für den ersten Monat nach der ersten Tilgung ($5.000) berechnet wird. Die Funktion gibt dafür 0 Währungseinheiten zurück, was zu erwarten war, da in diesem letzten Monat der Barwert auf 0 gesunken ist.

    0

    Ähnliche LibreOffice Funktionen:

    ZW

    ZZR

    RMZ

    BW

    ZINS

    ODF Standard:

    Kapitel 6.12.25, Teil 2.

    Betroffene (oder ähnliche) EXCEL-Funktionen:

    ISPMT