Documentatie/Calc-functies/NPER

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/NPER and the translation is 100% complete.
    Other languages:

    Functienaam:

    NPER

    Categorie:

    Financieel

    Samenvatting:

    Berekent het aantal betalingstermijnen voor een investering of lening. NPER berekent het aantal benodigde perioden, zodat de huidige waarde (Present Value), gevolgd door een regelmatige betaling aan het einde van elke periode resulteert in een gespecificeerde waarde aan het einde van de termijn (Future Value).

    NPER gaat uit van een investering of lening met de volgende algemene kenmerken:

    • Een eerst forfaitair bedrag.
    • Een aantal periodieke betalingen/stortingen.
    • Een eindbedrag.
    • Een constante rente.

    Sommige van deze kenmerken kunnen worden genegeerd door relevante functie-argumenten op nul te zetten.

    Syntaxis:

    NPER(Tarief; BET; HW[; [TW] [; Type]])

    Retourneert:

    Retourneert een reëel getal, het aantal betalingsperioden voor de opgegeven investering of lening.

    Argumenten:

    Tarief is een reëel getal (uitgedrukt als een percentage, zoals 2,5%, of een decimale breuk, zoals 0,025), of een verwijzing naar een cel die dat getal bevat, wat de periodieke rentevoet is. Het is gebruikelijk dat rentetarieven jaarlijks worden genoteerd en, waar nodig, moet ervoor worden gezorgd dat dergelijke waarden worden omgerekend zodat ze compatibel zijn met de lengte van uw betalingsperiode.

    BET is een reëel getal of een verwijzing naar een cel die dat getal bevat, wat de constante betaling of storting is die in elke periode is gedaan.

    HW is een reëel getal, of een verwijzing naar een cel die dat getal bevat, wat de contante waarde van de investering of lening is. HW moet dezelfde valuta hebben als BET.

    TW is een reëel getal of een verwijzing naar een cel die dat getal bevat, wat de toekomstige waarde is van het gewenste kassaldo aan het einde van de termijn. Als TW wordt weggelaten, gebruikt de functie de waarde 0,0. TW moet dezelfde valuta hebben als BET en HW.

    Type is een logische waarde of een verwijzing naar een cel die een logische waarde bevat, die bepaalt of de vervaldatum aan het begin of einde van een betalingsperiode ligt. Als Type is ingesteld op 0 of ONWAAR of wordt weggelaten, dan gaat de functie uit van het einde van de betalingsperiode. Als Type is ingesteld op een andere waarde, dan gaat de functie uit van het begin van de betalingsperiode.

    • Als een argument niet-numeriek is, retourneert NPER als foutcode #WAARDE!
    • Als zowel HW als TW zijn ingesteld op 0,0, dan retourneert NPER de waarde 0.
    • NPER voert geen bereikcontroles uit op de waarden van de Rente, de argumenten BET, HW en TW. Bijgevolg is het mogelijk om reeksen argumenten te genereren die ertoe leiden dat NPER nietszeggende negatieve waarden retourneert.

    Aanvullende details:

    • Zoals bij verschillende financiële functies van Calc, gebruikt NPER een algemeen model om zowel leningen als annuïteiten te beschrijven. Dit model gaat ervan uit dat een initiële forfaitaire som wordt geleend of geïnvesteerd, een aantal periodieke betalingen wordt gedaan of ontvangen en een laatste som wordt betaald of ontvangen. Er wordt een constante rente toegepast en samengesteld gedurende de looptijd van de investering. Dit model wordt uitgedrukt door de volgende vergelijkingen:
    In het geval van een nulrente:
    [math]\displaystyle{ HW ~+~ AFLOSSING \times n~+~TW~=~0 }[/math]
    In het geval van een niet-nul rente:
    [math]\displaystyle{ HW \times (1+r)^{n} ~+~ AFLOSSING \times \frac{\left ( \left ( 1+r \right )^{n} -1\right )}{r}\times \left ( 1+ \left (t \times r \right ) \right )~+~TW~=~0 }[/math]
    where:
    FV = toekomstige waarde
    n = aantal betalingsperioden
    PMT = periodieke betalingswaarde
    PV = huidige waarde
    r = periodieke rentevoet
    t = Vlag vervaldatum (0 Wanneer de vervaldatum aan het einde van elke betalingsperiode is; 1 wanneer de vervaldatum aan het begin van elke betalingsperiode is).
    • NPER gaat ervan uit dat de ontvangen geld positief is, terwijl de uitbetaling negatief is.
    • De waarde die wordt geretourneerd door NPER kan een breukdeel hebben, wat het resultaat kan zijn van het oplossen van de relevante vergelijking. Niet-gehele waarden zijn mogelijk niet zinvol in het echte leven, wanneer een geheel aantal betalingstermijnen zou worden verwacht.

    Voorbeelden:

    Opmerkingː

    1. De opmaak van de geretourneerde waarden in de volgende voorbeelden kan uitgaan van de landinstelling Engels (VS).
    2. De geretourneerde waarden worden tot op één decimaal vermeld, aangezien verdere granulariteit niet nuttig is voor deze functie.
    Formule Beschrijving Retourneert
    =NPER(A1; A2; A3; A4)

    waar cel A1 de formule =8% / 12 bevat, bevat cel A2 de waarde 500, cel A3 bevat de waarde −35.019,37 en cel A4 bevat de waarde 20.000.

    Hier berekent de functie de duur in maanden van een investering die aanvankelijk 35.019,37 valuta-eenheden kost, maar de belegger elke maand 500 valuta-eenheden betaalt en een extra bedrag van 20.000 valuta-eenheden aan het einde van de investeringsperiode. Het jaarlijkse rentepercentage wordt verondersteld 8% te zijn en de periodieke betalingen worden aan het einde van elke maand gedaan (dit is de standaardinstelling voor het weggelaten argument Type). Merk op dat betalingen aan de belegger een positieve waarde hebben, terwijl betalingen door de belegger een negatieve waarde hebben. De teruggegeven waarde is 48,0 en dus is de investeringsperiode 48 maanden of 4 jaar.

    48,0
    =NPER(8% / 12; 500; −35155.91; 20000; 1)

    Hier berekent de functie de duur in maanden van dezelfde investering als in het vorige voorbeeld, behalve dat de waarde anders dan nul voor het argument Type impliceert dat de periodieke betalingen van 500 valuta-eenheden aan het begin van elke maand plaatsvinden. (in plaats van aan het einde). De teruggegeven waarde is weer 48,0 en dus is de investeringsperiode 48 maanden of 4 jaar.

    48,0
    =NPER(7%; 1500; −15891.02)

    Hier berekent de functie de looptijd in jaren van een annuïteit die aanvankelijk 15.891,02 valuta-eenheden kost, maar de belegger aan het einde van elk jaar 1500 valuta-eenheden uitbetaalt. Er wordt uitgegaan van een constante jaarlijkse rente van 7%. De argumenten TW en Type worden weggelaten en nemen hun standaardwaarden van respectievelijk 0,0 en 0 aan. De teruggegeven waarde is 20,0 en dus is de investeringsperiode 20 jaar.

    20,0
    =NPER(5,5% / 12; −300; 15705.85)

    Hier berekent de functie de looptijd in maanden van een lening, uitgaande van een constant jaarlijks rentepercentage van 5,5%. Het geleende bedrag is 15.705,85 valuta-eenheden en moet maandelijks worden terugbetaald tegen een koers van 300 valuta-eenheden. De argumenten TW en Type worden weer weggelaten en nemen hun standaardwaarden van respectievelijk 0,0 en 0 aan. De teruggegeven waarde is 60,0 en dus is de investeringsperiode 60 maanden of 5 jaar.

    60,0
    =NPER(7,5% / 12; −100; −3785.21; 60000)

    Er is een investering nodig die over 18 jaar een contant bedrag van 60.000 valuta-eenheden oplevert. De investering kost aanvankelijk 3.785,21 valuta-eenheden en aan het einde van elke maand moeten 100 valuta-eenheden worden belegd, met een verondersteld jaarlijks integratiepercentage van 7,5%. Het argument Type wordt weggelaten en gaat uit van de standaardwaarde van 0. De geretourneerde waarde is 216,0 en dus is de investeringsperiode 216 maanden of 18 jaar.

    216,0

    Gerelateerde LibreOffice-functies:

    TW

    BET

    HW

    RENTE

    ODF standaard:

    Sectie 6.12.29, deel 2

    Gerelateerde (of gelijkwaardige) Excel-functies:

    NPER