Documentatie/Calc-functies/BET
TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren
Functienaam:
BET
Categorie:
Financieel
Samenvatting:
Berekent de periodieke betaling (kapitaal en rente) voor een lening met vaste rente op basis van een bepaald aantal periodieke betalingen gedurende een bepaalde looptijd.
Hoewel de periodieke betalingen altijd voor hetzelfde bedrag zijn, varieert het deel van de rente en het terugbetaalde kapitaal per periode gedurende de looptijd van de lening. De gerelateerde functie IBET berekent het rentegedeelte van de betaling voor een bepaalde periode, terwijl de functie PBET de overeenkomstige kapitaalcomponent berekent .
BET kan ook worden gebruikt om de reguliere inleg voor een rentevaste lijfrente te berekenen.
Syntaxis:
BET(Tarief; NPER; HW[; [TW] [; Type]])
Retourneert:
Retourneert een reëel getal, dat de waarde is van de periodieke betaling of aanbetaling. Het geretourneerde getal heeft dezelfde valuta-eenheid als de opgegeven huidige en toekomstige waarden en wordt standaard opgemaakt in een landafhankelijke valuta-indeling.
Argumenten:
Tarief is een reëel getal (uitgedrukt als een percentage, zoals 2,5%, of een decimale breuk, zoals 0,025), of een verwijzing naar een cel die dat getal bevat, wat de periodieke rentevoet is. Het is gebruikelijk dat rentetarieven jaarlijks worden genoteerd en, waar nodig, moet ervoor worden gezorgd dat dergelijke waarden worden omgerekend zodat ze compatibel zijn met de lengte van uw betalingsperiode.
NPER is een reëel getal of een verwijzing naar een cel die dat getal bevat, wat het aantal betalingsperioden in de termijn is.
HW is een reëel getal of een verwijzing naar een cel die dat getal bevat, wat de contante waarde is van het geleende of geïnvesteerde bedrag.
TW is een reëel getal, of een verwijzing naar een cel die dat getal bevat, wat de toekomstige waarde is van het gewenste kassaldo aan het einde van de termijn . Als TW wordt weggelaten, gebruikt de functie de waarde 0.0. TW moet dezelfde valuta hebben als HW.
Type is een logische waarde of een verwijzing naar een cel die een logische waarde bevat, die bepaalt of de vervaldatum aan het begin of einde van een betalingsperiode ligt. Als Type is ingesteld op 0 of ONWAAR of wordt weggelaten, dan gaat de functie uit van het einde van de betalingsperiode. Als Type is ingesteld op een andere waarde, dan gaat de functie uit van het begin van de betalingsperiode.
- Als een argument niet-numeriek is, retourneert IBET als foutcode #WAARDE!.
- BET legt geen bereikcontroles op aan de waarden van de Tarief', NPER ', HW en TW argumenten. Echter, inspectie van de vergelijkingen gepresenteerd in de sectie Aanvullende details hieronder geeft aan dat het mogelijk zou zijn om onrealistische vergelijkingen te genereren waarbij de noemer resulteert in 0. In dergelijke gevallen retourneert BET als foutcode #GETAL!.
Aanvullende details:
- Zoals bij verschillende financiële functies van Calc, gebruikt PMT een algemeen model om zowel leningen als annuïteiten te beschrijven. Dit model gaat ervan uit dat een initiële forfaitaire som wordt geleend of geïnvesteerd, een aantal periodieke betalingen wordt gedaan of ontvangen en een laatste som wordt betaald of ontvangen. Er wordt een constante rente toegepast en samengesteld gedurende de looptijd van de investering. Dit model wordt uitgedrukt door de volgende vergelijkingen:
- In het geval van een nulrente:
- [math]\displaystyle{ HW ~+~ AFLOSSING \times n~+~TW~=~0 }[/math]
- In het geval van een niet-nul rente:
- [math]\displaystyle{ HW \times (1+r)^{n} ~+~ AFLOSSING \times \frac{\left ( \left ( 1+r \right )^{n} -1\right )}{r}\times \left ( 1+ \left (t \times r \right ) \right )~+~TW~=~0 }[/math]
- where:
- FV = toekomstige waarde
- n = aantal betalingsperioden
- PMT = periodieke betalingswaarde
- PV = huidige waarde
- r = periodieke rentevoet
- t = Vlag vervaldatum (0 Wanneer de vervaldatum aan het einde van elke betalingsperiode is; 1 wanneer de vervaldatum aan het begin van elke betalingsperiode is).
- In het geval van een nulrente:
- BET gaat ervan uit dat de ontvangen geld positief is, terwijl de uitbetaling negatief is.
Voorbeelden:
Houd er rekening mee dat de opmaak van de geretourneerde waarden die in de volgende voorbeelden worden gegeven, uitgaat van de landinstelling Engels (VS).
Het verband tussen BET, PBET en IBET
 |
