Documentatie/Calc-functies/NETTO.WERKDAGEN

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/NETWORKDAYS and the translation is 100% complete.
    Other languages:


    Functienaam:

    NETTO.WERKDAGEN

    Categorie:

    Datum en tijd

    Samenvatting:

    Berekent het netto aantal werkdagen tussen twee datums. Feestdagen (of andere niet-werkdagen) kunnen worden gespecificeerd en de standaard werkweek kan opnieuw worden gedefinieerd

    Syntaxis:

    NETTO.WERKDAGEN(Begindatum; Einddatum[; [Feestdagen] [; Werkdagen] ])

    Retourneert:

    Retourneert een geheel getal dat het aantal werkdagen in de opgegeven periode is, exclusief gedefinieerde feestdagen en weekenddagen. De begin- en einddatum van de periode worden geteld, tenzij ze zijn gedefinieerd als vakantie- of weekenddagen.

    Argumenten:

    Begindatum is de datum (tussen aanhalingstekens) of een datum-tijd-serienummer of een verwijzing naar de cel die één van die typen bevat, namelijk de begindatum of de einddatum van de periode waarvoor de berekening moet worden uitgevoerd.

    Einddatum is de datum (tussen aanhalingstekens) of een datum-tijd-serienummer of een verwijzing naar de cel die één van die typen bevat, namelijk de einddatum of de begindatum van de periode waarvoor de berekening moet worden uitgevoerd.

    Feestdagen is een lijst met data die overeenkomen met feestdagen die niet als werkdagen worden geteld. Deze lijst kan worden doorgegeven als een celbereik met serienummers voor datum en tijd (mogelijk weergegeven in een datumnotatie). Als alternatief kan de lijst worden doorgegeven als een inline matrix met datumreeksen (tussen aanhalingstekens) of datum-tijd-serienummers. Indien weggelaten, worden geen feestdagen verondersteld.

    Werkdagen is een lijst met getallen die de standaard werkweek definiëren. Deze lijst bevat zeven vermeldingen, waarbij de eerste vermelding overeenkomt met zondag en de zevende vermelding met zaterdag. Elk getal is ofwel nul om een werkdag aan te geven of niet-nul (meestal 1) om een niet-werkdag aan te geven. Deze lijst kan worden doorgegeven als een celbereik met de getallen of als een inline matrix. Indien weggelaten, is de standaardconfiguratie dat alleen zaterdag en zondag niet-werkdagen zijn ({1; 0; 0; 0; 0; 0; 1} wanneer uitgedrukt als een inline matrix).

    • Als Begindatum of Einddatum geen geldige datumexpressie is, retourneert NETTO.WERKDAGEN als fout #WAARDE!
    • Als Begindatum eerder is dan Einddatum, is het resultaat een positief geheel getal; als Begindatum later is dan Einddatum, is het resultaat een negatief geheel getal.
    • NETTO.WERKDAGEN negeert alle tijdcomponenten van Begindatum en Einddatum.
    • Als Feestdagen wordt doorgegeven als een inline matrix, wordt als fout #WAARDE! weergegeven als een invoer van die matrix geen datum of een datum-tijdserienummer is.
    • Als Feestdagen wordt doorgegeven als een celbereik, worden in de meeste gevallen cellen die geen datum of een datum-tijd-serienummer bevatten dat binnen de relevante periode ligt, genegeerd. Als een cel echter een foutcode bevat (zoals#NAAM?), wordt die foutstatus doorgegeven als resultaat van NETTO.WERKDAGEN.
    • Als Werkdagen niet precies zeven getallen specificeert, retourneert NETTO.WERKDAGEN als fout Ongeldig argument (Fout:502).
    • Als Werkdagen wordt doorgegeven als een celbereik, als een cel een foutcode bevat (zoals #NAAM?), wordt die foutstatus doorgegeven als resultaat van NETTO.WERKDAGEN.

    Aanvullende details:

    Details specifiek voor de functie NETTO.WERKDAGEN

    NETTO.WERKDAGEN is inclusief en telt de eerste en laatste dag van de periode (zie #Voorbeelden:).

    De functie NETTO.WERKDAGEN van Calc voldoet aan de vereisten van ODF 1.2. Als u een werkblad van Calc naar Microsoft Excel exporteert die aanroepen naar NETTO.WERKDAGEN die alle vier de argumenten gebruiken, dan zal dat werkblad fouten genereren wanneer deze in Excel wordt geopend. Dit komt omdat de Excel functie NETTO.WERKDAGEN de parameter Werkdagen die is opgegeven in ODF 1.2 niet ondersteunt. Voor interoperabiliteit met Excel kunt u de functie NETTO.WERKDAGEN gebruiken.


    Algemene informatie over de datum- en tijdfuncties van Calc

    Note pin.svg

    NB:
    Voor het gemak wordt de informatie in deze subsectie herhaald op alle pagina's die functies beschrijven in de categorie Datum en Tijd.

    • Intern in Calc, een datum/tijd-waarde wordt behandeld als een reëel getal en dit wordt soms aangeduid met de term datum-tijd serienummer. 2021-02-08 12:00:00 komt bijvoorbeeld overeen met het datum-tijd serienummer 44235.5. Het gehele deel van een datum-tijd-serienummer (vóór de komma) is het aantal dagen sinds een gedefinieerde startdatum. Het fractionele deel van een datum-tijd-serienummer (achter de komma) is de tijd van de dag uitgedrukt als een fractie van een dag. 0,25 is bijvoorbeeld gelijk aan 06:00:00 en 0,75 is gelijk aan 18:00:00.
    • Calc gebruikt 1899-12-30 als standaard startdatum (dag 0) maar u kunt naar Extra ▸ Opties ▸ LibreOffice Calc ▸ Berekenen gaan om alternatieve startdatums te selecteren; we raden u echter aan deze instelling niet te wijzigen, tenzij u specifieke vereisten heeft voor compatibiliteit met oudere werkbladtoepassingen. Als u cellen met datumwaarden kopieert en plakt tussen verschillende werkbladen, controleer dan of beide documenten zijn ingesteld om dezelfde startdatum te gebruiken om onverwachte wijzigingen in de weergegeven datums te voorkomen.
    • Negatieve datum-tijd serienummers komen overeen met datums eerder dan de startdatum van Calc. Calc berekent alle datums terug tot 15 oktober 1582 met behulp van de Gregorian calendar. De dag ervoor is 4 oktober 1582 en Calc gebruikt de Julian calendar voor eerdere data.
    • Een serienummer voor datum en tijd is hetzelfde als elk ander getal, behalve dat we er meestal voor kiezen om het in de vorm van een datum/tijd weer te geven. U kunt een getal in een cel invoeren en vervolgens de opmaak van de cel wijzigen om de waarde als datum/tijd weer te geven. U kunt ook een datum/tijd in een cel invoeren en vervolgens de opmaak van de cel wijzigen om het datum-tijd-serienummer weer te geven.
    • Voor de duidelijkheid: de beschrijvingen van de Calc-functies op deze wiki-pagina's gebruiken het standaard ISO 8601-formaat voor datum en tijd omdat dit onafhankelijk moet zijn van de door u geselecteerde landinstellingen. Het standaard datumformaat op uw computer kan anders zijn. Bij het invoeren van datums als onderdeel van formules, kunnen schuine strepen of streepjes die als datumscheidingsteken worden gebruikt, worden geïnterpreteerd als rekenkundige operatoren. Daarom worden datums die in dit formaat zijn ingevoerd, niet herkend als datums en resulteren in foutieve berekeningen. Om te voorkomen dat datums worden geïnterpreteerd als onderdelen van formules, gebruikt u de functie DATUM of plaatst u de datum tussen aanhalingstekens en gebruikt u de ISO 8601-notatie. Vermijd het gebruik van locale-afhankelijke datumnotaties die fouten kunnen veroorzaken als het document onder verschillende locale-instellingen wordt geladen.
    • Tijdzone-informatie wordt niet gebruikt door de datum- en tijdfuncties van Calc.
    • Als u alleen twee cijfers van het jaar wilt invoeren (bijvoorbeeld 21 in plaats van 2021), moet Calc weten of u 2021 of 1921 bedoelt. Ga naar Extra ▸ Opties ▸ LibreOffice ▸ Algemeen om het bereik van jaren te bekijken of aan te passen dat Calc zal gebruiken om tweecijferige jaarwaarden te interpreteren.
    • Calc bevat logica om te beslissen hoe tekst moet worden behandeld wanneer het wordt aangetroffen als een opdrachtelement in een rekenkundige bewerking of als een argument voor een functie die in plaats daarvan een getal verwacht. In deze context is eenduidige conversie mogelijk voor ISO 8601 datums en tijden in hun uitgebreide formaten met scheidingstekens. De eenvoudige formule =1 + "2021-02-08" geeft bijvoorbeeld meestal het resultaat 2021-02-09 (wanneer opgemaakt als een datum). Deze logica kan echter worden beïnvloed door de instellingen in het dialoogvenster Gedetailleerde berekeningsinstellingen, toegankelijk door Extra ▸ Opties ▸ LibreOffice Calc ▸ Formule te selecteren en op de knop Details te drukken in het gebied "Gedetailleerde berekeningsinstellingen". Als een #WAARDE! fout optreedt, kan het zijn dat de optie Algemene fout #WAARDE! is geselecteerd, in welk geval u moet experimenteren met één van de andere opties in de keuzelijst Van tekst naar getal converteren.

    Voorbeelden:

    Gegevens voor voorbeelden
    A B C D E F G H
    1 Begin/Einddatums Feestdagen Werkdagen
    2 2020-01-01 1
    3 2020-12-31 2020-01-01 0
    4 2020-04-10 0
    5 2020-04-13 0
    6 2020-05-08 0
    7 2020-05-25 0
    8 2020-08-31 1
    9 2020-12-25
    10 2020-12-28
    Formule Beschrijving Retourneert
    =NETTO.WERKDAGEN("2021-02-18"; "2021-02-19") Retourneert 2 werkdagen, gebaseerd op de opgegeven begin- en einddatum, geen feestdagen en de standaard vijfdaagse werkweek. Dit eenvoudige voorbeeld toont het inclusieve karakter van de telling. 2
    =NETTO.WERKDAGEN("2020-12-31"; "2020-01-01") Werkdagen in het jaar 2020. De negatieve waarde geeft aan dat de Begindatum later is dan de Einddatum. −262
    =NETTO.WERKDAGEN("2020-01-01"; "2020-12-31"; {"2020-01-01", "2020-04-10", "2020-04-13", "2020-05-08", "2020-05-25", "2020-08-31", "2020-12-25", "2020-12-28"}) Acht opgegeven vakantiedatums en de standaard vijfdaagse werkweek. 254
    =NETTO.WERKDAGEN(B2; B3; E3:E10; H2:H8) Gelijk aan het vorige voorbeeld, met behulp van de bovenstaande gegevenstabel. 254
    =NETTO.WERKDAGEN("2020-01-01"; "2020-12-31";; {1;0;0;0;0;1;1}) Een vierdaagse werkweek (maandag t/m donderdag). Er is een extra scheidingsteken toegevoegd om aan te geven dat het argument Feestdagen is weggelaten. 210
    =NETTO.WERKDAGEN(43831; 43861; {43845; 43852}; {1;{1;0;0;0;1;1}) 43831, 43861, 43845 en 43852 zijn de datum-tijd serienummers voor respectievelijk de datums 2020-01-01, 2020-01-31, 2020-01-15 en 2020-01-22. Twee feestdagen binnen de periode en een driedaagse werkweek (dinsdag, woensdag en donderdag). 12

    Gerelateerde LibreOffice-functies:

    NETWERKDAGEN.INTL

    NETTO.WERKDAGEN_EXCEL2003

    ODF standaard:

    Section 6.10.14, part 2

    Gerelateerde (of gelijkwaardige) Excel-functies:

    NETTO.WERKDAGEN