Documentación/Funciones de Calc/DIAS.LAB.INTL

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/NETWORKDAYS.INTL and the translation is 94% complete.
    Outdated translations are marked like this.
    Other languages:


    Nombre de la función:

    DIAS.LAB.INTL

    Categoría:

    Fecha y hora

    Resumen:

    Calcula el número neto de días laborables o hábiles entre dos fechas. Se pueden especificar vacaciones (u otros días no laborables) y se puede redefinir la semana laboral estándar.

    Sintaxis:

    DIAS.LAB.INTL(FechaInicio; FechaFinal[; [Fin de semana] [; Vacaciones] ])

    Devuelve:

    Devuelve un valor entero, que es el número de días laborables o laborables en el período determinado, sin incluir días festivos definidos y fines de semana. Se computan las fechas de inicio y finalización del periodo, a menos que se definan como festivos o fines de semana.

    Argumentos:

    FechaInicio es la fecha (entre comillas) o un número de serie de fecha y hora, o una referencia a la celda que contiene uno de esos tipos, que es la fecha de inicio o la fecha de finalización del periodo para el cual se va a realizar el calculo.

    FechaFinal es la fecha (entre comillas) o un número de serie de fecha y hora, o una referencia a la celda que contiene uno de esos tipos, que es la fecha de finalización o la fecha de inicio del periodo para el cual se va a realizar el calculo.


    Fin de semana es un número o una cadena, o una referencia a la celda que contiene uno de esos tipos, que se usa para definir la semana laboral estándar que se usará. Las opciones numéricas disponibles proporcionan una forma sencilla de definir la semana laboral, con la lista de valores posibles que se proporciona en la siguiente tabla. Los valores del 1 al 7 corresponden a semanas laborales con dos días no laborables, mientras que los valores 11 a 17 corresponden a semanas laborales con un día no laborable.

    Número Días no laborables
    1 u omitido Sábado y domingo
    2 Domingo y lunes
    3 Lunes y martes
    4 Martes y miércoles
    5 Miércoles y jueves
    6 Jueves y viernes
    7 Viernes y sábado
    11 Solo domingo
    12 Solo lunes
    13 Solo martes
    14 Solo miércoles
    15 Solo jueves
    16 Solo viernes
    17 Solo sábados

    Usar una cadena es un método más flexible para definir la semana laboral. La cadena debe tener siete dígitos: '0' se usa para indicar un día laborable y '1' se utiliza para indicar un día no laborable. Cada dígito corresponde a un día de la semana, comenzando por el lunes. Por ejemplo, la cadena "0100011" definiría martes, sábado y domingo como días no laborables.

    Vacaciones es una lista de fechas correspondientes a días festivos que no se cuentan como días laborables. Esta lista se puede pasar como un rango de celdas que contienen números de serie de fecha y hora (posiblemente mostrados en un formato de fecha). Como alternativa, la lista se puede pasar como una matriz en línea que contiene cadenas de fecha (entre comillas) o números de serie de fecha y hora. Si se omite, no se asumen vacaciones.

    • Si FechaInicio o FechaFinal no son expresiones de fechas válidas, DIAS.LAB.INTL mostrará el error #¡VALOR!.
    • Si FechaInicio es anterior a FechaFinal, el resultado es un entero positivo; si FechaInicio es posterior a FechaFinal, el resultado es un entero negativo.
    • DIAS.LAB.INTL ignora cualquier componente de hora de FechaInicio y FechaFinal.
    • Si se usa una cadena para el argumento FinesDeSemana DIAS.LAB.INTL y esa cadena no contiene exactamente siete caracteres, mostrará el error #¡VALOR!. Si la cadena contiene siete caracteres, pero al menos uno de esos caracteres no es un '0' ni un '1', DIAS.LAB.INTL mostrará un error de argumento no válido (Err:502).
    • Si se usa un número para el argumento FinesDeSemana y ese número no es un valor entero, DIAS.LAB.INTL mostrará un error de argumento no válido (Err:502). Si el número es un valor entero pero no se encuentra en el rango de 1 a 7 ni en el rango de 11 a 17, DIAS.LAB.INTL mostrará el error #¡VALOR!.
    • Si Vacaciones se pasa como referencia de celda y esa celda contiene un código de error (como #¿NOMBRE?), ese estado de error se propagará como resultado de DIAS.LAB.INTL.
    • Si Vacaciones se pasa como una matriz en línea, y cualquier entrada de esa matriz no es ni una fecha ni un número de serie de fecha y hora, entonces DIAS.LAB.INTL mostrará el error #¡VALOR!.
    • Si Vacaciones se pasa como un rango de celdas, en la mayoría de los casos se ignorarán las celdas que no contengan ni una fecha ni un número de serie de fecha y hora dentro del período relevante. Sin embargo, si una celda contiene un código de error (como #¿NOMBRE?), ese estado de error se propagará como resultado de DIAS.LAB.INTL.

    Detalles adicionales:

    Detalles específicos de la función DIAS.LAB.INTL

    DIAS.LAB.INTL es inclusivo, contando el primer y último día del periodo (ver #Ejemplos:).


    Información general sobre las funciones de fecha y hora de Calc

    Note pin.svg

    Nota:
    Para mayor comodidad, la información de esta subsección se repite en todas las páginas que describen funciones en la categoría Fecha y hora.

    • Internamente, Calc trata a valores de fecha-hora como números reales, y esto a veces se denomina con el término de número de serie de fecha-hora. Por ejemplo, 2021-02-08 12:00:00 corresponde al número de serie de fecha-hora 44235.5. La parte entera de un número de serie de fecha-hora (antes del punto decimal) es el número de días desde una fecha de inicio definida. La parte fraccionaria de un número de serie de fecha-hora (después del punto decimal) es la hora del día expresada como una fracción de día. Por ejemplo, 0.25 equivale a 06:00:00 y 0.75 es equivalente a 18:00:00.
    • Calc considera la fecha 1899-12-30 como la inicial (día 0) de manera predeterminada, pero puede ir a Herramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular para seleccionar fechas de inicio alternativas; no obstante, a no ser que tenga requisitos específicos de compatibilidad con aplicaciones de hoja de cálculo antiguas, es recomendable que no modifique esta configuración. Si copiare y pegare celdas que contengan valores de fecha entre distintas hojas de cálculo, habrá de cerciorarse de que ambos documentos tengan definida la misma fecha de inicio, para evitar cambios sorpresivos en las fechas mostradas.
    • Los números de serie de fecha-hora negativos corresponden a fechas anteriores a la fecha de inicio definida en Calc. Calc calcula todas las fechas desde el 15 de octubre de 1582 utilizando el calendario gregoriano. El día anterior es el 4 de octubre de 1582, y para fechas anteriores, Calc usa el calendario juliano.
    • Un número de serie de fecha-hora no es más que un número común y corriente, con la diferencia de que se suele preferir darle el formato de fecha/hora. Puede introducir un número en una celda y luego cambiar el formato de la celda para que se muestre el valor como una fecha/hora. También puede introducir una fecha/hora en una celda y luego cambiar el formato de esta para que se visualice el valor como un número de serie.
    • Para mayor claridad, las descripciones de las funciones de Calc dentro de estas páginas wiki usan el formato estándar ISO 8601 para fecha y hora porque esto debería ser independiente de la configuración regional seleccionada. El formato de fecha predeterminado en su ordenador puede ser diferente. Al ingresar fechas como parte de fórmulas, las barras o guiones utilizados como separadores de fecha pueden interpretarse como operadores aritméticos. Por lo tanto, las fechas ingresadas en este formato no se reconocen como fechas y dan como resultado cálculos erróneos. Para evitar que las fechas se interpreten como partes de fórmulas, utilice la función FECHA o coloque la fecha entre comillas y utilice la notación ISO 8601. Evite el uso de formatos de fecha dependientes de la configuración regional que pueden producir errores si el documento se carga con una configuración regional diferente.
    • Las funciones de fecha y hora de Calc no utilizan los datos de huso horario.
    • Si desea introducir sólo dos dígitos para el año (por ejemplo, «21» en vez de «2021»), Calc ha de saber si usted entiende «21» como 2021 o como 1921. Diríjase a Herramientas ▸ Opciones ▸ LibreOffice ▸ General para ver o ajustar el intervalo de años que Calc deberá utilizar para interpretar los valores de año de dos dígitos.
    • Calc utiliza cierta lógica para decidir cómo tratar el texto cuando este se encuentra como un operando en una operación aritmética o como un argumento para una función que espera un número en su lugar. En este contexto, la conversión inequívoca es posible para fechas y horas ISO 8601 en sus formatos extendidos con separadores. Por ejemplo, la fórmula simple =1 + "2021-02-08" generalmente dará el resultado 2021-02-09 (cuando se formatea como una fecha). Sin embargo, esta lógica puede verse afectada por la configuración en el cuadro de diálogo Configuración de cálculo detallado, se accede seleccionando Herramientas ▸ Opciones ▸ LibreOffice Calc ▸ Fórmula y presionando el botón Detalles en el área Configuración detallada de cálculo. Si se da un error de #¡VALOR!, puede deberse a que la opción Generar error #¡VALOR! está seleccionada en el menú desplegable Conversión de texto a número, en cuyo caso debe experimentar con alguna de las otras opciones que se explican por sí mismas.

    Ejemplos:

    Datos para ejemplos
    A B C D E F G H
    1 Fechas Inicial/Final   Vacaciones   Fin de Semana
    2 2020-01-01 Formato de texto, sin comillas dobles 0000011
    3 2020-12-31 2020-01-01
    4 2020-04-10 Formato General de número 11
    5 2020-04-13
    6 2020-05-08
    7 2020-05-25
    8 2020-08-31
    9 2020-12-25
    10 2020-12-28
    Fórmula Descripción Devuelve
    =DIAS.LAB.INTL("2021-02-18"; "2021-02-19") Devuelve 2 días laborables, en función de las fechas de inicio y finalización proporcionadas, sin días festivos y la semana laboral predeterminada de cinco días. Este simple ejemplo muestra la naturaleza inclusiva del conteo. 2
    =DIAS.LAB.INTL("2020-12-31"; "2020-01-01") Días laborables durante el año 2020. El valor negativo refleja que FechaInicio es posterior a FechaFinal. −262
    =DIAS.LAB.INTL("2020-01-01"; "2020-12-31"; 5) Semana laboral de cinco días (con el miércoles y el jueves como días no laborables). 260
    =DIAS.LAB.INTL("2020-01-01"; "2020-12-31";; {"2020-01-01"; "2020-04-10"; "2020-04-13"; "2020-05-08"; "2020-05-25"; "2020-08-31"; "2020-12-25"; "2020-12-28"}) Ocho fechas de vacaciones especificadas y la semana laboral predeterminada de cinco días. Se incluye un separador adicional para indicar que se ha omitido el argumento FinesDeSemana. 254
    =DIAS.LAB.INTL(B2; B3; H2; E3:E10) Equivalente al ejemplo anterior, usando los datos de la tabla previa; la celda H2 contiene el valor 0000011 con formato de texto sin comillas dobles. 254
    =DIAS.LAB.INTL(B2; B3; H4; E3:E10) Similar al ejemplo anterior, pero FinesDeSemana consiste en los domingos solamente; la celda H4 contiene el valor numérico 11. 306
    =DIAS.LAB.INTL("2020-01-01"; "2020-12-31"; "0000111") Semana laboral de cuatro días (de lunes a jueves). 210
    =DIAS.LAB.INTL(43831; 43861; "1000111"; { 43845; 43852 }) 43831, 43861, 43845, y 43852 son los números de serie de fecha y hora para las fechas 2020-01-01, 2020-01-31, 2020-01-15 y 2020-01-22 respectivamente. Dos días festivos dentro del periodo, y una semana laboral de tres días (martes, miércoles y jueves). 12

    Funciones de LibreOffice relacionadas:

    DIAS.LAB

    DIAS.LAB_EXCEL2003

    Norma ODF:

    Ninguna

    Funciones equivalentes de Excel:

    NETWORKDAYS.INTL