Dokumentation/Calc Funktionen/UND
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende
Funktionsname:
UND
Kategorie:
Logisch
Zusammenfassung:
Testet mehrere Bedingungen und überprüft, ob alle zutreffen. Wenn alle Bedingungen zutreffen, wird WAHR zurückgegeben, ansonsten wird FALSCH zurückgegeben.
Syntax:
UND(Logischer Wert 1 [; Logischer Wert 2 [; … [; Logischer Wert 255]]])
Rückgabewerte:
Gibt den logischen Wert WAHR zurück, wenn alle Bedingungen zutreffen. Gibt den logischen Wert FALSCH zurück, wenn eine oder mehr der angegebenen Bedingungen nicht zutreffen. In anderen Worten gibt die Funktion den logischen Wert FALSCH zurück, wenn wenigstens eine der angegebenen Bedingungen nicht zutrifft.
Argumente:
Logischer Wert 1, Logischer Wert 2, … , Logischer Wert 255 geben die zu überprüfenden Bedingungen an. Jede Bedingung gibt einen Ausdruck an, der entweder WAHR oder FALSCH sein kann. Falls ein Ausdruck eine Zahl statt eines logischen Ausdruckes ist, wird 0 (Null) als FALSCH und alle anderen Zahlen als WAHR behandelt. Jedes Argument kann eine der folgenden Formen annehmen:
- Ein logischer Ausdruck oder ein Ausdruck, der als logischer Ausdruck gewertet werden kann. Beispiele sind WAHR, 3, 1 < 5, 2 + 3 = 7, A2 * A3, und B8 < 10.
- Eine Referenz auf eine Zelle mit einem logischen Ausdruck.
- Eine Referenz auf einen Zellbereich mit logischen Ausdrücken (z. Bsp. D6:E12 or A1:B9~E12:E14).
- Der Name eines benannten Bereiches, wobei die Zellen logische Ausdrücke enthalten.
- Der Name eines Datenbankbereiches, wobei die Zellen logische Ausdrücke enthalten.
- Eine Aufzählung von logischen Ausdrücken oder Zahlen (zum Beispiel {WAHR, FALSCH, 0, 123,456}).
Beachten Sie, dass UND bis zu 255 Argumente akzeptiert. Trotzdem können Sie Zellbereiche angeben. Dadurch können auch viel mehr als 255 Dezimalzahlen verarbeitet werden.
- Falls die Argumente nicht wenigstens einen logischen Ausdruck haben, dann meldet UND einen #WERT!-Fehler zurück.
- Falls die Argumente genau einen Wert haben, gibt UND diesen logischen Wert zurück.
- Falls ein Argument eine Zeichenkette in Anführungszeichen ist, dann meldet UND einen #WERT! Fehler. Das trifft nicht für Referenzen auf Zellen zu, die Zeichenketten enthalten.
- Leere Zellen und Zellen mit Text werden von UND ignoriert.
- Falls eine Zelle einen Fehler enthält, dann gibt UND diesen Fehler unabhängig vom Inhalt der anderen Zellen zurück.
Zusätzliche Informationen:
Spezifische Eigenheiten der Funktion UND
- In seiner einfachsten Form ist das logische UND (manchmal auch logische Konjunktion genannt) von zwei logischen Werten eine Operation mit dem Ergebnis WAHR, falls beide seiner Operanden WAHR ist. Ansonsten ist das Ergebnis FALSCH. Dies kommt in der folgenden Wahrheitstabelle zu Ausdruck.
| Operand 1 | Operand 2 | Operand 1 UND Operand 2 |
|---|---|---|
| wahr | wahr | wahr |
| wahr | falsch | falsch |
| falsch | wahr | falsch |
| falsch | falsch | falsch |
- UND ignoriert jeden Text oder leere Zellen in einem Zellbereich. Falls Sie falsche Ergebnisse vermuten, kontrollieren Sie, ob Texte in den angegebenen Zellbereich(en) sind. Um Textinhalte hervorzuheben, nutzen Sie den Punkt ▸ .
- Obwohl UND auch alleine genutzt werden kann, ist es oft viel nützlicher, wenn sie mit anderen Funktionen kombiniert wird. Wenn Sie z. Bsp. in der Zelle A1 einen Wert zwichen 1 und 10 erwarten, können Sie folgendermaßen formulieren:
=WENN(UND(A1>=1; A1<=10); "Innerhalb des Bereiches"; "Außerhalb des Bereiches")
Allgemeine Informationen über die logischen Funktionen in Calc
 |
