# Documentation/Calc Functions/TIME

TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Donate

## Function name:

TIME

## Category:

Date and Time

## Summary:

Calculates the time (as the fractional part of a date-time serial number) for given hours, minutes, and seconds values.

## Syntax:

TIME(**Hour**; **Minute**; **Second**)

## Returns:

Returns a real number (0 ≤ x < 1) which is the fractional part of the date-time serial number calculated using the given arguments. The returned value is formatted as a time by default, but you can apply other formats as needed.

## Arguments:

**Hour** is a real number or a reference to a cell containing that value, which is the hours value to be used. Both positive and negative values are accepted along with values outside the normal range of 0 to 23.

**Minute** is a real number or a reference to a cell containing that value, which is the minutes value to be used. Both positive and negative values are accepted; values outside the normal range of 0 to 59 result in carry over to the calculated hours value.

**Second** is a real number or a reference to a cell containing that value, which is the seconds value to be used. Both positive and negative values are accepted; values outside the normal range of 0 to 59 result in carry over to the calculated minutes value.

- If any of
**Hour**,**Minute**, or**Second**is non-numeric, then TIME reports a #VALUE! error. - If no value is provided for any argument (for example,
`=TIME( ; 1; 1)`

), then TIME applies a default value of 0 for that argument. - If the value calculated is negative, then TIME returns an invalid argument error (Err:502).

## Additional details:

### Details specific to TIME function

The formula for TIME is:

- TIME = MOD(((
**HOUR***60*60) + (**MINUTE***60) +**SECOND**), (24*60*60)) / (24*60*60)

TIME does not convert argument values to integers before doing its calculations. This approach may be the cause of some minor differences between the results from the TIME functions of Calc and Microsoft Excel. However, both approaches are compliant with ODF 1.2.

### General information about Calc's Date and Time functions

- Internal to Calc,
**a date/time value is handled as a real number**and this is sometimes referred to by the term*date-time serial number*. For example, 2021-02-08 12:00:00 corresponds to the date-time serial number 44235.5. The integer part of a date-time serial number (before the decimal point) is the number of days since a defined start date. The fractional part of a date-time serial number (after the decimal point) is the time of day expressed as a fraction of a day. For example, 0.25 is equivalent to 06:00:00 and 0.75 is equivalent to 18:00:00.

- Calc uses 1899-12-30 as the
**default start date (day 0)**but you can go to**Tools > Options > LibreOffice Calc > Calculate**to select alternative start dates; however, unless you have specific requirements for compatibility with legacy spreadsheet applications, we recommend that you do not change this setting. If you copy and paste cells containing date values between different spreadsheets, check that both documents are set to use the same start date to avoid unexpected changes to the dates displayed.

**Negative date-time serial numbers**correspond to dates earlier than Calc's start date. Calc calculates all dates back to 15th October 1582 using the Gregorian calendar. The day before this is 4th October 1582, and Calc uses the Julian calendar for earlier dates.

**A date-time serial number is the same as any other number**, except that we usually choose to display it formatted as a date/time. You can enter a number in a cell and then change the cell’s formatting to display the value as a date/time. You can also enter a date/time in a cell and then change the cell’s formatting to display the date-time serial number.

- For clarity, the descriptions of the Calc functions within these wiki pages use the
**standard ISO 8601 format for date and time**because this should be independent of your selected locale settings. The default date format on your computer may be different. When entering dates as part of formulas, slashes or dashes used as date separators may be interpreted as arithmetic operators. Therefore, dates entered in this format are not recognized as dates and result in erroneous calculations. To keep dates from being interpreted as parts of formulas either use the DATE function or place the date in quotation marks and use the ISO 8601 notation. Avoid using locale dependent date formats which may produce errors if the document is loaded under different locale settings.

**Time zone information**is not used by Calc’s Date & Time functions.

- If you only wish to enter
**two digits of the year**(for example 21 instead of 2021), Calc needs to know whether you mean 2021 or 1921. Go to**Tools > Options > LibreOffice > General**to view or adjust the range of years which Calc will use to interpret two-digit year values.

- Calc contains logic to decide
**how to treat text**when encountered as an operand in an arithmetic operation or as an argument to a function that expects a number instead. In this context, unambiguous conversion is possible for ISO 8601 dates and times in their extended formats with separators. For example, the simple formula`=1 + "2021-02-08"`

will usually give the result`2021-02-09`

(when formatted as a date). However, this logic may be affected by the settings on the Detailed Calculation Settings dialog, accessed by selecting**Tools > Options > LibreOffice Calc > Formula**and pressing the**Details**button in the*Detailed Calculation Setting*s area. If a #VALUE! error occurs, it may be because the**Generate #VALUE! error**option is selected, in which case you should experiment with one of the other self-explanatory options in the*Conversion from text to number*drop-down.

## Examples:

Formula | Description | Returns |
---|---|---|

=TIME(5; 45; 30) | The function returns the value 0.239930555555556, which is the date-time serial number for the time 05:45:30. | 05:45:30 |

=TIME(25; 45; 30) | The function returns the value 0.0732638888888889, which is the date-time serial number for the time 01:45:30. Note that only the fractional part corresponding to the time of day is returned. | 01:45:30 |

=TIME(1; 30.5; 0) | The function returns the value 0.062847222222222, which is the date-time serial number for the time 01:30:30. Note how the fractional part of the minutes argument appears as 30 seconds in the calculated time. | 01:30:30 |

=TIME(D6; E6; F6) where cells D6, E6, and F6 contain the values 9, -31, and 20 respectively. | The function returns the value 0.353703703703704, which is the date-time serial number for the time 08:29:20. Note that the negative number of minutes has been processed as expected, reducing the calculated hours value with respect to the value of the Hour argument. |
08:29:20 |

## Related LibreOffice functions:

## ODF standard:

## Equivalent Excel functions:

TIME