Documentatie/Calc-functies/IR.SCHEMA

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/XIRR and the translation is 100% complete.
    Other languages:

    Functienaam:

    IR.SCHEMA

    Categorie:

    Financieel

    Samenvatting:

    Berekent het interne rendement voor een reeks toekomstige kasstromen die niet periodiek hoeven te zijn. Het interne rendement wordt gedefinieerd als het disconteringspercentage dat resulteert in een netto contante waarde (NHW2) van nul. Interne rendementsanalyse is een financiële techniek die vaak wordt gebruikt om de waarschijnlijke winstgevendheid van een project of investering te beoordelen.

    Met IR.SCHEMA kunnen cashflows plaatsvinden op elke datum, met waarden die kunnen variëren en inkomsten (positief) of uitgaven (negatief) vertegenwoordigen. Ten minste één waarde moet negatief zijn en ten minste één waarde moet positief zijn.

    IR.SCHEMA gaat ervan uit dat alle jaren (inclusief schrikkeljaren) 365 dagen omvatten.

    IR.SCHEMA gebruikt een iteratief algoritme om de relevante vergelijking op te lossen, met de optie om een beginwaarde op te geven als een van de argumenten van de functie.

    Syntaxis:

    IR.SCHEMA(Waarden; Datums[; Geschatte waarde])

    Retourneert:

    Retourneert een reëel getal, de constante jaarlijkse disconteringsvoet die een netto contante waarde van nul oplevert voor de opgegeven cashflows. Het geretourneerde getal is een percentage dat wordt uitgedrukt als een decimale breuk (een geretourneerde waarde van 0,025 vertegenwoordigt bijvoorbeeld 2,5%).

    Argumenten:

    Waarden is een lijst met reële getallen, dit zijn de waarden van de cashflows. Waarden kan een specifiek celbereik zijn (bijvoorbeeld "$Brongegevens.A3:B12"), de naam van een benoemd of databasebereik of een inline matrix. Met betrekking tot de aangeleverde kasstromen dienen de volgende punten te worden opgemerkt:

    • Values should be the same length as the Dates argument and each should comprise at least two cells.
    • Voor elke waarde in Waarden moet er een overeenkomstige datum zijn in Datums.
    • Elke cashflow moet worden uitgedrukt in dezelfde munteenheid.
    • Elke cashflow kan positief (inkomsten) of negatief (uitgaven) zijn. Er moet minimaal één negatieve waarde en minimaal één positieve waarde zijn.

    Datums is een lijst met data, dit zijn de data waarop de cashflows plaatsvinden. Datums kan een specifiek celbereik zijn (bijvoorbeeld "$Brongegeve s.A3:B12"), de naam van een benoemd of databasebereik of een inline matrix. De volgende punten moeten worden opgemerkt met betrekking tot de verstrekte datums:

    • Datums moeten dezelfde lengte hebben als Waarden en elk moet minstens twee cellen bevatten.
    • Voor elke datum in Datums moet er een corresponderende waarde zijn in Waarden.
    • De eerste invoer in Datums wordt genomen als het begin van de kasstromen, met volgende invoer verdisconteerd naar die datum.
    • De tweede en daaropvolgende cashflows gedefinieerd in de Datums en Waarden lijsten hoeven niet in chronologische volgorde te staan.

    Geschatte waarde is een reëel getal (uitgedrukt als een percentage, zoals 2,5%, of een decimale breuk, zoals 0,025) of een verwijzing naar een cel die dat getal bevat, wat een eerste schatting is voor de jaarlijkse kortingspercentage. Dit kan worden ingevoerd als u enig idee heeft van de disconteringsvoet, maar indien weggelaten wordt uitgegaan van 0,1 (10%). Geschatte waarde moet groter zijn dan -1 (-100%).

    De volgende condities (inclusief fouten) kunnen optreden:

    • Als het aantal cellen in Waarden niet gelijk is aan het aantal cellen in Datums, dan retourneert IR.SCHEMA als foutcode Ongeldig argument (Fout:502).
    • Als het aantal cellen in Waarden kleiner is dan twee, dan retourneert IR.SCHEMA als foutcode Ongeldig argument (Fout:502).
    • Als het argument Geschatte waarde niet-numeriek is, retourneert IR.SCHEMA als foutcode Ongeldig argument (Fout:502).
    • Als het argument Geschatte waarde kleiner is dan of gelijk is aan -1 (-100%), dan retourneert IR.SCHEMA als foutcode Ongeldig argument (Fout:502).
    • Vanwege de gebruikte iteratieve methode is het mogelijk dat de berekening niet convergeert naar een resultaat. In dergelijke gevallen meldt IR.SCHEMA als foutcode Ongeldig argument (Fout:502).

    Aanvullende details:

    • De functie IR.SCHEMA berekent r in de volgende vergelijking:
    [math]\displaystyle{ \Grootte\som{i=1}^{N}~\frac{Waarden_{i}}{(1+r)^{\frac{Datums_{i}-Datums{1}}{365}}}~= ~0 }[/math]
    waarbij N het aantal kasstromen is gedefinieerd door de argumenten Waarden en Datums.
    • Gebruik de functie IR om het interne rendementspercentage voor een reeks periodieke cashflows te berekenen.
    • Als u onjuiste resultaten vermoedt voor IR.SCHEMA, zoekt u in de gegevensbereiken naar lege cellen of cellen met tekst. Gebruik de functie Beeld ▸ Waardemarkering van Calc om tekstinhoud in een gegevensbereik te markeren.
    • Er zijn problemen opgetreden bij het definiëren van de datums van cashflows in een inline matrix, zoals {"2022-01-01", "2022-07-01", "2023-01-01"}</ code>, wanneer IR.SCHEMA niet de verwachte resultaten geeft. Plaats de datums in cellen of gebruik equivalente datum-tijd-serienummers in de inline matrix(bijvoorbeeld {44562, 44743, 44927}).
    • Ga voor meer achtergrondinformatie over intern rendement naar de Wikipedia-pagina Intern rendement.

    Voorbeelden:

    Datums in de volgende voorbeelden zijn opgemaakt in overeenstemming met de ISO 8601-standaard (JJJJ-MM-DD). Andere locatie-afhankelijke datumnotaties zullen beschikbaar zijn voor uw Calc-installatie. Merk op dat het vaak een goede gewoonte is om de functie DATUM te gebruiken in plaats van opgemaakte datumwaarden te typen.

    De volgende tabel toont de gegevens die in het eerste voorbeeld hieronder zijn gebruikt.

    Gegevens bij voorbeeld van IR.SCHEMA functie
    A B
    1 Waarde Datum
    2 −3500 2021-03-31
    3 100 2021-06-30
    4 150 2021-09-30
    5 200 2021-12-31
    6 250 2022-03-31
    7 300 2022-06-30
    8 350 2022-09-30
    9 400 2022-12-31
    10 450 2023-03-31
    11 500 2023-06-30
    12 550 2023-09-30
    13 600 2023-12-31
    Formule Beschrijving Retourneert
    =IR.SCHEMA(A2:A13; B2:B13) waarbij cellen A2:B13 de waarden bevatten die in de bovenstaande tabel worden weergegeven. Hier berekent de functie het interne rendement voor twaalf driemaandelijkse kasstromen. Het argument Geschatte waarde wordt weggelaten en dus wordt de standaardwaarde van 0,1 (10%) toegepast. De functie retourneert de waarde 0,0530 (tot op vier decimalen), gelijk aan 5,30%. Merk op dat de formule =NHW2(IR.SCHEMA(A2:A13; B2:B13); A2:A13; B2 :B13) retourneert een zeer klein getal dat ongeveer gelijk is aan 0,0. 0,0530
    =IR.SCHEMA(A1:A6; B1:B6; C1) waarbij de cellen A1:A6 respectievelijk de waarden -30000, 4000, 9000, 15000, 19000 en 26000 bevatten; cellen B1:B6 bevatten respectievelijk de datums 01-01-2020, 01-01-2021, 01-01-2022, 01-01-2023, 01-01-2024 en 01-01-2025; cel C1 bevat de waarde 35%. Hier berekent de functie het interne rendement voor de zes cashflows die zijn gedefinieerd in de cellen A1:B6, met behulp van een initiële schatting die is gedefinieerd in cel C1. De functie retourneert de waarde 0,2850 (tot op vier decimalen), gelijk aan 28,50%. Merk op dat de formule =NHW2(IR.SCHEMA(A1:A6; B1:B6); A1:A6; B1 :B6) retourneert een zeer klein getal dat ongeveer gelijk is aan 0,0. 0,2850
    =IR.SCHEMA({-2750, 1000, 2000}; {44597, 44747, 44931}) Hier berekent de functie het interne rendement voor drie cashflows. De waarden 44597, 44747 en 44931 zijn de datum-tijd-serienummers voor respectievelijk 2022-02-05, 2022-07-05 en 2023-01-05. De functie retourneert de waarde 0,1241 (tot op vier decimalen), gelijk aan 12,41%. 0,1241

    Gerelateerde LibreOffice-functies:

    IR

    NHW2

    ODF standaard:

    Sectie 6.12.51, deel 2

    Gerelateerde (of gelijkwaardige) Excel-functies:

    XIRR