Dokumentace/Výpočetní funkce/TEXT

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/TEXT and the translation is 100% complete.
    Other languages:


    Název funkce:

    TEXT

    Kategorie:

    Text

    Shrnutí:

    Převede číslo na text v zadaném formátu.

    Funkce TEXT je užitečná zejména tehdy, když chcete vložit formátované číslo do textového řetězce.

    Syntaxe:

    TEXT(Číslo; Formát)

    Vrátí:

    Vrací textový řetězec, který je převedenou hodnotou v požadovaném formátu.

    Argumenty:

    Hodnota je hodnota, která se má zpracovat, nebo odkaz na buňku obsahující tuto hodnotu. Zadaná hodnota může být v libovolném číselném formátu platném pro vaše místní prostředí, například číslo v desetinné soustavě, číslo ve vědeckém zápisu, číslo ve zlomku, procento, měna, datum, čas nebo logická hodnota.

    Formát je textový řetězec (v uvozovkách) nebo odkaz na buňku obsahující textový řetězec, který určuje formát výstupního textového řetězce. Další informace o tomto argumentu naleznete níže v části #Další podrobnosti:.

    • Pokud řetězec Format není platný, TEXT ohlásí chybu neplatného argumentu (Chyba:502).

    Další detaily:

    Pro demonstraci užitečnosti funkce TEXT uvažujte následující vzorec, který byl určen k zobrazení dnešního data:

    ="Dnešní datum je " & TODAY()

    Za předpokladu, že dnes je 2021-08-22, pak tento vzorec zobrazí řetězec "Dnešní datum je 44430", kde 44430 je pořadové číslo data a času pro 2021-08-22. Je pravděpodobné, že toto tvůrce vzorce neměl na mysli!

    Následující alternativní vzorec používá funkci TEXT a poskytuje výstup, který byl pravděpodobně zamýšlen, se správně formátovaným datem:

    ="Dnešní datum je " & TEXT(TODAY(); "rrrr-mm-dd")

    Tento vzorec zobrazí řetězec "Dnešní datum je 2021-08-22".

    Příklady formátovacích kódů najdete na kartě "Čísla" dialogového okna Formátovat buňky v poli označeném "Formátovací kód". K tomuto dialogu se dostanete jedním z následujících způsobů:

    1. Vyberte Formát ▸ Buňky na panelu nabídek.
    2. Klepněte pravým tlačítkem myši na buňku tabulky a v kontextové nabídce vyberte možnost Formátovat buňky.
    3. Stiskněte klávesovou zkratku Ctrl+1.

    Jakmile provedete výběr v oblastech Kategorie, Formát, Jazyk a Možnosti na kartě Čísla, Calc aktualizuje obsah pole Kód formátu podle těchto výběrů.

    Podrobnější popis naleznete v rejstříku nápovědy pod heslem "kódy formátu čísla" nebo navštivte příslušnou stránku nápovědy.

    Chování funkce TEXT je lokálně závislé, a proto by nemělo být považováno za přenositelné.

    Příklady:

    Následující příklady předpokládají, že vaše lokalizace je nastavena na angličtinu (USA).

    Vzorec Popis Vrátí
    =TEXT(12,34567; "###.##") Zde je zadaná hodnota zobrazena bez počátečních nul a zaokrouhlena na dvě desetinná místa. 12,35
    =TEXT(D1; D2), kde buňka D1 obsahuje hodnotu 12 a buňka D2 řetězec "000.00". Zde je zadaná hodnota zobrazena s úvodní nulou a zaokrouhlena na dvě desetinná místa. 012,00
    =TEXT(123 456 789, "#,###") Zde se zobrazí zadaná hodnota s čárkou použitou jako oddělovač skupin číslic. 123,456,789
    =TEXT(0,123456, "0.00%") Zde se zadaná hodnota zobrazí v procentech. 12.35%
    =TEXT(−6 789,4, "[$$-409]#,##0.00; -[$$-409]#,##0.00") Zde se zadaná hodnota zobrazí jako hodnota v měně USD. Všimněte si, že formátovací řetězec má dvě části oddělené středníky - kladné hodnoty se zobrazují bez znaménka plus, zatímco záporným hodnotám předchází znaménko minus. -$6,789.40
    =TEXT(0, "YYYY-MM-DD HH:MM:SS") Zde se zadaná hodnota zobrazí jako datum a čas ve standardním formátu ISO8601. Výsledný datum-čas je výchozím počátečním bodem pro interní převod dat na čísla v programu Calc. 1899-12-30 00:00:00
    =TEXT(123,456, "0.00E+#") Zde je zadaná hodnota zobrazena ve vědeckém zápisu. 1.23E+2
    =TEXT(1,5, "# ?/?") Zde je zadaná hodnota zobrazena ve zlomkovém zápisu. 1 1/2
    =TEXT(1, "BOOLEAN") Zde se zadaná hodnota zobrazí jako logická hodnota (zadaná hodnota 0 by vrátila FALSE). TRUE
    =TEXT("xyz";"=== @ ===") Zde je zadanou hodnotou řetězec, který se zobrazí jako součást delšího řetězce. === xyz ===

    Související funkce LibreOffice:

    N

    T

    ODF standard:

    Section 6.20.23, part 2

    Související (nebo podobné) funkce Excelu:

    TEXT