Documentation/Fonctions Calc/AMORDEGRC
TDF LibreOffice Document Liberation Project Blogs communautaires Weblate Nextcloud Redmine Ask LibreOffice Donner
Nom de la fonction :
AMORDEGRC
Catégorie :
Analyse financière
Résumé :
Calcule l'amortissement d'un actif sur une période donnée à l'aide d'un modèle d'amortissement dégressif. Cette méthode prévoit un taux d'amortissement plus élevé au début, puis décroissant sur la durée de vie utile de l'actif. Si l'actif est acquis en cours d'exercice, l'amortissement pour cette période est calculé au prorata.
AMORDEGRC est destiné aux utilisateurs du système comptable français.
Syntaxe :
AMORDEGRC(Coût; Date d'achat; Première période; Récupération; Période; Taux[; Base])
Renvoie :
Renvoie un nombre réel non négatif qui correspond à l'amortissement de l'actif au cours de la période spécifiée, exprimé dans les mêmes unités monétaires que le coût et les valeurs de récupération de l'actif.
Arguments :
Coût est un nombre réel positif, ou une référence à une cellule contenant ce nombre, qui est le coût ou la valeur de l'actif avant amortissement.
Date d'achat est une date, ou une référence à une cellule contenant cette date, qui correspond à la date de début de l'amortissement. Pour un actif corporel, il s'agit généralement de la date d'acquisition.
Première période est une date, ou une référence à une cellule contenant cette date, qui est la date de fin de la première période comptable au cours de laquelle l'amortissement est calculé.
Récupération est un nombre réel positif, ou une référence à une cellule contenant ce nombre, qui est la valeur résiduelle de l'actif à la fin de sa durée de vie amortie. Récupération doit être dans les mêmes unités monétaires que Coût.
Période est un entier non négatif, ou une référence à une cellule contenant cet entier, qui spécifie la période comptable pour laquelle la valeur d'amortissement est renvoyée. La valeur 0 indique la période se terminant à la date indiquée par Première période. Les périodes comptables suivantes sont numérotées 1, 2, 3, et ainsi de suite.
Taux est un nombre réel positif (exprimé sous forme de pourcentage, tel que 2,5 %, ou de fraction décimale, telle que 0,025), ou une référence à une cellule contenant ce nombre, qui est le taux annuel auquel la valeur de l'actif est amortie.
Base est un entier compris entre 0 et 4, ou une référence à une cellule contenant cet entier, qui indique comment l'année doit être calculée. Pour plus d'informations, consultez la page Wikipédia [1] (Convention de comptage des jours).
Base | Calcul |
---|---|
0 ou manquant | Méthode américaine (NASD), 12 mois de 30 jours chacun |
1 | Nombre exact de jours dans les mois, nombre exact de jours dans l'année. |
2 | Nombre exact de jours dans le mois, l'année compte 360 jours. |
3 | Nombre exact de jours dans le mois, l'année compte 365 jours. |
4 | Méthode européenne, 12 mois de 30 jours chacun. |
- Si l'une des dates Date d'achat ou Première période n'est pas une date valide, alors AMORDEGRC renvoie une erreur #VALEUR !.
- Si l'un des éléments Coût, Récupération, Période ou Taux n'est pas numérique, alors AMORDEGRC signale une erreur #VALEUR !.
- Si Base n'est pas numérique, alors AMORDEGRC signale une erreur d'argument non valide (Err :502).
- Si Date d'achat est postérieure à Première période, alors AMORDEGRC signale une erreur d'argument non valide (Err :502).
- Si Coût ou Taux est inférieur ou égal à 0, alors AMORDEGRC signale une erreur d'argument non valide (Err :502).
- Si Récupération est inférieur à 0 ou supérieur à Coût, alors AMORDEGRC signale une erreur d'argument non valide (Err :502).
- Si l'une des valeurs Période ou Base est une valeur non entière, alors AMORDEGRC la tronque en une valeur entière.
- Si Période est inférieur à 0, alors AMORDEGRC signale une erreur d'argument non valide (Err :502).
- Si, après une troncature, Base n'est pas égal à 0, 1, 2, 3 ou 4, alors AMORDEGRC signale une erreur d'argument non valide (Err :502).
Détails complémentaires :
- AMORDEGRC utilise un facteur d'amortissement (f) qui dépend de la durée de vie ([math]\displaystyle{ t~=~\frac{1}{Taux} }[/math]) de l'actif. Ce facteur vise à augmenter le taux d'amortissement des actifs à durée de vie plus longue. Il est défini comme suit :
Durée de vie de l'actif (t) | Facteur d'amortissement (f) |
---|---|
t < 3 | 1 |
3 <= t < 5 | 1,5 |
5 <= t <=6 | 2 |
t > 6 | 2,5 |
- Si Période = 0, l'amortissement est calculé au prorata. Pour cette période, la formule de AMORDEGRC est :
- [math]\displaystyle{ \operatorname{AMORDEGRC_{0}}~=~f*Coût~*~Taux~*~\operatorname{FRACTION.ANNEE}(Date~d'achat; Première~période; Base) }[/math]
- Si Date d'achat est égale à Première période, alors [math]\displaystyle{ \operatorname{AMORDEGRC_{0}}~=~0 }[/math]
- Pour les périodes suivantes, AMORDEGRC calcule l'amortissement en fonction du coût ou de la valeur de l'actif avant amortissement moins l'amortissement total des périodes précédentes.
- Si Période = 1, l'amortissement est calculé comme suit.
- [math]\displaystyle{ \operatorname{AMORDEGRC_{1}}~=~f*(Coût-AMORDEGRC_{0})~*~Taux }[/math]
- Si Période = 2, l'amortissement est calculé comme suit.
- [math]\displaystyle{ \operatorname{AMORDEGRC_{2}}~=~f*(Coût-AMORDEGRC_{0}-AMORDEGRC_{1})~*~Taux }[/math]
- Ce traitement se poursuit pour les périodes suivantes jusqu'à la fin de la durée d'amortissement. L'amortissement total sur toutes les périodes ne sera pas supérieur à la valeur de l'actif avant amortissement, indiquée dans l'argument Coût.
- Il existe quelques différences entre le comportement de AMORDEGRC dans Calc et Microsoft Excel.
- Excel ne prend pas en charge l'option 2 pour l'argument Base (nombre réel de jours dans le mois, 360 jours dans l'année).
- Calc et Excel se comportent différemment lorsque la date d'achat coïncide avec la fin d'une période comptable. Calc considère la période initiale 0 comme étant de durée nulle et renvoie donc un amortissement nul. Excel considère la période initiale 0 comme la première période complète.
- À mesure que l'argument Période est augmenté, la dernière période qui renvoie une valeur d'amortissement différente de zéro peut renvoyer des valeurs différentes pour Calc et Excel.
- Il peut y avoir des différences d'arrondi mineures entre les valeurs renvoyées par Excel et Calc.
- Ces différences peuvent limiter l’interopérabilité lorsque vous disposez d’une feuille de calcul Calc contenant des appels AMORDEGRC qui est ensuite ouverte dans Excel.
- Pour plus d’informations générales sur la dépréciation et l’amortissement, consultez les pages Amortissement et Amortissement (business) de Wikipédia.
Exemples :
Exemple simple avec plusieurs appels à AMORDEGRC
Le tableau suivant illustre le comportement de la fonction AMORDEGRC.
A | B | C | D | E | |
---|---|---|---|---|---|
1 | Coût | 1200 | Période | Amortissement | |
2 | Date d'achat | 2022-07-01 | 0 | 225 | |
3 | Première période | 2022-12-31 | 1 | 366 | |
4 | Récupération | 200 | 2 | 228 | |
5 | Période | - | 3 | 143 | |
6 | Taux | 15% | 4 | 119 | |
7 | Base | 0 | 5 | 0 | |
8 | 6 | 0 | |||
9 | 7 | 0 | |||
10 | 8 | 0 | |||
11 | |||||
12 | Total | 1081 |
Les données des cellules B1:B4 et B6:B7 contiennent les valeurs de la plupart des arguments passés dans les appels de fonction AMORDEGRC. La fonction est appelée neuf fois, une fois pour chaque valeur de l'argument Période donnée dans les cellules D2 à D10. La cellule E2 contient la formule =AMORDEGRC($B$1; $B$2; $B$3; $B$4; $D2; $B$6; $B$7)
; la cellule E3 contient la formule =AMORDEGRC($B$1; $B$2; $B$3; $B$4; $D3, $B$6, $B$7)
; et ainsi de suite. Les valeurs renvoyées par les appels AMORDEGRC sont affichées dans les cellules E2 à E10, et la cellule E12 contient la somme de toutes les valeurs des cellules E2 à E10. Les caractéristiques suivantes sont visibles dans ces résultats :
- Pour cet exemple de données, l'amortissement est calculé sur une période partielle (période 0) et quatre périodes comptables complètes (périodes 1 à 4).
- Période 0. Étant donné que l'actif a été acquis au milieu de la période comptable, l'amortissement pour la période 0 est calculé au prorata comme suit : [math]\displaystyle{ 1 200 \times 0,5 \times 2,5 \times 0,15~=~225 }[/math].
- Période 1. Pour cette période comptable complète, l'amortissement est calculé comme [math]\displaystyle{ (1200-225) \times 2,5 \times 0,15~=~365,625 }[/math] et AMORDEGRC arrondit cette valeur à 366.
- Les valeurs d’amortissement pour les périodes 2 et 3 sont calculées de manière similaire à la période 1.
- Pendant les périodes 0 à 3, l'amortissement total est de 962. Étant donné que Coût - Récupération - 962 est supérieur à 0, AMORDEGRC détermine qu'il doit y avoir une charge d'amortissement finale dans la période 4. Cependant, au lieu d'utiliser le même algorithme que les étapes 1 à 3, le nombre renvoyé pour la période 4 est la moitié de la différence entre la valeur d'origine de l'argument Coût (1200 dans ce cas) moins l'amortissement total dans les périodes précédentes (962 dans ce cas), soit [math]\displaystyle{ 0,5 \times 238 }[/math] ou [math]\displaystyle{ 119 }[/math].
- Pour les périodes 5 ou ultérieures, AMORDEGRC renvoie 0.
Exemples supplémentaires
Formule | Description | Renvoie |
---|---|---|
=AMORDEGRC(1500; "2001-04-01"; "2001-06-15"; 454; 0; 0,19; 2) | Ici, la fonction calcule l'amortissement au prorata pour la période 0, qui est une courte période d'environ 2,5 mois. | 119 |
=AMORDEGRC(1500; "2001-04-01"; "2001-06-15"; 454; 0; 0,19) | Ici, la fonction calcule à nouveau l'amortissement au prorata pour la période 0, soit une courte période d'environ 2,5 mois. Cependant, dans ce cas, la valeur de l'argument Base n'est pas spécifiée ; la valeur par défaut est donc 0, ce qui donne un résultat légèrement différent de l'exemple précédent. | 117 |
=AMORDEGRC(1500; "2001-04-01"; "2001-06-15"; 454; 1; 0,19; 2) | Ici, la fonction calcule le montant de l'amortissement pour une période comptable complète (période 1). | 525 |
=AMORDEGRC(2000; DATE(2020; 2; 1); DATE(2020; 12; 31); 10; 4; 10%; 0) | Ici, la fonction calcule le montant de l'amortissement pour une période comptable complète (période 4). Notez qu'il est souvent recommandé d'utiliser la fonction DATE plutôt que de saisir des valeurs de date formatées. | 163 |
Fonctions LibreOffice associées :
Standard ODF :
Aucun
Fonctions Excel relatives (ou similaires) :
AMORDEGRC