Dokumentation/Calc Funktionen/MLAUFZEIT

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/MDURATION and the translation is 100% complete.
    Other languages:

    Funktionsname:

    MLAUFZEIT

    Kategorie:

    Finanzmathematik

    Zusammenfassung:

    Berechnet die modifizierte Laufzeit eines festverzinslichen Wertpapiers in Jahren.

    Die modifizierte Laufzeit ähnelt der Macaulay Duration wie sie bei der Funktion LAUFZEIT berechnet wird. Der modifizierten Laufzeit wird unterstellt, dass sie den Kurswert besser darstellt und sensibler auf Änderungen im Zinssatz reagiert.

    Syntax:

    MLAUFZEIT(Wertstellung; Endfälligkeit; Zinssatz; Rendite; Zinshäufigkeit[; Basis])

    Rückgabewerte:

    Gibt die modifizierte Laufzeit des spezifizierten Wertpapieres als positive Dezimalzahl in Jahren zurück.

    Argumente:

    Wertstellung ist ein Datum (in Anführungszeichen) oder ein Zeitstempel oder eine Referenz auf eine Zelle mit einer dieser Typen. Dieses Datum sagt uns, wann der Kauf "abgerechnet" wird. An diesem Datum überträgt der Verkäufer das Wertpapier an den Käufer und der Käufer zahlt den vereinbarten Preis an den Verkäufer.

    Endfälligkeit ist ein Datum (in Anführungszeichen) oder ein Zeitstempel oder eine Referenz auf eine Zelle mit einer dieser Typen. Dieses Datum sagt uns, wann das Wertpapier fällig ist. Bei Endfälligkeit zahlt der Emittent der Wertpapiers dem Inhaber des Wertpapiers den vollen Wert des Papiers.

    Zinssatz ist eine positive Dezimalzahl (ausgedrückt als Prozentsatz wie z. Bsp. 2,5 % oder als Dezimalzahl wie z. Bsp. 0,025) oder eine Referenz auf die Zelle welche den jährlichen nominellen Zinssatz des Wertpapiers enthält.

    Rendite ist eine nicht–negative Dezimalzahl (ausgedrückt als Prozentsatz wie z. Bsp. 2,5 % oder als Dezimalbruch wie z. Bsp. 0,025) oder eine Referenz auf die Zelle welche den jährlichen Zinsertrag des Wertpapiers enthält.

    Zinshäufigkeit ist eine positive Ganzzahl oder eine Referenz auf eine Zelle mit dieser Ganzzahl. Diese Zahl ist die Anzahl der Zinszahlungen pro Jahr. Gültige Werte sind 1 (jährlich), 2 (halbjährlich) oder 4 (vierteljährlich).


    Basis ist eine Ganzzahl im Bereich 0 bis 4, welche anzeigt, wie das Jahr berechnet wird. Oder eine Referenz auf eine Zelle, die diese Ganzzahl enthält, wird verwendet. Für mehr Hintergrund Informationen, siehe Wiki unter Zinsberechnungsmethode.

    Basis Berechnung
    0 oder fehlt US-Methode (NASD), 12 Monate je 30 Tage
    1 Exakte Anzahl der Tage im Monat, exakte Anzahl der Tage im Jahr.
    2 Exakte Anzahl der Tage im Monat, Das Jahr hat 360 Tage.
    3 Exakte Anzahl der Tage im Monat, Jahr hat 365 Tage.
    4 Euro-Methode, 12 Monate zu je 30 Tagen.


    • Falls Endfälligkeit oder Wertstellung kein gültiges Datum enthält, gibt MLAUFZEIT einen #WERT!-Fehler zurück
    • Falls Endfälligkeit oder Wertstellung Zeitanteile enthalten, werden diese von MLAUFZEIT ignoriert.
    • Falls die Wertstellung an oder nach der Endfälligkeit liegt, gibt MLAUFZEIT den invalid argument error (Fehler:502) zurück.
    • Falls Zinssatz, Rendite oder Zinshäufigkeit nicht numerisch ist, dann gibt MLAUFZEIT einen #WERT!-Fehler zurück.
    • Falls Basis nicht numerisch ist, gibt MLAUFZEIT einen invalid argument error (Fehler:502) zurück.
    • Falls entweder die Basis oder Zinshäufigleit kein ganzzahliger Wert ist, verkürzt ihn MLAUFZEIT auf einen ganzzahligen Wert.
    • Falls entweder der Zinssatz oder die Rendite kleiner als 0,0 ist, meldet MLAUFZEIT einen invalid argument error (Fehler:502) zurück.
    • Falls nach einer eventuellen Verkürzung Zinshäufigkeit nicht 1, 2 oder 4 ist, gibt MLAUFZEIT einen invalid argument error (Fehler:502) zurück.
    • Falls nach einer eventuellen Verkürzung Basis nicht 0, 1, 2, 3 oder 4 ist, gibt MLAUFZEIT einen invalid argument error (Fehler:502) zurück.

    Zusätzliche Informationen:

    • MLAUFZEIT nutzt die folgende Beziehung, um die modifizierte Laufzeit von der Macaulay Duration zu berechnen:
    [math]\displaystyle{ \text{MLAUFZEIT}~=~\frac{\text{LAUFZEIT}}{1~+~\frac{Rendite}{Zinshäufigkeit}} }[/math]
    wobei unterstellt wird, dass die selben Argumente sowohl an MLAUFZEIT als auch an LAUFZEIT übergeben werden.

    Beispiele:

    Beispielsdaten
    A B C D E F
    1 2022-01-01 2027-01-01 5% 4% 2 1
    Formel Beschreibung Ergebnis
    =MLAUFZEIT(A1; B1; C1; D1; E1; F1) Die modifizeirte Laufzeit für das angegebene Wertpapier ist ungefähr 4,4 Jahre. 4,41113731090512
    =MLAUFZEIT(DATUM(2022; 1; 1); DATUM(2027; 1; 1); 0,05; 0,04; 2)

    Das selbe Wertpapier wie im vorherigen Beispiel, nutzt aber statt dem ausformulierten Datum die Funktion DATUM. Für die (fehlende) Basis wird der Wert 0 angenommen.

    4,41068984757474
    =MLAUFZEIT("2022-01-01"; "2027-01-01"; 0,0; 0,4; 4; 1) Berechnet die modifizierte Laufzeit für das angegebene Wertpapier ohne laufende Zinszahlungen. Gibt den Wert von ungefähr 4,5 Jahren zurück. 4,54586946599726
    =MLAUFZEIT("2001-01-01"; "2006-01-01"; 8%; 9%; 2; 3) Berechnet die modifizierte Laufzeit für das angegebene Wertpapier und gibt ungefähr 4 Jahre zurück. 4,02068710841898

    Ähnliche LibreOffice Funktionen:

    LAUFZEIT

    PLAUFZEIT

    ODF Standard:

    Kapitel 6.12.26, Teil 2.

    Betroffene (oder ähnliche) EXCEL-Funktionen:

    MDURATION