Dokumentace/Výpočetní funkce/A
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Donate
Název funkce:
AND
Kategorie:
Logické
Shrnutí:
Testuje více podmínek pro určení, jestli jsou all splněny.
Syntaxe:
AND(Logická hodnota 1 [; Logická hodnota 2 [; … [; Logická hodnota 255]]])
Vrátí:
Navrací logickou hodnotu TRUE pokud jsou dodané podmínky all splněny. Navrací logickou hodnotu FALSE pokud nejsou splněny podmínky one nebo more. Jinak řečeno, kunkce navrací logickou hodnotu FALSE pokud alespoň jedna at least one z vybraných podmínek není not splněna.
Argumenty:
Logická Hodnota 1, Logická Hodnota 2, … ,Logická hodnota 255uvádí soubor podmínek, které se mají zkontrolovat. Každá podmínka by měla obsahovat výraz, který se hodnotí tak, že dává hodnotu , která je buď TRUE nebo FALSE. Pokud se výraz hodnotí jako číslo místo logické hodnoty, tak se hodnota 0 (nula) bere jako FALSE a všechny non-zero numerické hodnoty jako TRUE. Každý argument může mít jednu z následujících forem:
- Logická hodnota nebo výraz, který se může hodnotit jako logická hodnota.
Příklady zahrnují TRUE, 3, 1<5, 2+3=7, A2*A3, a B8<10.
- Odkaz na jednu buňku obsahující logickou hodnotu nebo výraz.
- Odkaz na rozsah buněk obsahujících logické hodnoty nebo výrazy (například, D6:E12 nebo A1:B9~E12:E14)..
- Název nazvaného rozsahu skládající se z buněk obsahujících logické hodnoty nebo výrazy.
- Název rozsahu databáze skládající se u buněk obsahujících logické hodnoty nebo výrazy.
- Pole řádků logických hodnot nebo čísel (například {TRUE, FALSE, 0, 123,456}).
Všimněte si, že ačkoliv AND může přijmout až 255 argumentů, každý argument může uvést rozsah buněk. To znamená, že počet zpracovaných podmínek může být více než 255.
- Pokud argument nedává alespoň jednu logickou hodnotu, tak AND se hlásí jako #VALUE! chyba.
- Pokud dává argument přesně jednu hodnotu, tak AND navrací onu logickou hodnotu.
- Pokud je jakýkoliv argument v řetězci uvozovek, tak se AND hlásí jako #VALUE! chyba. Toto se nevztahuje na odkazy k buňkám obsahujících řetězce.
- Prázdné buňky a buňky, které obsahují text jsou ignorované AND.
- Pokud buňka obsahuje chybnou hodnotu, tak AND šíří tuto chybu bez ohledu na obsah dalších buněk.
Další detaily:
Podrobnosti specifické pro AND funkce
- V nejjednodušší formě, logické AND (někdy známé jako logical conjunction) ze dvou logických hodnot je operace, která vytváří hodnotu TRUE pokud both jeho operandy jsou pravdivé, jinak je výsledek FALSE. Může být vyjádřen jako tabulka pravdivosti takto:
Operanda 1 | Operanda 2 | Operanda 1 AND Operand 2 |
---|---|---|
true | true | true |
true | false | false |
false | true | false |
false | false | false |
- AND ignoruje jakékoliv texty v buňkách nebo prázdné buňky. Pokud máte podezření pro špatné výsledky, hledejte text bez přidaných rozsahů dat. Zvýraznění textového obsahu v rámci datového rozsahu použijte funkce ▸ výpočtu.
- Nicméně můžete použít samotnou AND, je to kolikrát mnohem užitečnější v kombinaci s dalšími funkcemi. Například, berte v potaz hodnotu v buňce A1, u které očekáváte, že bude v oblasti 1 až 10. Můžete vložit vzorec jako
=IF(AND(A1>=1; A1<=10); "v oblasti"; "mimo oblast")
do dalších buněk, abyste zkontrolovali, jestli je hodnota v buňce A1 v rámci očekávané oblasti.
Obecné informace o logických funkcích v Calcu
Calc používá čísla 0 (FALSE) a 1 (TRUE) pro vyjádření logických hodnot. Například zadejte 1 do buňky, která má výchozí obecný formát čísla. Poté zvolte na panelu nabídek
▸ , čímž zobrazíte dialogové okno Formátovat buňky, v oblasti Kategorie na kartě Čísla vyberte možnost Booleovská hodnota a klepněte na tlačítko . Všimněte si, že číslo 1 je nyní zobrazeno jako TRUE. Chcete-li se vrátit k zobrazení čísla 1, zopakujte postup, ale místo možnosti Booleovská hodnota vyberte možnost Číslo'.Chcete-li do buňky zadat logickou hodnotu, jednoduše do ní napište buď TRUE, nebo FALSE (bez ohledu na velikost písmen). Calc logickou hodnotu rozpozná, zobrazí ji velkými písmeny a změní formát buňky na formát vhodný pro logické hodnoty.
Funkce Calc, které vytvářejí logický výsledek, vracejí číslo, buď 0 nebo 1. V případě vzorce, který jednoduše volá takovou logickou funkci a je v buňce, která má výchozí obecný formát čísla, se buňka přepne na formát booleovské hodnoty a vrácená hodnota se zobrazí jako FALSE nebo TRUE. Například =TRUE()
vrátí hodnotu 1, která se zobrazí jako TRUE; pokud potom změníte formát na číselný formát, zobrazí se jako číslo 1.
Funkce Calcu, které testují logický výsledek, vždy vyhodnotí testovaný výraz a zkontrolují, zda se rovná 0. Hodnota 0 je brána jako FALSE a jakákoli jiná hodnota je brána jako TRUE. Například =NOT(0)
vrátí hodnotu TRUE a =NOT(57,89)
vrátí hodnotu FALSE.
Na rozdíl od Calcu má Microsoft Excel samostatný typ pro logické hodnoty - nejsou to čísla, ale někdy se na čísla převádějí. Dejte si proto pozor, pokud potřebujete kompatibilitu.
Příklady:
A | B | C | D | |
---|---|---|---|---|
1 | =TRUE() | 45 | 2,2 | |
2 | =NOT(FALSE()) | 3 | ||
3 | 1 | -5,4 | ||
4 | 2 | |||
5 | 3 | "Podmínky": A1:A5
|
⇐ pojmenované oblasti
|
Vzorec | Popis | Vrátí |
---|---|---|
=AND(FALSE(); TRUE()) | Jeden z argumentů je nepravda. | FALSE |
=AND(TRUE(); C1>10; FALSE()) | Jeden z argumentů je nepravda. | FALSE |
=AND(D1:D3) | Všechny dodané numerické hodnoty se nerovnají 0 (nule). | TRUE |
=AND({2; 4; 6; 8}) | Všechny dodané numerické hodnoty se nerovnají 0 (nule). | TRUE |
=AND(12<13; 14>12; 7<6) | Třetí argument je nepravda. | FALSE |
=AND(Podmínky) | Všechny buňky ve jmenované oblasti jsou buď TRUE nebo ne 0 (nula). | TRUE |
Související funkce LibreOffice:
ODF standard:
Související (nebo podobné) funkce Excelu:
AND