Jump to content

Documentazione/Funzioni di Calc/ISPMT

From The Document Foundation Wiki
This page is a translated version of the page Documentation/Calc Functions/ISPMT and the translation is 100% complete.

Nome funzione:

INTERESSE.RATA

Categoria:

Analisi finanziaria

Riepilogo:

Calcola gli interessi dovuti per un periodo specifico di un investimento o prestito a tasso fisso, assumendo che lo stesso importo di capitale venga rimborsato in ogni periodo. Gli interessi dovuti in un dato periodo dipendono dal saldo residuo in quel momento e diminuiranno nel corso del tempo.

Sintassi:

INTERESSE.RATA(Tasso; Periodo; Periodi totali; Investimento)

Restituisce:

Restituisce un numero reale, che rappresenta il valore degli interessi dovuti nel periodo specificato per l'investimento o il prestito indicato. Il valore restituito è negativo per i pagamenti e positivo per i depositi. Il numero restituito è nella stessa unità di valuta del valore dell'investimento specificato.

Argomenti:

Tasso è un numero reale (espresso come percentuale, ad esempio 2,5%, o come frazione decimale, ad esempio 0,025), oppure un riferimento a una cella contenente tale numero, che rappresenta il tasso di interesse periodico. È comune che i tassi di interesse siano espressi su base annua e, se necessario, è importante convertirli affinché siano compatibili con la durata del periodo di pagamento.

Periodo è un numero reale o un riferimento a una cella contenente quel numero, che rappresenta il periodo specifico per il quale viene calcolato l'interesse.

Periodi totali è un numero reale diverso da zero oppure un riferimento a una cella contenente tale numero, che rappresenta il numero di periodi di pagamento nel termine.

Investimento è un numero reale o un riferimento a una cella contenente quel numero, che rappresenta il valore attuale dell'importo preso in prestito o investito.

  • Se uno qualsiasi degli argomenti non è numerico, INTERESSE.RATA segnala un errore #VALORE!.
  • Se Totale periodi è uguale a 0,0, allora INTERESSE.RATA restituisce un errore #NUM!.

Dettagli aggiuntivi:

  • INTERESSE.RATA calcola il pagamento degli interessi per qualsiasi periodo utilizzando la formula:
[math]\displaystyle{ \text{ISPMT}~=~Investimento ~ \times ~ Tasso ~ \times ~ \left( \frac{Periodo}{Totale~periodi} ~-~ 1\right) }[/math]
  • Una conseguenza dell'utilizzo della formula di cui sopra è che occorre prestare attenzione al valore passato a INTERESSE.RATA nell'argomento Periodo.
  1. Se il piano di rimborso richiede che il pagamento degli interessi per il primo periodo si basi sul valore totale dell'argomento Investimento (e quindi sia uguale a [math]\displaystyle{ -Investimento \times Tasso }[/math]), allora l'argomento Periodo dovrebbe essere impostato a 0 per il primo periodo. In altre parole, in questo caso i valori attesi di Periodo sono compresi nell'intervallo 0 ≤ PeriodoPeriodo totale - 1.
  2. Se si applica un piano di rimborso diverso, in modo che il primo rimborso del capitale venga effettuato prima del calcolo degli interessi per il primo pagamento, l'argomento Periodo deve essere impostato a 1 per il primo periodo. In altre parole, in questo caso i valori attesi di Periodo sono compresi nell'intervallo 1 ≤ PeriodoPeriodo totale.
  • Per un investimento di questo tipo, il pagamento periodico costante del capitale è pari a [math]\displaystyle{ \frac {Investimento}{Totale~periodi} }[/math] unità di valuta.
  • Si noti che INTERESSE.RATA presuppone importi di capitale periodici costanti ma interessi periodici variabili. Questa funzione è diversa dalla funzione INTERESSI, in cui l'importo totale dovuto per ciascun periodo (interessi più capitale) è costante.

Esempi:

Esempio pratico per il piano di rimborso completo

John decide di prendere in prestito $8 000 per un periodo di 12 mesi a un tasso di interesse annuo del 4%. Alla fine del prestito non rimane più liquidità. Il prestito è strutturato in modo che gli interessi mensili siano calcolati in base al saldo capitale residuo alla fine del mese precedente. La tabella seguente mostra il piano di rimborso.

