Dokumentation/Calc Funktionen/TEXT

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/TEXT and the translation is 100% complete.
    Other languages:


    Funktionsname:

    TEXT

    Kategorie:

    Text

    Zusammenfassung:

    Wandelt eine Zahl in ein angegebenes Format als Text um.

    Die Funktion TEXT ist vor allem nützlich, wenn eine formatierte Zahl in einen Text eingebunden werden soll.

    Syntax:

    TEXT(Zahl; Format)

    Rückgabewerte:

    Gibt eine umgewandelte Zahl als Text zurück.

    Argumente:

    Zahl ist die umzuwandelnde Zahl oder eine Referenz auf eine Zelle mit der umzuwandelnden Zahl. Diese Zahl kann in jedem im aktuellen Gebietsschema gültigen Format sein. Z. Bsp. als Dezimalzahl, in wissenschaftlicher Notation, als Bruch, Prozentangabe, Währung, Datum, Zeit oder als logischer Wert.

    Format ist ein Text (in Anführungszeichen) oder eine Refernz auf eine Zelle mit dem Text. Dieser Text gibt das Format für den Ausgabetext an. Für weiter Informationen siehe #Zusätzliche Informationen:

    • Falls das Format nicht gültig ist, meldet TEXT einen invalid argument error (Fehler:502).

    Zusätzliche Informationen:

    Den Nutzen der Funktion TEXT zeigt die folgende Formel zur Anzeige des heutigen Datums:

    ="Das heutige Datum ist der " & HEUTE()

    Unter der Annahme, dass heute der 22.08.2021 ist zeigt die Formel den Text "Das heutige Datum ist der 44430" an, wobei 44130 der Zeitstempel für den 22.08.2021 ist. Das war offensichtlich nicht im Sinne des Erfinders.

    Die folgende alternative Formel nutzt die Funktion TEXT und gibt die eher beabsichtigte Ausgabe an, ein anständig formatiertes Datum:

    ="Das heutige Datum ist der " & TEXT(HEUTE(); "dd.mm.yyyy")

    Diese Formel gibt den Text "Das heutige Datum ist der 22.08.2021".

    Beispiele für das Format finden sich auf dem Tabulator Zahlen im Dialog Zellen formatieren, im Abschnitt namens Format-Code. Diesen Dialog erreicht man mit den folgenden Methoden:

    1. Format ▸ Zellen... in der Menü-Zeile.
    2. Rechtsklick auf einer Zelle und Auswahl von Zellen formatieren... im Kontext-Menü.
    3. Tastenkombination Strg + 1

    Wenn Auswahlen in der Kategorie, dem Format, der Sprache und den Optionen im Tabulator Zahlen getroffen werden, aktualisiert Calc den Inhalt des Format-Codes, um diese Auswahlen widerzuspiegeln.

    Eine weitergehende Beschreibung zu den "Zahlen Formaten" findet sich im Hilfe-Index oder unter der entsprechenden Hilfe-Seite.

    Das Verhalten der Funktion TEXT ist abhängig vom Gebietsschema. Daher sollte sie nicht als portabel angesehen werden.

    Beispiele:

    Die folgenden Beispiele gehen davon aus, dass das Gebietsschema English (USA) verwendet wird.

    Formel Beschreibung Ergebnis
    =TEXT(12,34567; "###.##") Hier wird die mitgegebene Zahl ohne führende Nullen und auf zwei Nachkommastellen gerundet angezeigt. 12,35
    =TEXT(D1; D2), wobei die Zelle D1 die Zahl 12 enthält und die Zelle D2 den Text "000.00". Hier wird die angegebene Zahl mit einer führenden Null und auf zwei Nachkommastellen gerundet angezeigt. 012,00
    =TEXT(123.456.789, "#,###") Hier wird die angegebene Zahl mit einem Komma als Zifferngruppentrenner angezeigt. 123,456,789
    =TEXT(0,123456, "0.00%") Hier wird die angegebene Zahl als Prozentsatz angezeigt. 12.35%
    =TEXT(−6.789,4, "[$$-409]#,##0.00; -[$$-409]#,##0.00") Hier wird die angegebene Zahl als USD Währung angezeigt. Die zwei Teile des Formats sind durch einen Strichpunkt getrennt - positive Werte weden ohne Plus-Zeichen angezeigt, während negative Werte mit einem Minus-Zeichen angezeigt werden. -$6,789.40
    =TEXT(0, "YYYY-MM-DD HH:MM:SS") Hier wird die angegebene Zahl als Zeitstempel im ISO8601 Standardformat angezeigt. Der resultierende Zeitstempel ist der Startpunkt für Calc's interne Umwandlung vom Datum zur Zahl. 1899-12-30 00:00:00
    =TEXT(123,456, "0.00E+#") Hier wird die angegebene Zahl in wissenschaftlicher Notation angezeigt. 1.23E+2
    =TEXT(1,5, "# ?/?") Hier wird die angegebene Zahl als Bruch dargestellt. 1 1/2
    =TEXT(1, "BOOLEAN") Hier wird di angegebene Zahl als logischer Wert dargestellt. (ein Wert von 0 wird als FALSCH dargestellt). WAHR
    =TEXT("xyz";"=== @ ===") Hier wird die angegebene Zahl als Text, als Teil eines größeren Textes, dargestellt. === xyz ===

    Ähnliche LibreOffice Funktionen:

    N

    T

    ODF Standard:

    Kapitel 6.20.23, Teil 2.

    Betroffene (oder ähnliche) EXCEL-Funktionen:

    TEXT