Documentatie/Calc-functies/WAARDE

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/VALUE and the translation is 100% complete.
    Other languages:


    Functienaam:

    WAARDE

    Categorie:

    Tekst

    Samenvatting:

    Converteert de tekenreeksweergave van een getal naar een numerieke vorm. Als de opgegeven tekenreeks een geldige datum, tijd of datum-tijd is, wordt het bijbehorende serienummer voor datum-tijd geretourneerd.

    Syntaxis:

    WAARDE(Tekst)

    Retourneert:

    Retourneert een getal dat overeenkomt met de opgegeven tekenreeks.

    Argumenten:

    Tekst is een tekenreeks (tussen aanhalingstekens), een getal of een verwijzing naar een cel die één van die typen bevat, die de waarde bevat die moet worden geconverteerd.

    • Als Tekst de lege tekenreeks is, retourneert WAARDE als fout Ongeldig argument (Fout:502).
    • Als Tekst geen getal, datum, tijd of datum-tijd in een herkende opmaak bevat (wat afhankelijk kan zijn van de landinstelling), dan retourneert WAARDE als fout Ongeldig argument (Fout:502).

    Aanvullende details:

    Het gedetailleerde gedrag van de functie WAARDE hangt af van de door u geselecteerde landinstelling en de volgende richtlijnen bieden meer informatie.

    Lokaal onafhankelijk gedrag

    De volgende richtlijnen zijn van toepassing op elke lokale instelling:

    • WAARDE accepteert een reeks getalnotaties die geen decimale scheidingstekens of scheidingstekens voor cijfergroepen bevatten. Voorbeelden zijn: "+1234" (het teken "+" mag worden weggelaten), "-345", "2e+3" (het teken "+" mag worden weggelaten), "-2E-1", "50%" (waarden die eindigen op het teken "%" worden gedeeld door 100).
    • WAARDE accepteert breuken, gespecificeerd als een geheel getal gevolgd door een spatie en vervolgens de breuk. Voorbeelden zijn "-1 2/5", "+7 15/16" (het teken "+" mag worden weggelaten), "0 1/2" (waarden tussen 0 en 1 worden in deze opmaak gespecificeerd door een geheel getal 0 op te nemen een deel).
    • WAARDE accepteert tijden in de opmaak "uu:mm:ss" of "uu:mm".
    • WAARDE accepteert datums in de ISO 8601 "JJJJ-MM-DD"-opmaak.
    • WAARDE accepteert datum-tijden in de ISO 8601 "JJJJ-MM-DDTuu:mm:ss" opmaak en het gerelateerde "JJJJ-MM-DD uu:mm:ss" opmaak.

    Locaal-afhankelijk gedrag

    Op een pagina als deze is het onpraktisch om elke mogelijkheid vast te leggen die zich voordoet voor alle mogelijke lokale instellingen. Daarom verwijzen de volgende aanvullende richtlijnen naar het gedrag van de functie WAARDE met de landinstelling Engels (USA) geselecteerd. Deze zouden u in staat moeten stellen om te experimenteren om extra gedrag voor uw land vast te stellen.

    • WAARDE accepteert een reeks getalnotaties met decimale scheidingstekens (volledige stop, Unicode U+002E) of cijfergroepscheidingtekens (komma, Unicode U+002C). Voorbeelden zijn: "+1.234.567" (het teken "+" mag worden weggelaten), "-12.345.678", "+2.345e+3" (beide tekens "+" mogen worden weggelaten), "-2.345E-1", " 50,55%" (waarden die eindigen op het "%"-teken worden gedeeld door 100), "$45,67" (het "$"-teken, dat de Amerikaanse munteenheid vertegenwoordigt, wordt genegeerd).
    • WAARDE accepteert datums die maandnamen bevatten. Voorbeelden zijn "Jul 30, 2021" (met behulp van afgekorte maandnamen van 3 tekens) en "July 30, 2021" (met volledige maandnamen).
    • WAARDE accepteert datums in de opmaak "MM/DD/YYYY" en "MM/DD/YY".
    • WAARDE accepteert tijden die fracties van seconden bevatten in de notatie "uu:mm:ss.ss".

    Voorbeelden:

    De volgende voorbeelden verwijzen allemaal naar de Engelse (USA) landinstelling.

    Formule Beschrijving Retourneert
    =WAARDE("1234") - 1234
    =WAARDE(1.234) Hier accepteert WAARDE een numeriek argument zonder aanhalingstekens. 1234
    =WAARDE(D1) waarbij cel D1 1234 bevat (opgemaakt als een getal of een tekenreeks). Hier wordt het argument doorgegeven als celverwijzing. 1234
    =WAARDE("+1,234.567") Hier bevat het argument zowel een decimaalteken als een groepscheidingsteken, waarbij de laatste wordt verwijderd. 1.234,567
    =WAARDE("-12,345.678") Hier bevat het argument zowel een decimaalteken als een groepscheidingsteken, waarbij de laatste wordt verwijderd. −12.345,678
    =WAARDE("+2.345e+3") Hier gebruikt het argument wetenschappelijke notatie, met een kleine "e". 2345
    =WAARDE("-2.345E-1") Hier gebruikt het argument wetenschappelijke notatie, met een hoofdletter "E". −0,2345
    =WAARDE("50.55%") Hier bevat het argument een volgend procentteken (%), zodat het opgegeven getal wordt gedeeld door 100. 0,5055
    =WAARDE("$45.67") Hier wordt het leidende euroteken (€) verwijderd. 45,67
    =WAARDE("-1 2/5") Hier is het argument een negatieve fractionele waarde. −1,4
    =WAARDE("+7 15/16") Hier is het argument een positieve fractionele waarde - het plusteken (+) is verwijderd. 7,9375
    =WAARDE("0 1/2") Hier is het argument een fractionele waarde. 0,5
    =WAARDE("09:20:25") Hier wordt een tijd in uu:mm:ss-formaat geconverteerd naar een datum-tijdvolgnummer. 0,389178240740741
    =WAARDE("09:20") Hier wordt een tijd in uu:mm formaat omgezet naar een datum-tijd volgnummer. 0,388888888888889
    =WAARDE("09:20:25.765") Hier wordt een tijd die fractionele seconden omvat, geconverteerd naar een datum-tijdvolgnummer. 0,389187094907407
    =WAARDE("2021-07-30") Hier wordt een datum in het formaat JJJJ-MM-DD omgezet naar een datum-tijdvolgnummer. 44407
    =WAARDE("July 30, 2021") Hier wordt een datum met maandtekst geconverteerd naar een datum-tijdvolgnummer. 44407
    =WAARDE("Jul 30, 2021") Hier wordt een datum met afgekorte maandtekst omgezet naar een datum-tijdvolgnummer. 44407
    =WAARDE("07/30/2021") Hier wordt een datum in MM/DD/JJJJ-formaat geconverteerd naar een datum-tijdvolgnummer. 44407
    =WAARDE("07/30/21") Hier wordt een datum in MM/DD/JJ-formaat geconverteerd naar een datum-tijdvolgnummer. 44407
    =WAARDE("2021-07-30T09:20:25") Hier wordt een datum en tijd in ISO8601-formaat geconverteerd naar een datum-tijdvolgnummer. 44.407,3891782407
    =WAARDE("2021-07-30 09:20:25") Hier worden een datum en tijd in een formaat vergelijkbaar met ISO 8601 (zonder het binnenste "T"-teken) geconverteerd naar een datum-tijdvolgnummer. 44.407,3891782407

    Gerelateerde LibreOffice-functies:

    DATUMWAARDE

    NUMERIEKE.WAARDE

    TIJDWAARDE

    ODF standaard:

    Section 6.13.34, part 2

    Gerelateerde (of gelijkwaardige) Excel-functies:

    VALUE