A B C D
1 Ammontare del prestito $8 000
2 Rata annuale 4%
3
4 Mese Precedente
Saldo
Pagamento
principale
INTERESSE.RATA
5 1 $8 000,00 -$666,67 −26,67
6 2 $7 333,33 -$666,67 −24,44
7 3 $6 666,67 -$666,67 −22,22
8 4 $6 000,00 -$666,67 −20,00
9 5 $5 333,33 -$666,67 −17,78
10 6 $4 666,67 -$666,67 −15,56
11 7 $4 000,00 -$666,67 −13,33
12 8 $3 333,33 -$666,67 −11,11
13 9 $2 666,67 -$666,67 −8,89
14 10 $2 000,00 -$666,67 −6,67
15 11 $1 333,33 -$666,67 −4,44
16 12 $666,67 -$666,67 −2,22
17
18 SOMMA -$8 000,00 −173,33

Le celle B5:D16 contengono le seguenti formule:

  • La cella B5 contiene la formula =$B$1.
  • La cella B6 contiene la formula =$B5+$C6; la cella B7 contiene la formula =$B6+$C7; e così via per le celle B8:B16.
  • Le celle C5:C16 contengono tutte la formula =-$B$1/$A$16.
  • La cella D5 contiene la formula =INTERESSE.RATA($B$2/12; $A5-1; $A$16; $B$1); la cella D6 contiene la formula =INTERESSE.RATA($B$2/12; $A6-1; $A$16; $B$1); e così via per le celle D7:D16.

Le caratteristiche significative dei dati nella tabella sopra includono:

  • In tutte le chiamate alla funzione INTERESSE.RATA, il primo argomento è $B$2/12. La divisione per 12 converte il tasso di interesse annuo in un equivalente mensile corrispondente alla durata del periodo.
  • In tutte le chiamate alla funzione INTERESSE.RATA, il secondo argomento viene passato come numero del periodo effettivo meno 1. Questo approccio garantisce che gli interessi nel primo periodo (e nei successivi) siano basati sul saldo capitale alla fine del periodo precedente.
  • Si noti che l'inclusione del prefisso dollaro ($) nella cella B1 comporta la visualizzazione dei valori nelle celle B5:C16 anche come valori di valuta. Tuttavia, i risultati della funzione INTERESSE.RATA visualizzati nelle celle D5:D16 non vengono visualizzati come valori di valuta per impostazione predefinita.
  • Il valore −173,33 nella cella D18 viene calcolato come la somma dei valori nelle celle D5:D16 e rappresenta quindi l'interesse totale pagato durante la durata del prestito.

Altri esempi

Formula Descrizione Restituisce
=INTERESSE.RATA(0,01; 1; 24; 120000)

Calcola gli interessi dovuti nel primo mese per un prestito di 120 000 unità di valuta con una durata di due anni, rate mensili, rate di capitale costanti ogni mese e un tasso di interesse annuo del 12%. In questo esempio, si presume che il pagamento degli interessi del primo mese venga calcolato dopo il primo pagamento di capitale ($5 000). La ​​funzione restituisce un valore di −1 150 unità di valuta.

−1150
=INTERESSE.RATA(0,01; 18; 24; 120000)

Calcola gli interessi dovuti nel diciottesimo mese per un prestito di 120 000 unità di valuta con una durata di due anni, rate mensili, rimborso del capitale costante ogni mese e un tasso di interesse annuo del 12%. In questo esempio, si presume che il pagamento degli interessi di un mese venga calcolato dopo il pagamento del capitale per quel mese ($5 000). La ​​funzione restituisce un valore di −300 unità di valuta.

−300
=INTERESSE.RATA(0,01; 24; 24; 120000)

Calcola gli interessi dovuti nell'ultimo mese per un prestito di 120 000 unità di valuta con una durata di due anni, rate mensili, rimborso del capitale costante ogni mese e un tasso di interesse annuo del 12%. In questo esempio, si presume che il pagamento degli interessi di un mese venga calcolato dopo il pagamento del capitale per quel mese ($5 000). La ​​funzione restituisce un valore di 0 unità di valuta, come previsto perché il rimborso del capitale in questo ultimo mese riduce il saldo a 0.

0

Funzioni di LibreOffice correlate:

VAL.FUT

NUM.RATE

RATA

VA

TASSO

Standard ODF:

Section 6.12.25, part 2

Funzioni equivalenti (o simili) di Excel:

ISPMT