Documentatie/Calc-functies/ISBET

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/ISPMT and the translation is 100% complete.
    Other languages:

    Functienaam:

    ISBET

    Categorie:

    Financieel

    Samenvatting:

    Berekent de verschuldigde rente voor een specifieke periode van een investering of lening met vaste rente, ervan uitgaande dat in elke periode hetzelfde bedrag aan kapitaal wordt terugbetaald. De in een bepaalde periode verschuldigde rente is afhankelijk van het op dat moment openstaande saldo en neemt gedurende de looptijd af.

    Syntaxis:

    ISBET(Wisselkoers; Periode; Gehele termijn; Investering)

    Retourneert:

    Retourneert een reëel getal, dat de waarde is van de verschuldigde rente in de opgegeven periode voor de gegeven investering of lening. De geretourneerde waarde is negatief voor betalingen en positief voor stortingen. Het geretourneerde getal is in dezelfde munteenheid als de opgegeven investeringswaarde.

    Argumenten:

    Wisselkoers is een reëel getal (uitgedrukt als een percentage, zoals 2,5% of een decimale breuk, zoals 0,025) of een verwijzing naar een cel die dat getal bevat, wat de periodieke rentevoet is. Het is gebruikelijk dat rentetarieven jaarlijks worden genoteerd en, waar nodig, moet ervoor worden gezorgd dat dergelijke waarden worden omgerekend zodat ze compatibel zijn met de lengte van uw betalingsperiode.

    Periode is een reëel getal of een verwijzing naar een cel die dat getal bevat, wat de specifieke periode is waarvoor de rente wordt berekend.

    Gehele termijn is een reëel getal dat niet nul is of een verwijzing naar een cel die dat getal bevat, het aantal betalingstermijnen in de termijn.

    Investering is een reëel getal of een verwijzing naar een cel die dat getal bevat, wat de contante waarde is van het geleende of geïnvesteerde bedrag.

    • Als een argument niet-numeriek is, retourneert ISBET als foutcode #WAARDE!.
    • Als Gehele termijn gelijk is aan 0,0, dan retourneert ISBET als foutcode #GETAL!.

    Aanvullende details:

    • ISBET berekent de rentebetaling voor elke periode met behulp van de formule:
    [math]\displaystyle{ \text{ISBET}~=~Investering ~ \times ~ Wisselkoers ~ \times ~ \left( \frac{Periode}{Gehele~termijn} ~-~ 1\right) }[/math]
    • Een consequentie van het gebruik van de bovenstaande formule is dat er voorzichtig moet worden omgegaan met de waarde die wordt doorgegeven aan ISBET in het argument Periode.
    1. Als het aflossingsschema vereist dat de rentebetaling voor de eerste periode wordt gebaseerd op de volledige waarde van het argument Investering (en dus gelijk is aan [math]\displaystyle{ -Investering \times Wisselkoers }[/math]), dan het argument Periode moet voor de eerste periode op 0 worden gezet. Met andere woorden, voor dit geval liggen de verwachte waarden van Periode in het bereik 0 ≤ PeriodeGehele termijn – 1.
    2. Als er een ander aflossingsschema van toepassing is, zodat de eerste kapitaalaflossing wordt gedaan voordat de rentebetaling voor de eerste betaling wordt berekend, dan moet het argument Periode op 1 worden gezet voor de eerste periode. Met andere woorden, voor dit geval liggen de verwachte waarden van Periode in het bereik 1 ≤ PeriodeGehele termijn.
    • Voor een investering van dit type is de constante periodieke hoofdsombetaling [math]\displaystyle{ \frac {Investering}{Gehele~termijn} }[/math] valuta-eenheden.
    • Merk op dat ISBET uitgaat van constante periodieke hoofdsommen maar variabele periodieke rentebedragen. Dit verschilt van de functie IBET, waarbij het totale verschuldigde bedrag per periode (rente plus kapitaal) constant is.

    Voorbeelden:

    Uitgewerkt voorbeeld voor volledig aflossingsschema

    John besluit $8.000 te lenen over een periode van 12 maanden tegen een jaarlijkse rente van 4%. Aan het einde van de lening is er geen kassaldo meer. De lening is zo gestructureerd dat de maandelijkse rentebetalingen worden berekend op basis van het uitstaande kapitaalsaldo aan het eind van de voorgaande maand. De volgende tabel toont het schema voor zijn aflossingen.

    A B C D
    1 Leenbedrag $8.000
    2 Jaarlijkse rente 4%
    3
    4 Maand Vorige
    Balans
    Hoofdsom
    Betaling
    ISBET
    5 1 $8.000,00 -$666,67 −26,67
    6 2 $7.333,33 -$666,67 −24,44
    7 3 $6.666,67 -$666,67 −22,22
    8 4 $6.000,00 -$666,67 −20,00
    9 5 $5.333,33 -$666,67 −17,78
    10 6 $4.666,67 -$666,67 −15,56
    11 7 $4.000,00 -$666,67 −13,33
    12 8 $3.333,33 -$666,67 −11,11
    13 9 $2.666,67 -$666,67 −8,89
    14 10 $2.000,00 -$666,67 −6,67
    15 11 $1.333,33 -$666,67 −4,44
    16 12 $666,67 -$666,67 −2,22
    17
    18 SOM -$8.000,00 −173,33

    Cellen B5:D16 bevatten de volgende formules:

    • Cel B5 bevat de formule =$B$1.
    • Cel B6 bevat de formule =$B5+$C6; cel B7 bevat de formule =$B6+$C7; enzovoort voor cellen B8:B16.
    • Cells C5:C16 all contain the formula =-$B$1/$A$16.
    • Cel D5 bevat de formule =ISBET($B$2/12; $A5-1; $A$16; $B$1); cel D6 bevat de formule =ISBET($B$2/12; $A6-1; $A$16; $B$1); enzovoort voor cellen D7:D16.

    Belangrijke kenmerken van de gegevens in de bovenstaande tabel zijn:

    • Bij alle aanroepen van de functie ISBET is het eerste argument $B$2/12. De deling door 12 converteert het jaarlijkse rentepercentage naar een maandelijks equivalent dat overeenkomt met de lengte van de periode.
    • Bij alle aanroepen van de functie ISBET wordt het tweede argument doorgegeven als het werkelijke periodenummer minus 1. Deze benadering zorgt ervoor dat de interesse in de eerste (en volgende) perioden is gebaseerd op het kapitaalsaldo aan het einde van de vorige periode.
    • Merk op dat de opname van het voorvoegsel dollar ($) in cel B1 ertoe leidt dat de waarden in cellen B5:C16 ook worden weergegeven als valutawaarden. De uitvoer van de functie ISBET die wordt weergegeven in cellen D5:D16, wordt echter niet standaard weergegeven als valutawaarden.
    • De waarde −173,33 in cel D18 wordt berekend als de som van de waarden in cellen D5:D16 en vertegenwoordigt daarom de totale betaalde rente tijdens de looptijd van de lening.

    Andere voorbeelden

    Formule Beschrijving Retourneert
    =ISBET(0,01; 1; 24; 120000)

    Hier berekent de functie de verschuldigde rente in de eerste maand voor een lening van 120.000 valutaeenheden met een looptijd van twee jaar, maandelijkse terugbetalingsperioden, constante kapitaalaflossingen elke maand en een jaarlijkse rentevoet van 12%. In dit voorbeeld wordt aangenomen dat de rentebetaling van de eerste maand wordt berekend nadat de eerste kapitaalbetaling ($5.000) is gedaan. De functie retourneert een waarde van −1.150 valuta-eenheden.

    −1150
    =ISBET(0,01; 18; 24; 120000)

    Hier berekent de functie de verschuldigde rente in de achttiende maand voor een lening van 120.000 valutaeenheden met een looptijd van twee jaar, maandelijkse terugbetalingsperioden, constante kapitaalaflossingen per maand en een jaarlijkse rentevoet van 12%. In dit voorbeeld wordt aangenomen dat de rentebetaling van een maand wordt berekend nadat de kapitaalbetaling voor die maand ($5.000) is gedaan. De functie retourneert een waarde van −300 valuta-eenheden.

    −300
    =ISBET(0,01; 24; 24; 120000)

    Hier berekent de functie de verschuldigde rente in de laatste maand voor een lening van 120.000 valutaeenheden met een looptijd van twee jaar, maandelijkse terugbetalingsperioden, constante kapitaalaflossingen elke maand en een jaarlijkse rentevoet van 12%. In dit voorbeeld wordt aangenomen dat de rentebetaling van een maand wordt berekend nadat de kapitaalbetaling voor die maand ($5.000) is gedaan. De functie retourneert een waarde van 0 valuta-eenheden, wat verwacht wordt omdat de aflossing van het kapitaal in deze laatste maand het saldo terugbrengt tot 0.

    0

    Gerelateerde LibreOffice-functies:

    TW

    NPER

    AFLOSSING

    HW

    RENTE

    ODF standaard:

    Sectie 6.12.25, deel 2

    Gerelateerde (of gelijkwaardige) Excel-functies:

    ISPMT