Documentation/Fonctions Calc/ET
TDF LibreOffice Document Liberation Project Blogs communautaires Weblate Nextcloud Redmine Ask LibreOffice Donner
Nom de la fonction :
ET
Catégorie :
Logique
Résumé :
Teste plusieurs conditions pour déterminer si toutes sont remplies. VRAI est renvoyé si toutes les conditions sont remplies ; sinon, FAUX est renvoyé.
Syntaxe :
ET(Valeur logique 1 [; Valeur logique 2 [; … [; Valeur logique 255]]])
Renvoie :
Renvoie la valeur logique VRAI si toutes les conditions fournies sont remplies.
Renvoie la valeur logique FAUX lorsque une ou plusieurs des conditions fournies ne sont pas remplies.
En d'autres termes, la fonction renvoie la valeur logique FAUX si au moins une des conditions fournies n'est pas remplie.
Arguments :
Valeur logique 1', Valeur logique 2, … , Valeur logique 255 indiquent l'ensemble des conditions à vérifier.
Chaque condition doit comprendre une expression dont l'évaluation donne une valeur logique égale à VRAI ou FAUX.
Si une expression donne un nombre plutôt qu'une valeur logique, la valeur 0 (zéro) est considérée comme FAUX et toutes les valeurs numériques non nulles sont considérées comme VRAI.
Chaque argument peut prendre l'une des formes suivantes :
- Une valeur logique, ou une expression pouvant être évaluée comme telle. Les exemples incluent VRAI, 3, 1<5, 2+3=7, A2*A3, et B8<10.
- Une référence à une cellule unique contenant une valeur ou une expression logique.
- Une référence à une plage de cellules contenant des valeurs ou des expressions logiques (par exemple, D6:E12 ou A1:B9~E12:E14).
- Le nom d'une plage nommée, comprenant des cellules contenant des valeurs logiques ou des expressions.
- Le nom d'une plage de base de données, comprenant des cellules contenant des valeurs logiques ou des expressions.
- Une matrice en ligne de valeurs logiques ou de nombres (par exemple {VRAI, FAUX, 0, 123,456}).
Notez que même si ET peut accepter jusqu'à 255 arguments, chaque argument peut spécifier une plage de cellules. Cela signifie que le nombre de conditions traitées pourrait être bien supérieur à 255.
- Si les arguments ne donnent pas au moins une valeur logique, alors ET signale une erreur #VALEUR !.
- Si les arguments donnent exactement une valeur, alors ET renvoie cette valeur logique.
- Si un argument est une chaîne entre guillemets, ET renvoie une erreur #VALEUR !. Ceci ne s'applique pas aux références à des cellules contenant des chaînes.
- Les cellules vides et les cellules contenant du texte sont ignorées par ET.
- Si une cellule contient une valeur d'erreur, alors ET propage cette erreur, quel que soit le contenu des autres cellules.
Détails complémentaires :
Détails spécifiques à la fonction ET
- Dans sa forme la plus simple, la logique ET (parfois appelée conjonction logique) de deux valeurs logiques est une opération qui produit la valeur VRAI si ses deux opérandes sont vraies ; sinon, le résultat est FAUX. Elle peut être exprimée sous forme de table de vérité comme suit :
Opérande 1 | Opérande 2 | Opérande 1 ET Opérande 2 |
---|---|---|
vrai | vrai | vrai |
vrai | faux | faux |
faux | vrai | faux |
faux | faux | faux |
- ET ignore le texte dans les cellules, qu'il soit vide ou non. Si vous suspectez des résultats erronés, recherchez du texte dans les plages de données fournies. Pour surligner du texte dans une plage de données, utilisez la fonctionnalité ▸ de Calc.
- Bien que vous puissiez utiliser ET seule, elle est souvent bien plus utile combinée à d'autres fonctions. Par exemple, imaginons une valeur dans la cellule A1 comprise entre 1 et 10. Vous pouvez placer une formule telle que
=SI(ET(A1>=1; A1<=10); "Dans la plage"; "Hors plage")
dans une autre cellule pour vérifier si une valeur de la cellule A1 est comprise dans la plage attendue.
Informations générales sur les fonctions logiques de Calc
Calc utilise les nombres 0 (FAUX) et 1 (VRAI) pour représenter les valeurs logiques. Par exemple, saisissez 1 dans une cellule au format numérique général par défaut. Sélectionnez ensuite
▸ dans la barre de menus pour afficher la boîte de dialogue Format de cellule, sélectionnez l'option Valeur logique dans la zone Catégorie de l'onglet Nombres, puis cliquez sur le bouton . Notez que le nombre 1 s'affiche désormais sous la forme FAUX. Pour revenir à l'affichage du nombre 1, répétez l'opération, mais sélectionnez Nombre au lieu de Valeur logique.Pour saisir une valeur logique dans une cellule, saisissez simplement VRAI ou FAUX (insensible à la casse). Calc reconnaîtra la valeur logique, l'affichera en majuscules et adaptera le format de la cellule aux valeurs booléennes.
Les fonctions Calc qui produisent un résultat logique renvoient un nombre, 0 ou 1. Dans le cas d'une formule appelant simplement une telle fonction logique et se trouvant dans une cellule au format numérique général par défaut, la cellule passe au format de valeur logique et la valeur renvoyée s'affiche sous la forme FAUX ou VRAI. Par exemple, =VRAI()
renvoie la valeur 1, qui s'affiche sous la forme VRAI ; si vous passez ensuite au format numérique, la valeur affichée est 1.
Les fonctions Calc qui testent un résultat logique évaluent toujours l'expression à tester et vérifient si elle est égale à 0. La valeur 0 est considérée comme FAUX et toute autre valeur est considérée comme VRAI. Par exemple, =NON(0)
renvoie VRAI et =NON(57.89)
renvoie FAUX.
Contrairement à Calc, Microsoft Excel dispose d'un type distinct pour les valeurs logiques : elles ne sont pas des nombres, mais sont parfois converties en nombres. Soyez donc vigilant si vous avez besoin de compatibilité.
Exemples :
A | B | C | D | |
---|---|---|---|---|
1 | =VRAI() | 45 | 2,2 | |
2 | =NON(FAUX()) | 3 | ||
3 | 1 | -5,4 | ||
4 | 2 | |||
5 | 3 | "Conditions": A1:A5
|
⇐ plage nommée
|
Formule | Description | Renvoie |
---|---|---|
=ET(FAUX(); VRAI()) | L'un des arguments n'est pas vrai. | FAUX |
=ET(VRAI(); C1>10; FAUX()) | L'un des arguments n'est pas vrai. | FAUX |
=ET(D1:D3) | Toutes les valeurs numériques fournies ne sont pas égales à 0 (zéro). | VRAI |
=ET({2; 4; 6; 8}) | Toutes les valeurs numériques fournies ne sont pas égales à 0 (zéro). | VRAI |
=ET(12<13; 14>12; 7<6) | Le troisième argument est faux. | FAUX |
=ET(Conditions) | Toutes les cellules de la plage nommée sont soit VRAI, soit différentes de 0 (zéro). | VRAI |
Fonctions LibreOffice associées :
Standard ODF :
Fonctions Excel relatives (ou similaires) :
AND