NB:
|
Jan besluit $ 8.000 te lenen over een periode van 12 maanden tegen een jaarlijkse rente van 4%. Er is geen kassaldo meer aan het einde van de lening en de betalingen moeten aan het einde van elk jaar worden betaald. In onderstaande tabel ziet u de rentecomponenten van zijn aflossingen.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Geleende bedrag | $8,000 | ||
| 2 | Jaarrente | 4% | ||
| 3 | ||||
| 4 | Maand | BET | PBET | IBET |
| 5 | 1 | -$681.20 | -$654.53 | -$26.67 |
| 6 | 2 | -$681.20 | -$656.71 | -$24.48 |
| 7 | 3 | -$681.20 | -$658.90 | -$22.30 |
| 8 | 4 | -$681.20 | -$661.10 | -$20.10 |
| 9 | 5 | -$681.20 | -$663.30 | -$17.90 |
| 10 | 6 | -$681.20 | -$665.51 | -$15.68 |
| 11 | 7 | -$681.20 | -$667.73 | -$13.47 |
| 12 | 8 | -$681.20 | -$669.96 | -$11.24 |
| 13 | 9 | -$681.20 | -$672.19 | -$9.01 |
| 14 | 10 | -$681.20 | -$674.43 | -$6.77 |
| 15 | 11 | -$681.20 | -$676.68 | -$4.52 |
| 16 | 12 | -$681.20 | -$678.94 | -$2.26 |
| 17 | -$8,174.39 | -$8,000.00 | -$174.39 |
Cellen B5:D16 bevatten formules:
- Cellen B5:B16 de formule
=BET($B$2/12; $A$16; $B$1). - Cel C5 de formule
=PBET($B$2/12; $A5; $A$16; $B$1); cel C6 de formule=PBET($B$2/12; $A6; $A$16; $B$1); en zo verder voor de cellen C7:C16. - Cel D5 de formule
=IBET($B$2/12; $A5; $A$16; $B$1); cel D6 de formule=IBET($B$2/12; $A6; $A$16; $B$1); en zo verder voor cellen D7:D16.
De functies in de gegevens van de bestaande tabel zijn o.a. :
- BET wordt gebruikt voor het berekenen van de vaste maandbetaling, hier $681.20. BET zet er een min-teken voor om aan te geven dat het betalingen zijn.
- PBET wordt gebruikt om het kapitaal-element te berekenen per maandelijkse betaling. Merk op dat het aandeel van de PBET in het totaal toeneemt in de periode.
- IBET wordt gebruikt om het rente-element te berekenen van de vaste maandbetaling. Merk op dat het aandeel van de IBET in het totaal afneemt in de periode.
- Per maand id het totaal van de PBET en de IBET gelijk aan BET-waarde.
- Het totaal van alle maandelijkse betalingen (cel B17) is gelijk naan de som van alle kapitaal elementen (cel C17) en de rente (cel D17).
Andere voorbeelden
| Formule | Beschrijving | Retourneert |
|---|---|---|
| =BET(1.99%/12; 36; 25000; 5000; 1) | Hier berekent de functie de periodieke betalingen voor een lening van 25.000 valuta-eenheden tegen een jaarlijks rentepercentage van 1,99% (1,99%/12 per maand), met een looptijd van 3 jaar (36 maanden). Een gewenst kassaldo van 5000 valuta-eenheden is vereist op de looptijd en de betaling is verschuldigd aan het begin van elke maand. De maandelijkse betaling berekend door BET is 849,45 valuta-eenheden en dit wordt geretourneerd als een negatieve waarde. | -$849.45 |
| =BET(1.99%/12; 36; 25000) | Hier berekent de functie de periodieke betalingen voor een lening van 25.000 valuta-eenheden tegen een jaarlijks rentepercentage van 1,99% (1,99%/12 per maand), met een looptijd van 3 jaar (36 maanden). Op het einde van de looptijd is geen kassaldo vereist en de betaling dient aan het einde van elke maand te worden voldaan. De maandelijkse betaling berekend door BET is 715,96 valuta-eenheden en dit wordt geretourneerd als een negatieve waarde. | -$715.96 |
Gerelateerde LibreOffice-functies:
ODF standaard:
Gerelateerde (of gelijkwaardige) Excel-functies:
PMT