Documentatie/Calc-functies/RENTE

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/RATE and the translation is 100% complete.
    Other languages:

    Functienaam:

    RENTE

    Categorie:

    Financieel

    Samenvatting:

    Berekent de constante rentevoet per periode van een investering of lening. RENTE berekent de vaste rentevoet die nodig is, zodat de huidige waarde (Present Value), gevolgd door een regelmatige betaling aan het einde van elk van een gedefinieerd aantal perioden, resulteert in een gespecificeerde waarde aan het einde van de termijn (Future Value). RENTE gebruikt een iteratief wortelzoekalgoritme om de relevante vergelijking op te lossen, met de optie om een initiële startwaarde op te geven als één van de argumenten van de functie.

    RENTE gaat uit van een investering of lening met de volgende algemene kenmerken:

    • Een eerst forfaitair bedrag.
    • Een aantal periodieke betalingen/stortingen.
    • Een eindbedrag.
    • Een constante rente.

    Sommige van deze kenmerken kunnen worden genegeerd door relevante functie-argumenten op nul te zetten.

    Syntaxis:

    RENTE(NPER; BET; HW[; [TW][; [Type] [; Geschatte waarde] ] ])

    Retourneert:

    Retourneert een reëel getal, dat het constante rentepercentage per periode is voor de opgegeven investering of lening. Het geretourneerde getal is een percentage en wordt standaard opgemaakt als een percentage.

    Argumenten:

    NPER is een positief reëel getal of een verwijzing naar een cel die dat getal bevat, wat het aantal betalingsperioden in de termijn is.

    BET is een reëel getal of een verwijzing naar een cel die dat getal bevat, wat de constante betaling of storting is die in elke periode is gedaan.

    HW is een reëel getal, of een verwijzing naar een cel die dat getal bevat, wat de contante waarde van de investering of lening is. HW moet dezelfde valuta hebben als BET.

    TW is een reëel getal of een verwijzing naar een cel die dat getal bevat, wat de toekomstige waarde is van het gewenste kassaldo aan het einde van de termijn . Als TW wordt weggelaten, gebruikt de functie de waarde 0,0. TW moet dezelfde valuta hebben als BET en HW.

    Type is een logische waarde of een verwijzing naar een cel die een logische waarde bevat, die bepaalt of de vervaldatum aan het begin of einde van een betalingsperiode ligt. Als Type is ingesteld op 0 of ONWAAR of wordt weggelaten, dan gaat de functie uit van het einde van de betalingsperiode. Als Type is ingesteld op een andere waarde, dan gaat de functie uit van het begin van de betalingsperiode.

    Geschatte waarde is een reëel getal (uitgedrukt als een percentage, zoals 2,5%, of een decimale breuk, zoals 0,025) of een verwijzing naar een cel die dat getal bevat, wat een eerste schatting is voor de periodieke rente. Dit kan worden ingevoerd als u enig idee heeft van het rentepercentage, maar indien weggelaten wordt uitgegaan van 0,1 (10%). Het is gebruikelijk dat rentetarieven jaarlijks worden genoteerd en, waar nodig, moet ervoor worden gezorgd dat dergelijke waarden worden omgerekend zodat ze compatibel zijn met de lengte van uw betalingsperiode.

    • Als een argument niet-numeriek is, retourneert RENTE als foutcode #WAARDE!
    • Als NPER kleiner is dan of gelijk is aan 0,0, dan retourneert RENTE als foutcode Ongeldig argument (Fout:502).
    • Vanwege de gebruikte iteratieve methode is het mogelijk dat de berekening niet convergeert naar een resultaat. In dergelijke gevallen meldt RENTE dat een berekening niet convergeert (Fout:523). Het kan mogelijk zijn om een resultaat te verkrijgen door een andere waarde op te geven voor het argument Geschatte waarden, omdat een significante fout in deze aanvankelijke schatting kan leiden tot niet-convergentie van het algoritme. Het kan ook de moeite waard zijn om de argumenten opnieuw te controleren.

    Aanvullende details:

    • Zoals bij verschillende financiële functies van Calc, gebruikt RATE een algemeen model om zowel leningen als annuïteiten te beschrijven. Dit model gaat ervan uit dat een initiële forfaitaire som wordt geleend of geïnvesteerd, een aantal periodieke betalingen wordt gedaan of ontvangen en een laatste som wordt betaald of ontvangen. Er wordt een constante rente toegepast en samengesteld gedurende de looptijd van de investering. Dit model wordt uitgedrukt door de volgende vergelijkingen:
    In het geval van een nulrente:
    [math]\displaystyle{ HW ~+~ AFLOSSING \times n~+~TW~=~0 }[/math]
    In het geval van een niet-nul rente:
    [math]\displaystyle{ HW \times (1+r)^{n} ~+~ AFLOSSING \times \frac{\left ( \left ( 1+r \right )^{n} -1\right )}{r}\times \left ( 1+ \left (t \times r \right ) \right )~+~TW~=~0 }[/math]
    where:
    FV = toekomstige waarde
    n = aantal betalingsperioden
    PMT = periodieke betalingswaarde
    PV = huidige waarde
    r = periodieke rentevoet
    t = Vlag vervaldatum (0 Wanneer de vervaldatum aan het einde van elke betalingsperiode is; 1 wanneer de vervaldatum aan het begin van elke betalingsperiode is).
    • RENTE gaat ervan uit dat de ontvangen geld positief is, terwijl de uitbetaling negatief is.
    • RENTE gebruikt de Newton-Raphson-methode voor het vinden van wortels (er is geen algemeen theoretisch alternatief voor deze iteratieve benadering). Ga voor meer informatie over deze methode naar Wikipedia-pagina Newton's method.

    Voorbeelden:

    Houd er rekening mee dat de opmaak van de geretourneerde waarden die in de volgende voorbeelden worden gegeven, uitgaat van de landinstelling Engels (VS).

    Formule Beschrijving Retourneert
    =RENTE(A1; A2; A3; A4) waarbij de cellen A1 tot en met A4 respectievelijk de waarden 48, 500, -35019,37 en 20000 bevatten. Hier berekent de functie de constante rentevoet per periode van een investering die initieel 35.019,37 valuta-eenheden kost, maar de belegger maandelijks 500 valutɑ-eenheden betaalt en een extra bedrag van 20.000 valuta-eenheden aan het einde van de investeringsperiode van vier jaar. De periodieke betalingen worden aan het einde van elke maand gedaan (dit is de standaardinstelling voor het weggelaten argument Type) en het argument Geschatte waarde neemt de standaardwaarde van 10% aan. Merk op dat betalingen aan de belegger een positieve waarde hebben, terwijl betalingen door de belegger een negatieve waarde hebben. RENTE retourneert de waarde 0,67% per periode, wat overeenkomt met ongeveer 8% per jaar. 0,67%
    =RENTE(48; 500; −35019.37; 20000; 1) Hier berekent de functie de constante rentevoet per periode van dezelfde investering als in het vorige voorbeeld, behalve dat de waarde anders dan nul voor het argument Type impliceert dat de periodieke betalingen van 500 valuta-eenheden plaatsvinden aan het begin van elke maand (in plaats van aan het eind). RENTE retourneert de waarde 0,68% per periode, slechts marginaal verschillend van het resultaat van het vorige voorbeeld, met deze variantie als gevolg van numerieke onnauwkeurigheden van de twee berekeningen. 0.68%
    =RENTE(20; 1500; −15891.02) Hier berekent de functie de constante rentevoet per periode van een annuïteit die oorspronkelijk 15.891,02 valuta-eenheden kost, maar de belegger 1.500 valuta-eenheden betaalt aan het einde van elk jaar, voor de volgende 20 jaar. De argumenten TW, Type en Geschatte waarde worden weggelaten en gaan uit van hun standaardwaarden van 0,0, 0, respectievelijk 10%. RENTE retourneert de waarde 7,00%, wat het jaarlijkse rentepercentage is. 7.00%
    =RENTE(60; −300; 15705.85) Hier berekent de functie de constante rentevoet per periode voor een lening van 15.705,85 valuta-eenheden. De lening moet gedurende 5 jaar maandelijks in 300 valuta-eenheden worden terugbetaald. De argumenten TW, Type en Geschatte waarde worden weer weggelaten en gaan uit van hun standaardwaarden van 0,0, 0 respectievelijk 10%. RENTE retourneert de waarde 0,46% per periode, wat overeenkomt met ongeveer 5,5% per jaar. 0.46%
    =RENTE(18*12; −100; −3785.21; 60000; ; 20%) Er is een investering nodig die over 18 jaar een contant bedrag van 60.000 valuta-eenheden oplevert. Aan het begin van de belegging wordt een startbedrag van 3.785,21 valuta-eenheden belegd en aan het einde van elke maand 100 valuta-eenheden. Het argument Geschatte waarde' is ingesteld op 20%. Het argument Type wordt weggelaten en gaat uit van de standaardwaarden van 0. RENTE retourneert de waarde 0,62% per periode, wat overeenkomt met ongeveer 7,5% per jaar. Merk op dat de formule =RENTE(18*12; -100; -3785.21; 60000) die de standaardwaarde van 10% gebruikt voor het argumemt 'Geschatte waarde retourneert dezelfde waarde (wanneer weergegeven tot twee decimalen). 0.62%

    Gerelateerde LibreOffice-functies:

    TW

    NPER

    BET

    HW

    ODF standaard:

    Sectie 6.12.42, deel 2

    Gerelateerde (of gelijkwaardige) Excel-functies:

    RATE