Dokumentation/Calc Funktionen/WERT

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/VALUE and the translation is 100% complete.
    Other languages:


    Funktionsname:

    WERT

    Kategorie:

    Text

    Zusammenfassung:

    Wandelt die textuelle Darstellung der Zahl in eine numerische Form um. Falls der angegebene Text ein gültiges Datum, Zeit oder Datum + Zeit darstellt, wird der entsprechende Zeitstempel zurückgegeben.

    Syntax:

    WERT(Text)

    Rückgabewerte:

    Gibt eine Zahl zurück, die dem angegebenen Text entspricht.

    Argumente:

    Text ist eine Zeichenkette (in Anführungszeichen) oder eine Zahl oder eine Zelle mit einer dieser Typen, die die zu konvertierenden Zeichen enthält.

    • Falls der Text ein leerer Text ist, dann meldet WERT einen invalid argument error (Fehler:502).
    • Falls der Text keine Zahl, kein Datum, keine Zeit und kein Datum + Zeit in einem erkannten (Gebietsschema abhängigen) Format enthält, dann meldet WERT reports an invalid argument error (Fehler:502).

    Zusätzliche Informationen:

    Das genaue Verhalten der Funktion WERT hängt vom aktuellen Gebietsschema ab. Die folgenden Richtlinien geben mehr Informationen.

    Gebietsschema unabhängiges Verhalten

    Die folgenden Richtlinien gelten für jedes Gebietsschema:

    • WERT akzeptiert eine Reihe Zahlenformate, die keine Dezimaltrenner oder Zahlengruppentrenner enthalten. Beispiele sind: "+1234" (das "+" Zeichen kann fehlen), "-345", "2e+3" (das "+" Zeichen kann fehlen),"-2E-1", "50 %" (Zahlen, die mit dem % Zeichen enden, werden durch 100 geteilt).
    • WERT akzeptiert Brüche, angegeben als Ganzzahl gefolgt von einem Leerzeichen und dann dem Bruch. Beispiele sind: "-1 2/5", "+7 15/16" (das "+" Zeichen kann fehlen), "0 1/2" (Werte zwischen 0 und 1 werden in diesem Format mit einer 0 als Ganzzahl angegeben).
    • WERT akzeptiert Zeiten im Format "hh:mm:ss" oder "hh:mm".
    • WERT akzeptiert ein Datum im ISO 8601 Format "JJJJ-MM-DD".
    • WERT akzeptiert Datum + Zeit im ISO 8601 Format "JJJJ-MM-DDhh:mm:ss" und im verwandten Format "JJJJ-MM-DD hh:mm:ss".

    Gebietsschema-abhängiges Verhalten

    Auf einer Seite wie dieser wäre es äußerst unpraktisch, jede erdenkliche Möglichkeit in jedem möglichen Gebietsschema abzubilden. Daher beziehen sich die folgenden zusätzlichen Richtlinien auf das Verhalten der Funktion WERT beim Gebietsschema English(USA). Das sollte es ermöglichen, einiges auszuprobieren, um zusätzliches Verhalten bei jedem anderen Gebietsschema zu erkunden.

    • WERT akzeptiert eine Reihe von Zahlenformaten inklusive Dezimaltrennern (Punkt, Unicode U+002E) oder Zahlengruppentrennern (Komma, Unicode U+002C). Beispiele wären: "+1,234.567" (das "+" Zeichen kann fehlen), "-12,345.678", "+2.345e+3" (beide "+" Zeichen können fehlen), "-2.345E-1, "50,55 %" (Zahlen, die mit dem % Zeichen enden, werden durch 100 geteilt), "$45.67" (das "$"-Zeichen als Kennzeichen der US-Währungseinheit wird ignoriert).
    • WERT akzeptiert ein Datum inklusive Monatsnamen. Beispiele wären: "Jul 30, 2021" (mit 3-stelligen Monatsabkürzungen) und "July 30, 2021" (mit voll ausgeschriebenen Monatsnamen).
    • WERT akzeptiert ein Datum in den Formaten "MM/TT/JJJJ" und "MM/TT/JJ".
    • WERT akzeptiert Zeiten inklusive Sekundenbruchteilen im Format "hh:mm:ss.ss".

    Beispiele:

    Die folgenden Beispiele beziehen sich alle auf das Gebietsschema English(USA).

    Formel Beschreibung Ergebnis
    =WERT("1234") - 1234
    =WERT(1.234) Hier akzeptiert WERT ein numerisches Argument ohne Anführungszeichen. 1234
    =WERT(D1), wobei die Zelle D1 die Zahl 1234 (formatiert entweder als Zahl oder als Text) enthält. Hier wird das Argument als Zellbezug angegeben. 1234
    =WERT("+1,234.567") Hier hat das Argument sowohl einen Dezimalpunkt als auch Zifferngruppentrenner, wobei der Letztere entfernt wird. 1.234,567
    =WERT("-12,345.678") Hier hat das Argument sowohl einen Dezimalpunkt als auch Zifferngruppentrenner, wobei der Letztere entfernt wird. −12.345,678
    =WERT("+2.345e+3") Hier nutzt das Argument wissenschaftliche Notation, mit einem kleinen "e". 2345
    =WERT("-2.345E-1") Hier nutzt das Argument wissenschaftliche Notation, mit einem großen "E". −0,2345
    =WERT("50.55%") Hier enthält das Argument ein Prozentzeichen (%) am Ende, damit wird die angegebene Zahl durch 100 geteilt. 0,5055
    =WERT("$45.67") Hier wird das führende Dollar ($) Zeichen entfernt. 45,67
    =WERT("-1 2/5") Hier ist das Argument ein negativer Bruch. −1,4
    =WERT("+7 15/16") Hier ist das Argument ein positiver Bruch - das Plus (+) Zeichen wird entfernt. 7,9375
    =WERT("0 1/2") Hier ist das Argument ein Bruch. 0,5
    =WERT("09:20:25") Hier wird eine Zeit im Format hh:mm:ss umgewandelt in einen Zeitstempel. 0,389178240740741
    =WERT("09:20") Hier wird eine Zeit im Format hh:mm umgewandelt in einen Zeitstempel. 0,388888888888889
    =WERT("09:20:25.765") Hier wird eine Zeit inklusive Sekundenbruchteile umgewandelt in einen Zeitstempel. 0,389187094907407
    =WERT("2021-07-30") Hier wird ein Datum im Format JJJJ-MM-TT umgewandelt in einen Zeitstempel. 44407
    =WERT("July 30, 2021") Hier wird ein Datum mit Monatstext umgewandelt in einen Zeitstempel. 44407
    =WERT("Jul 30, 2021") Hier wird ein Datum mit abgekürztem Monat umgewandelt in einen Zeitstempel. 44407
    =WERT("07/30/2021") Hier wird ein Datum im Format MM/DD/JJJJ umgewandelt in einen Zeitstempel. 44407
    =WERT("07/30/21") Hier wird ein Datum im Format MM/DD/JJ umgewandelt in einen Zeitstempel. 44407
    =WERT("2021-07-30T09:20:25") Hier wird ein Datum + Zeit im ISO 8601 Format umgewandelt in einen Zeitstempel. 44.407,3891782407
    =WERT("2021-07-30 09:20:25") Hier wird ein Datum + Zeit in einem Format ähnlich dem ISO 8601 Format (ohne das innere "T") umgewandelt in einen Zeitstempel. 44.407,3891782407

    Ähnliche LibreOffice Funktionen:

    DATUMWERT

    ZAHLWERT

    ZEITWERT

    ODF Standard:

    Kapitel 6.16.32, Teil 2.

    Betroffene (oder ähnliche) EXCEL-Funktionen:

    VALUE