Documentatie/Calc-functies/NETWERKDAGEN.INTL

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/NETWORKDAYS.INTL and the translation is 100% complete.

    TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren

    Other languages:


    Functienaam:

    NETWERKDAGEN.INTL

    Categorie:

    Datum en tijd

    Samenvatting:

    Berekent het netto aantal werkdagen tussen twee datums. Feestdagen (of andere niet-werkdagen) kunnen worden gespecificeerd en de standaard werkweek kan opnieuw worden gedefinieerd

    Syntaxis:

    NETWERKDAGEN.INTL(Begindatum; Einddatum[; [Weekend] [; Feestdagen] ])

    Retourneert:

    Retourneert een geheel getal dat het aantal werkdagen in de opgegeven periode is, exclusief gedefinieerde feestdagen en weekenddagen. De begin- en einddatum van de periode worden geteld, tenzij ze zijn gedefinieerd als vakantie- of weekenddagen.

    Argumenten:

    Begindatum is de datum (tussen aanhalingstekens) of een datum-tijd-serienummer of een verwijzing naar de cel die één van die typen bevat, namelijk de begindatum of de einddatum van de periode waarvoor de berekening moet worden uitgevoerd.

    Einddatum is de datum (tussen aanhalingstekens) of een datum-tijd-serienummer of een verwijzing naar de cel die één van die typen bevat, namelijk de einddatum of de begindatum van de periode waarvoor de berekening moet worden uitgevoerd.


    Weekend is een getal of een tekenreeks of een verwijzing naar de cel die één van die typen bevat, die wordt gebruikt om de standaardwerkweek te definiëren die moet worden gebruikt. De beschikbare numerieke opties bieden een eenvoudige manier om de werkweek te definiëren, met de lijst met mogelijke waarden in de volgende tabel. Waarden 1 tot 7 komen overeen met werkweken met twee niet-werkdagen, terwijl waarden 11 tot 17 overeenkomen met werkweken met één niet-werkdag.

    Getal Niet-werkdagen
    1 of weggelaten Zaterdag en Zondag
    2 Zondag en Maandag
    3 Maandag en Dinsdag
    4 Dinsdag en Woensdag
    5 Woensdag en Donderdag
    6 Donderdag en Vrijdag
    7 Vrijdag en Zaterdag
    11 Alleen Zondag
    12 Alleen Maandag
    13 Alleen Dinsdag
    14 Alleen Woensdag
    15 Alleen Donderdag
    16 Alleen Vrijdag
    17 Alleen Zaterdag

    Het gebruik van een string is een flexibelere methode om de werkweek te definiëren. De string moet uit zeven tekens bestaan – '0' wordt gebruikt om een werkdag aan te geven en '1' wordt gebruikt om een niet-werkdag aan te geven. Elk teken komt overeen met een dag van de week, te beginnen met maandag. De tekenreeks "0100011" definieert bijvoorbeeld dinsdag, zaterdag en zondag als niet-werkdagen.

    Feestdagen is een lijst met data die overeenkomen met feestdagen die niet als werkdagen worden geteld. Deze lijst kan worden doorgegeven als een celbereik met serienummers voor datum en tijd (mogelijk weergegeven in een datumnotatie). Als alternatief kan de lijst worden doorgegeven als een inline matrix met datumreeksen (tussen aanhalingstekens) of datum-tijd-serienummers. Indien weggelaten, worden geen feestdagen verondersteld.

    • Als Begindatum of Einddatum geen geldige datumexpressie is, retourneert NETWERKDAGEN.INTL als fout #WAARDE!.
    • Als Begindatum eerder is dan Einddatum, is het resultaat een positief geheel getal; als Begindatum later is dan Einddatum, is het resultaat een negatief geheel getal.
    • NETWERKDAGEN.INTL negeert alle tijdcomponenten van Begindatum en Einddatum.
    • Als een tekenreeks wordt gebruikt voor het argument Weekend en die tekenreeks niet precies zeven tekens bevat, rapporteert NETWERKDAGEN.INTL een #WAARDE! fout. Als de tekenreeks zeven tekens bevat, maar ten minste één van die tekens is noch een '0' noch een '1', dan retourneert NETWERKDAGEN.INTL als fout Ongeldig argument (Fout:502).
    • Als een getal wordt gebruikt voor het argument Weekend en dat getal is geen geheel getal, dan retourneert NETWERKDAGEN.INTL als fout Ongeldig argument (Fout:502). Als het getal een geheel getal is maar niet in het bereik 1 tot 7 of het bereik 11 tot 17 ligt, retourneert NETWERKDAGEN.INTL als fout #WAARDE!.
    • Als Weekend wordt doorgegeven als celverwijzing en die cel een foutcode bevat (zoals #NAAM?), wordt die foutstatus doorgegeven als resultaat van NETWERKDAGEN.INTL.
    • Als Feestdagen wordt doorgegeven als een inline matrix en de invoer van die matrix is geen datum of een datum-tijd serienummer, dan retourneert NETWERKDAGEN.INTL als fout #WAARDE!.
    • Als Feestdagen wordt doorgegeven als een celbereik, worden in de meeste gevallen cellen die geen datum of een datum-tijd-serienummer bevatten dat binnen de relevante periode ligt, genegeerd. Als een cel echter een foutcode bevat (zoals #NAAM?), wordt die foutstatus doorgegeven als resultaat van NETWERKDAGEN.INTL.

    Aanvullende details:

    Details specifiek voor de functie NETWERKDAGEN.INTL

    NETWERKDAGEN.INTL is inclusief en telt de eerste en laatste dag van de periode (zie #Voorbeelden:).


    Algemene informatie over de datum- en tijdfuncties van Calc

    Note pin.svg

    NB:
    Voor het gemak wordt de informatie in deze subsectie herhaald op alle pagina's die functies beschrijven in de categorie Datum en Tijd.
    • Intern in Calc, een datum/tijd-waarde wordt behandeld als een reëel getal en dit wordt soms aangeduid met de term datum-tijd serienummer. 2021-02-08 12:00:00 komt bijvoorbeeld overeen met het datum-tijd serienummer 44235.5. Het gehele deel van een datum-tijd-serienummer (vóór de komma) is het aantal dagen sinds een gedefinieerde startdatum. Het fractionele deel van een datum-tijd-serienummer (achter de komma) is de tijd van de dag uitgedrukt als een fractie van een dag. 0,25 is bijvoorbeeld gelijk aan 06:00:00 en 0,75 is gelijk aan 18:00:00.
    • Calc gebruikt 1899-12-30 als standaard startdatum (dag 0) maar u kunt naar Extra ▸ Opties ▸ LibreOffice Calc ▸ Berekenen gaan om alternatieve startdatums te selecteren; we raden u echter aan deze instelling niet te wijzigen, tenzij u specifieke vereisten heeft voor compatibiliteit met oudere werkbladtoepassingen. Als u cellen met datumwaarden kopieert en plakt tussen verschillende werkbladen, controleer dan of beide documenten zijn ingesteld om dezelfde startdatum te gebruiken om onverwachte wijzigingen in de weergegeven datums te voorkomen.
    • Negatieve datum-tijd serienummers komen overeen met datums eerder dan de startdatum van Calc. Calc berekent alle datums terug tot 15 oktober 1582 met behulp van de Gregorian calendar. De dag ervoor is 4 oktober 1582 en Calc gebruikt de Julian calendar voor eerdere data.
    • Een serienummer voor datum en tijd is hetzelfde als elk ander getal, behalve dat we er meestal voor kiezen om het in de vorm van een datum/tijd weer te geven. U kunt een getal in een cel invoeren en vervolgens de opmaak van de cel wijzigen om de waarde als datum/tijd weer te geven. U kunt ook een datum/tijd in een cel invoeren en vervolgens de opmaak van de cel wijzigen om het datum-tijd-serienummer weer te geven.
    • Voor de duidelijkheid: de beschrijvingen van de Calc-functies op deze wiki-pagina's gebruiken het standaard ISO 8601-formaat voor datum en tijd omdat dit onafhankelijk moet zijn van de door u geselecteerde landinstellingen. Het standaard datumformaat op uw computer kan anders zijn. Bij het invoeren van datums als onderdeel van formules, kunnen schuine strepen of streepjes die als datumscheidingsteken worden gebruikt, worden geïnterpreteerd als rekenkundige operatoren. Daarom worden datums die in dit formaat zijn ingevoerd, niet herkend als datums en resulteren in foutieve berekeningen. Om te voorkomen dat datums worden geïnterpreteerd als onderdelen van formules, gebruikt u de functie DATUM of plaatst u de datum tussen aanhalingstekens en gebruikt u de ISO 8601-notatie. Vermijd het gebruik van locale-afhankelijke datumnotaties die fouten kunnen veroorzaken als het document onder verschillende locale-instellingen wordt geladen.
    • Tijdzone-informatie wordt niet gebruikt door de datum- en tijdfuncties van Calc.
    • Als u alleen twee cijfers van het jaar wilt invoeren (bijvoorbeeld 21 in plaats van 2021), moet Calc weten of u 2021 of 1921 bedoelt. Ga naar Extra ▸ Opties ▸ LibreOffice ▸ Algemeen om het bereik van jaren te bekijken of aan te passen dat Calc zal gebruiken om tweecijferige jaarwaarden te interpreteren.
    • Calc bevat logica om te beslissen hoe tekst moet worden behandeld wanneer het wordt aangetroffen als een opdrachtelement in een rekenkundige bewerking of als een argument voor een functie die in plaats daarvan een getal verwacht. In deze context is eenduidige conversie mogelijk voor ISO 8601 datums en tijden in hun uitgebreide formaten met scheidingstekens. De eenvoudige formule =1 + "2021-02-08" geeft bijvoorbeeld meestal het resultaat 2021-02-09 (wanneer opgemaakt als een datum). Deze logica kan echter worden beïnvloed door de instellingen in het dialoogvenster Gedetailleerde berekeningsinstellingen, toegankelijk door Extra ▸ Opties ▸ LibreOffice Calc ▸ Formule te selecteren en op de knop Details te drukken in het gebied "Gedetailleerde berekeningsinstellingen". Als een #WAARDE! fout optreedt, kan het zijn dat de optie Algemene fout #WAARDE! is geselecteerd, in welk geval u moet experimenteren met één van de andere opties in de keuzelijst Van tekst naar getal converteren.

    Voorbeelden:

    Gegevens voor voorbeelden
    A B C D E F G H
    1 Begin/Einddatums   Feestdagen   Weekend
    2 2020-01-01 Opgemaakt als tekst, zonder dubbele aanhalingstekens 0000011
    3 2020-12-31 2020-01-01
    4 2020-04-10 Opgemaakt als Algemeen nummer 11
    5 2020-04-13
    6 2020-05-08
    7 2020-05-25
    8 2020-08-31
    9 2020-12-25
    10 2020-12-28
    Formule Beschrijving Retourneert
    =NETWERKDAGEN.INTL("2021-02-18"; "2021-02-19") Retourneert 2 werkdagen, gebaseerd op de opgegeven begin- en einddatum, geen feestdagen en de standaard vijfdaagse werkweek. Dit eenvoudige voorbeeld toont het inclusieve karakter van de telling. 2
    =NETWERKDAGEN.INTL("2020-12-31"; "2020-01-01") Werkdagen in het jaar 2020. De negatieve waarde geeft aan dat de Begindatum later is dan de Einddatum. −262
    =NETWERKDAGEN.INTL("2020-01-01"; "2020-12-31"; 5) Een vijfdaagse werkweek (met woensdag en donderdag als niet-werkdagen). 260
    =NETWERKDAGEN.INTL("2020-01-01"; "2020-12-31";; {"2020-01-01"; "2020-04-10"; "2020-04-13"; "2020-05-08"; "2020-05-25"; "2020-08-31"; "2020-12-25"; "2020-12-28"}) Acht opgegeven vakantiedatums en de standaard vijfdaagse werkweek. Er is een extra scheidingsteken opgenomen om aan te geven dat het argument Weekend is weggelaten. 254
    =NETWERKDAGEN.INTL(B2; B3; H2; E3:E10) Gelijk aan het vorige voorbeeld, met behulp van de bovenstaande gegevenstabel; cel H2 bevat de waarde 0000011, opgemaakt als tekstwaarde zonder dubbele aanhalingstekens. 254
    =NETWERKDAGEN.INTL(B2; B3; H4; E3:E10) Vergelijkbaar met het vorige voorbeeld, maar het Weekend bestaat alleen op zondag; cel H4 bevat de numerieke waarde 11. 306
    =NETWERKDAGEN.INTL("2020-01-01"; "2020-12-31"; "0000111") Een vierdaagse werkweek (maandag tot en met donderdag). 210
    =NETWERKDAGEN.INTL(43831; 43861; "1000111"; { 43845; 43852 }) 43831, 43861, 43845 en 43852 zijn de datum-tijd serienummers voor respectievelijk de datums 2020-01-01, 2020-01-31, 2020-01-15 en 2020-01-22. Twee feestdagen binnen de periode en een driedaagse werkweek (dinsdag, woensdag en donderdag). 12

    Gerelateerde LibreOffice-functies:

    NETTO.WERKDAGEN

    NETTO.WERKDAGEN_EXCEL2003

    ODF standaard:

    Geen

    Gerelateerde (of gelijkwaardige) Excel-functies:

    NETWORKDAYS.INTL sinds v.2010


    Retrieved from "https://wiki.documentfoundation.org/index.php?title=Documentation/Calc_Functions/NETWORKDAYS.INTL/nl&oldid=775539"