Anmerkung:
|
Calc verwendet die Zahlen 0 (FALSCH) und 1 (WAHR) um logische Werte auszudrücken. Geben Sie zum Beispiel 1 in eine Zelle im allgemeinen Zahlenformat ein. Gehen Sie dann auf ▸ in der Menüleiste, wählen Sie Wahrheitswert im Feld Kategorie des Tabs Zahlen und klicken auf . Beachten Sie, das die Zahl 1 jetzt als WAHR angezeigt wird. Um die Anzeige zurückzustellen, wiederholen Sie den Vorgang, wählen Sie aber Dezimalzahl anstatt Wahrheitswert.
Um einen logischen Wert in eine Zelle einzugeben, tippen Sie einfach WAHR oder FALSCH (case-insensitive) in die Zelle ein. Calc erkennt den logischen Wert, zeigt ihn in Großbuchstaben an und ändert die Formatierung der Zelle auf Wahrheitswert.
Calc Funktionen, die einen Wahrheitswert erzeugen, geben ihn als Zahl, entweder 0 oder 1, zurück. Im Fall einer Formel, die eine solche logische Funktion aufruft und in einer Zelle mit einer Formatierung zur Dezimalzahl wird die Formatierung der Zelle auf einen Wahrheitswert geändert. Dabei wird der Rückgabewert als FALSCH oder WAHR angezeigt. Zum Beispiel gibt =WAHR() den Wert 1 zurück. Dieser wird als WAHR angezeigt. Falls Sie die Formatierung der Zelle auf Dezimalzahl ändern, wird die Zahl 1 angezeigt.
Calc Funktionen, die auf einen Wahrheitswert testen, tun dies immer, in dem Sie den Ausdruck auf den Wert 0 testen. Der Wert 0 wird als FALSCH angesehen. Jeder andere Wert wird als WAHR angesehen. Zum Beispiel gibt =NICHT(0) WAHR zurück, während =NICHT(57.89) FALSCH zurückgibt.
Im Gegensatz zu Calc hat Microsoft EXCEL einen seperaten Typ für logische Werte - sie sind keine Zahlen sondern werden manchmal in Zahlen umgewandelt. Also Vorsicht bei Kompatibilitätsbedarf.
Beispiele:
| A | B | C | D | |
|---|---|---|---|---|
| 1 | =WAHR() | 45 | 2,2 | |
| 2 | =NICHT(FALSCH()) | 3 | ||
| 3 | 1 | -5,4 | ||
| 4 | 2 | |||
| 5 | 3 | "Bedingungen": A1:A5
|
⇐ benannter Bereich
|
| Formel | Beschreibung | Ergebnis |
|---|---|---|
| =UND(FALSCH(); WAHR()) | Eines der Argumente ist nicht WAHR. | FALSCH |
| =UND(WAHR(); C1>10; FALSCH()) | Eines der Argumente ist nicht WAHR | FALSCH |
| =UND(D1:D3) | Alle angegebenen Zahlen sind nicht gleich 0 (Null). | WAHR |
| =UND({2; 4; 6; 8}) | Alle angegebenen Zahlen sind nicht gleich 0 (Null). | WAHR |
| =UND(12<13; 14>12; 7<6) | Das dritte Argument ist FALSCH | FALSCH |
| =UND(Bedingungen) | Alle Zellen im benannten Bereich sind entweder WAHR oder nicht 0 (Null). | WAHR |
Ähnliche LibreOffice Funktionen:
ODF Standard:
Betroffene (oder ähnliche) EXCEL-Funktionen:
AND