From The Document Foundation Wiki
Function name:
CELL
Category:
Information
Summary:
セルのアドレス、書式設定、または内容についての情報を返します。
Syntax:
CELL(情報の種類[; 対象セル])
Returns:
要求された情報の性質に応じた型の値を返します。
Arguments:
情報の種類は、返される情報のタイプを決定するテキスト文字列、またはテキスト文字列を含むセルへの参照です。情報の種類は大文字と小文字の区別がされません。そして、次の許可されたオプションのいずれかに対応している必要があります "ADDRESS"、"COL"、"COLOR"、"CONTENTS"、"COORD"、"FILENAME"、"FORMAT"、"PARENTHESES"、"PREFIX"、"PROTECT"、"ROW"、"SHEET"、"TYPE"、または "WIDTH"。これらの各オプションの詳細は、次の表を参照してください。
対象セルは情報を返すセルへの参照を指定します。対象セルを省略すると、数式が入力されているセルの情報が返されます。対象セルには、次のいずれかを指定できます。
- 単一のセルへの参照。
- セル範囲への参照 ( D6:E12 など)。
- 名前付き範囲の名前。
- データベース範囲の名前。
対象セルに複数のセルが指定されている場合、CELL は、その範囲の左上のセルの情報を返します。
 |
Note:
次の 2 つの表の内容には、数値や日付の書式など、ロケールに依存する項目が含まれています。このページのすべての例は英語(米国)ロケールでテストされていて、他のロケール設定では動作が異なる場合があります。
|
有効な情報の種類の説明
情報の種類
|
意味
|
ADDRESS
|
セルの絶対アドレスを返します。以下に例を示します。
- 数式がセル A1 にある場合、
=CELL("address") は $A$1 を返します。
=CELL("address"; D7) は $D$7 を返します.
=CELL("address"; Sheet2.E7) は $Sheet2.$E$7 を返します。
=CELL("address"; 'file:///C:/spreadsheets/test.ods'#$Sheet1.D10) は 'file:///C:/spreadsheets/test.ods'#$Sheet1.D10 を返します。
上記の例では、 ▸ ▸ ▸ ダイアログ (macOSでは ▸ ▸ ▸ ) の 数式の構文 メニューがデフォルト設定の Calc A1 であると仮定しています。
|
COL
|
セルの 列番号 を返します (列 A は 1、列 B は 2 など)。以下に例を示します。
- 数式がセル A1 にある場合、
=CELL("col") は 1 を返します。
=CELL("col"; D7) は 4 を返します。
=CELL("col"; Sheet2.E7) は 5 を返します。
|
COLOR
|
セルの負の値が色で書式設定されているかどうかを示す値を返します(1=色で書式設定されている、0=色で書式設定されていない)。以下に例を示します。
- 数式
=CELL("color") は、 ▸ ダイアログの 数値 タブで 負の数を赤にする オプションが選択され書式設定されたセルで 1 を返します。
- 数式
=CELL("color"; D7) は、 ▸ ダイアログの 数値 タブで 負の数を赤にする オプションが選択解除され書式設定されたセル D7 では 0 を返します。
|
CONTENTS
|
書式設定のないセルの内容を返します。以下に例を示します。
- セル E2 には数値 -1234.567 が含まれています。このセルは、小数点以下の桁数が表示されず、負数が赤で表示されるように書式設定されています(フォーマット コード 0;[RED]-0)。数式
=CELL("contents"; E2) は、セル E2 の書式設定が適用されていない -1234.567 を返します。
- セル E3 には、太字、斜体および下線で書式設定されたテキスト「Hello world!」が含まれています。数式
=CELL("contents"; E3) は、セル E3 に書式設定が適用されていない「Hello world!」を返します。
- セル E4 には日付 2021-12-05 が含まれています。数式
=CELL("contents"; E4) は、日時のシリアル値である 44535 を返します。2021-12-05 (日付から数値への内部変換で、開始日がデフォルトの 1899-12-30 に設定されていると仮定します)。
- セル E5 にはブール値 TRUE が含まれています。数式
=CELL("contents"; E5) は 1 を返します。
- 数式
=CELL("contents") がセルに配置されている場合、CELL は循環参照エラー (エラー:522) を返します。
|
COORD
|
シートの位置を文字で示すレガシー表記を使用して、完全なセルアドレスを返します(A はシートタブ領域の左側にあるスプレッドシートを示し、B は右側の次のシートを示します)。以下に例を示します。
- 8 番目のシートのセル A1 にある数式を使用すると、
=CELL("coord") は $H:$A$1 を返します。
- 6 番目のシートにある式を使用すると、
=CELL("coord"; D7) は $F:$D$7 を返します。
情報の種類 引数の "COORD" オプションは、ODF 1.2 の要件ではありません。
|
FILENAME
|
セルが配置されているシート名とファイル名を返します。以下に例を示します。
- ファイル C:/spreadsheets/test.ods の Sheet1 のセル D7 で数式を使用すると、
=CELL("filename") は 'file:///C:/spreadsheets/test.ods'#$Sheet1 を返します。
- 同じファイルで、
=CELL("filename"; $Sheet3.F5) は、'file:///C:/spreadsheets/test.ods'#$Sheet3 を返します。
- 新しい(保存されていない)スプレッドシートの Sheet1 のセル D7 の数式を使用すると、
=CELL("filename") は "#$Sheet1 を返します。
|
FORMAT
|
セルの表示形式を示す文字列を返します。戻り値については、次の表を参照してください。
|
PARENTHESES
|
セルの書式コードに左かっこ "(" が含まれる場合は 1 を返し、含まれない場合は 0 を返します。以下に例を示します:
- 書式コード #,##0_);(#,##0) がセル D3 に適用されている場合、
=CELL("parentheses"; D3) は 1 を返します。
|
PREFIX
|
セル内のテキストの配置を示す 1文字 を返します。コードは次のとおりです。
- ' (アポストロフィ) = 左揃えまたは両端揃え
- " (引用符) = 右揃え
- ^ (キャレット) = 中央揃え
- \ (バックスラッシュ) = 繰り返し
例えば
- セル D3 が右揃えの場合、数式
=CELL("prefix"; D3) は引用符(")を返します。
セルに文字列が含まれていない場合は、Null文字 (Unicode U+0000) を返します。
|
PROTECT
|
セルのセル保護の状態を返します。1 はセルが保護されていることを示し、0 はセルが保護されていないことを示します。以下に例を示します。
- セル B1 が保護されている場合、
=CELL("protect"; B1) は 1 を返します。
セルの保護は、現在のシートが保護された後にのみ有効になることに注意してください。セルの保護は、シートが保護されていない間に有効になる場合があります。
|
ROW
|
セルの行番号を戻します。以下に例を示します。
数式がセルA1にある場合、=CELL("row") は 1 を返します。
=CELL("row"; D7) は 7 を返します。
=CELL("row"; Sheet2.E12) は 12 を返します。
|
SHEET
|
参照されるシートの番号を返します。1 はシートタブ領域の左側にあるシートを示し、2 は右側にある次のシートを示します。以下に例を示します。
- 領収書シート(シートタブ領域の左から2番目)のセル A1 にある式では、
=CELL("sheet") は 2 を返します。
=CELL("sheet"; Accounts.G7) は、シート Accounts がシートタブ領域の左から 3 番目にある場合に3を返します。
|
TYPE
|
セル内容の種類を返します。空のセルの場合は b (空白)、セルにテキストが含まれている場合は l (ラベル)、それ以外の場合は v (値)の 3 つの単一文字列のいずれかです。以下に例を示します。
- セル A1 にテキスト "Hello world!" が含まれている場合、数式
=CELL("type"; A1) は "l" を返します。
- セル A2 に数値 2 が含まれている場合、数式
=CELL("type"; A2) は "v" を返します。
- セル A3 が空の場合、数式
=CELL("type"; A3) は "b" を返します。
数式 =CELL("type") は常に "v" を返します。
|
WIDTH
|
セルがある列の幅を返します。単位は、既定のフォントに基づいて列に収まるゼロ (0) 文字の数です。以下に例を示します。
- 仮に、数式
=CELL("width"; C2) が現在値 11 を返すかもしれません。
- 列Cの幅を変更すると、数式の結果に影響します。列の幅を増やすと、返される値は増加します。列の幅を減らすと、返される値は減少します。列の幅を変更した後、 ▸ ▸ を使用する必要がある場合があります。
|
情報の種類が "FORMAT" の時の戻り値の説明
戻り値
|
意味
|
数値
|
, (コンマ)
|
千単位の区切り記号が付いた数値を表示するようにセルが書式設定されていることを示します。セルの書式で指定された小数点以下の桁数は、カンマの後に追加されます。以下に例を示します。
- セル A3 (書式コード #,###.0000) に数値 123,456.7890 が表示されている場合、数式
=CELL("format"; A3) は、4 を返します。
|
F
|
千単位の区切り記号を使用せずに数値を表示するようにセルが書式設定されていることを示します。セルの書式で指定された小数点以下の桁数は、文字 F の後に追加されます。以下に例を示します。
- セル A4 (書式コード0.00)に数値 123456.79 が表示されている場合、数式
=CELL("format"; A4) は F2 を返します。
- セル A5(書式コードStandard)に数値 123456.789 が表示されている場合、数式
=CELL("format"; A5) はF0を返します。Standard 書式が選択されている場合、セルの書式設定ダイアログの 数値 タブにある 小数点以下の桁数 フィールドは空白になります。
|
C
|
数値が通貨書式で表示されるようにセルが書式設定されていることを示します。セル書式で指定された小数点以下の桁数は、文字 C の後に追加されます。以下に例を示します。
- セル A6(書式コード[$$-409]#,##0.00;-[$$-409]#,##0.00)に $2,345.68 という値が表示されている場合、数式
=CELL("format"; A6) は C2 を返します。
|
S
|
数値を指数表記で表示するようにセルの書式が設定されていることを示します。セルの書式で指定された小数点以下の桁数は、文字 S の後に追加されます。以下に例を示します。
- セル A7(書式コード 0.00E+00)に値 1.23E+45 が表示されている場合、数式
=CELL("format"; A7) は S2 を返します。
|
P
|
セルがパーセンテージで表示されるように書式設定されていることを示します。セルの書式設定で指定された小数点以下の桁数は、文字 P の後に追加されます。以下に例を示します:
- セル A8(書式コード 0.000%)に 56.789% の値が表示されている場合、数式
=CELL("format"; A8) は P3 を返します。
|
日付
|
D1
|
日、月および年の値で構成される日付の書式設定。以下に例を示します。
- セル A12(書式コード M/D/YY)に日付 12/8/21 が表示されている場合、数式
=CELL("format"; A12) は D1 を返します。
|
D2
|
日と月(省略形のアルファベット名)の値で構成される日付の書式。以下に例を示します。
- セル A13(書式コード MMM DD)に日付 Dec 08 が表示されている場合、数式
=CELL("format"; A13) は D2 を返します。
|
D3
|
月と年の値で構成される日付の書式。以下に例を示します。
- セル A14(書式コード MM/YY)に日付 12/21 が表示されている場合、数式
=CELL("format"; A14) は D3 を返します。
|
D4
|
秒、分、時、日、月、年の値で構成される日付と時刻の書式(AM/PMの表示なし)。以下に例を示します。
- セル A15(書式コード MM/DD/YYYY HH:MM:SS)に日付/時刻 12/08/2021 20:25:46 が表示されている場合、数式
=CELL("format"; A15) は D4 を返します。
|
D5
|
日と月(数値)で構成される日付の書式。以下に例を示します。
- セル A16(書式コード MM-DD)に日付 12-08 が表示されている場合、数式
=CELL("format"; A16) は D5 を返します。
|
D6
|
AM/PM の表示付きの 秒、分および時の値を含む時間書式。以下に例を示します。
- セル A17(書式コードHH:MM:SS AM/PM)に時刻 08:33:35 PM が表示されている場合、数式
=CELL("format"; A17) は D6 を返します。
|
D7
|
AM/PMの表示付きの 分および時の値を含む時間書式。以下に例を示します。
- セル A18(書式コード HH:MM AM/PM)に時刻 08:33 PM が表示されている場合、数式
=CELL("format"; A18) は D7 を返します。
|
D8
|
秒、分および時の値を含み、AM/PMの表示を含まない時間書式。以下に例を示します。
- セル A19(書式コード HH:MM:SS)に時刻 20:33:35 が表示されている場合、数式
=CELL("format", A19) は D8 を返します。
|
D9
|
分および時の値を含み、AM/PMの表示を含まない時間書式。以下に例を示します。
- セル A20(書式コード HH:MM)に時刻 20:33 が表示されている場合、数式
=CELL("format"; A20) は D9 を返します。
|
G
|
その他すべての日付と時刻の書式。以下に例を示します。
- セル A21(書式コード YYYY-MM-DD HH:MM:SS)に日付/時刻 2021-12-08 20:33:35 が表示されている場合、数式
=CELL("format"; A21) は G を返します。
|
注記
セルが負の数を色付きで表示するように書式設定されている場合は、返される文字列の最後に-(マイナス)が追加されます。以下に例を示します。
- セル A9(書式コード [$$-409]#,##0.00;[RED]-[$$-409]#,##0.00)に値 $12.34 が表示されている場合、数式
=CELL("format"; A9) は C2- を返します。
セルの書式コードに左括弧が含まれている場合は、返される文字列の末尾に()(括弧)が追加されます。以下に例を示します。
- セル A10(書式コード 0_);(0))に値 (789) が表示されている場合、数式
=CELL("format"; A10) は F0() を返します。
- セル A11(書式コード #,###.000_);[RED](#,###.000))に値 789.012 が表示されている場合、数式
=CELL("format"; A11) は 3-() を返します。この複雑な書式コードでは、括弧で囲まれた負の値が赤で表示されます。
|
- 情報の種類がこれらのリストにない場合、 CELL は無効な引数エラー (エラー:502) を返します。
- 対象セルが有効な参照に対応していない場合、 CELL は #REF! エラーを返します。
- 情報の種類が“CONTENTS”に設定され、対象セルが省略されている場合、CELL は循環参照エラー (エラー:522) を返します。
Additional details:
なし。
Examples:
上に記された #Arguments: セクションにある表の例を参照してください。
Related LibreOffice functions:
なし。
ODF standard:
Section 6.13.3, part 2
Related (or similar) Excel functions:
CELL