Documentatie/Calc-functies/CEL

From The Document Foundation Wiki
Jump to navigation Jump to search
This page is a translated version of the page Documentation/Calc Functions/CELL and the translation is 100% complete.
Other languages:
English • ‎Nederlands



Functienaam:

CEL

Categorie:

Informatie

Samenvatting:

Biedt gevraagde informatie over locatie, opmaakeigenschappen of inhoud van een cel.

Syntaxis:

CEL(Infotype[; Verwijzing])

Retourneert:

Retourneert een waarde waarvan het type afhangt van de aard van de gevraagde informatie.

Argumenten:

Infotype is een tekstreeks of een verwijzing naar een cel die een tekstreeks bevat, die het type informatie bepaalt dat moet worden geretourneerd. Infotype is niet hoofdlettergevoelig en moet overeenkomen met één van de volgende toegestane opties: "ADDRESS", "COL", "COLOR", "CONTENTS", "COORD", "FILENAME", "FORMAT", "PARENTHESES", "PREFIX", "PROTECT", "ROW", "SHEET", "TYPE", of "WIDTH". Meer details over elk van deze opties vindt u in de onderstaande tabel.

Verwijzing is een verwijzing naar de cel waarvoor informatie moet worden geretourneerd. Als Verwijzing wordt weggelaten, wordt informatie geretourneerd voor de cel waarin de formule zich bevindt. Verwijzing kan één van de volgende mogelijkheden zijn:

  • Een verwijzing naar een enkele cel.
  • Een verwijzing naar een celbereik (bijvoorbeeld D6:E12).
  • De naam van een benoemd bereik.
  • De naam van een databasebereik.

Waar Verwijzing meerdere cellen specificeert, retourneert CEL informatie voor de linkerbovenhoek van die cellen.

Note pin.svg

Note:
De inhoud van de volgende twee tabellen bevat aspecten die afhankelijk zijn van de landinstelling, zoals getal- en datumnotaties. Alle voorbeelden op deze pagina zijn getest in de Engelse (VS) landinstelling, maar het gedrag kan anders zijn in andere landinstellingen.

Beschrijving van geldige reeksen voor het argument Infotype
Infotype tekenreeks Betekenis
ADDRESS Retourneert het absolute adres van de cel. Bijvoorbeeld:
  • Met de formule in cel A1 retourneert =CEL("address") $A$1.
  • =CEL("address"; D7) geeft $D$7 terug.
  • =CEL("address"; Blad2.E7) geeft $Blad2.$E$7 terug.
  • =CEL("address"; 'file:///C:/werkbladen/test.ods'#$Sheet1.D10) geeft als resultaat 'file:///C:/werkbladen/test. ods'#$Blad1.D10.

De bovenstaande voorbeelden gaan uit van de standaardinstelling Calc A1 in Formulesyntaxis in het gedeelte Formule-opties van het dialoogvenster Extra ▸ Opties ▸ LibreOffice Calc ▸ Formule (LibreOffice ▸ Voorkeuren  ▸ LibreOffice Calc ▸ Formule op macOS).

COL Retourneert het kolomnummer van de cel (kolom A is 1, kolom B is 2, enzovoort). Bijvoorbeeld:
  • Met de formule in cel A1 geeft =CEL("col") als resultaat 1.
  • =CEL("col"; D7) geeft als resultaat 4.
  • =CEL("col"; Blad2.E7) geeft 5 terug.
COLOR Retourneert een waarde die aangeeft of negatieve waarden in kleur zijn opgemaakt in de cel (1=opgemaakt in kleur, 0=niet opgemaakt in kleur). Bijvoorbeeld:
  • De formule =CEL("color") geeft 1 terug in een cel die zo is opgemaakt dat de optie Negatieve getallen rood is geselecteerd op het tabblad Getallen van het dialoogvenster dat wordt geopend door Opmaak ▸ Cellen te selecteren.
  • De formule =CEL("color"; D7) retourneert 0 als cel D7 zo is opgemaakt dat de optie Negatieve getallen rood is gedeselecteerd op het tabblad Getallen van het dialoogvenster dat wordt geopend door Opmaak ▸ Cellen te selecteren.
CONTENTS Retourneert de inhoud van de cel, zonder enige opmaak. Bijvoorbeeld:
  • Cel E2 bevat het getal -1234.567, waarbij de cel is opgemaakt om geen decimalen en negatieve getallen als rood weer te geven (Opmaakcode 0;[RED]-0). De formule =CEL("contents"; E2) retourneert -1234.567, zonder de opmaak toegepast op cel E2.
  • Cel E3 bevat de tekst "Hallo wereld!", opgemaakt met vet, cursief en onderstreept. De formule =CEL("contents"; E3) geeft als resultaat "Hallo wereld!", zonder de opmaak toegepast op cel E3.
  • Cel E4 bevat de datum 05-12-2021. De formule =CEL("contents"; E4) retourneert het getal 44535, het datum-tijd serienummer van 05-12-2021 (ervan uitgaande dat de startdatum voor de interne conversie van dagen naar getallen is ingesteld op de standaard 30-12-1899).
  • Cel E5 bevat de Booleaanse waarde WAAR. De formule =CEL("contents"; E5) geeft als resultaat 1.
  • Als de formule =CEL("contents") in een cel wordt geplaatst, rapporteert CELL een kringverwijzingsfout (Fout:522).
COORD Retourneert het volledige celadres met behulp van een oude notatie, waarin de bladpositie wordt aangegeven door een letter (A geeft het werkblad aan de linkerkant van het bladtabgebied aan, B het volgende blad aan de rechterkant, enzovoort). Bijvoorbeeld:
  • Met de formule in cel A1 van het achtste blad, retourneert =CEL("coord") $H:$A$1.
  • Met de formule op het zesde blad, retourneert =CEL("coord"; D7) $F:$D$7.

De "COORD" optie voor het Infotype argument is geen vereiste van ODF 1.2.

FILENAME Retourneert de bestandsnaam en de naam van het blad waarin de cel zich bevindt. Bijvoorbeeld:
  • Met de formule in cel D7 van Blad1 in het bestand C:/werkbladen/test.ods, geeft =CEL("filename") als resultaat 'file:///C:/werkbladen/test.ods '#$Blad1.
  • In hetzelfde bestand zou =CELL("filename"; $Blad3.F5) 'file:///C:/werkbladen/test.ods'#$Blad3 retourneren.
  • Met de formule in cel D7 van Blad1 in een nieuwe (niet-opgeslagen) spreadsheet, retourneert =CEL("bestandsnaam") "#$Blad1.
FORMAT Retourneert een tekenreeks die de getalnotatie van de cel aangeeft. De mogelijke retourwaarden zijn gedefinieerd in een aparte tabel hieronder.
PARENTHESES Retourneert 1 als de opmaakcode van de cel haakjes bevat en geeft anders 0 terug. Bijvoorbeeld:
  • Als de notatiecode #,##0_);(#,##0) wordt toegepast op cel D3, dan geeft =CEL("parentheses"; D3) als resultaat 1.
PREFIX Retourneert een enkele tekenreeks die de uitlijning van tekst in de cel aangeeft, als volgt gecodeerd:
  • ' (apostrof) = links uitgelijnd
  • " (aanhalingsteken) = rechts uitgelijnd
  • ^ (caret) = gecentreerd
  • \ (backslash) = gevulde uitlijning

Bijvoorbeeld:

  • Als cel D3 rechts is uitgelijnd, retourneert de formule =CEL("prefix"; D3) een aanhalingsteken (").

Retourneert het nul-teken (Unicode U+0000) als de cel geen tekenreeks bevat.

PROTECT Retourneert de status van celbeveiliging voor de cel. 1 geeft aan dat de cel is beveiligd, terwijl 0 aangeeft dat de cel niet is beveiligd. Bijvoorbeeld:
  • Als cel B1 is beveiligd, geeft =CEL("protect"; B1) als resultaat 1.

Merk op dat celbeveiliging alleen effectief is nadat het huidige blad is beveiligd. Celbeveiliging kan worden ingeschakeld terwijl een blad niet is beveiligd.

ROW Retourneert het rijnummer van de cel. Bijvoorbeeld:
  • Met de formule in cel A1 geeft =CEL("row") als resultaat 1.
  • =CEL("row"; D7) geeft 7 terug.
  • =CEL("row"; Blad2.E12) geeft 12 terug.
SHEET Retourneert het nummer van het blad waarnaar wordt verwezen, 1 geeft het blad aan de linkerkant van het bladtabgebied aan, 2 het volgende blad aan de rechterkant, enzovoort. Bijvoorbeeld,
  • Met de formule in cel A1 van het blad Ontvangsten (2e van links in het bladtabgebied), retourneert =CEL("sheet") 2.
  • =CEL("sheet"; Rekeningen.G7) geeft 3 terug in het geval dat het blad Rekeningen de 3e van links is in het bladtabgebied.
TYPE Retourneert het type gegevens in de cel. Een van de drie mogelijke tekenreeksen van één teken – b (voor blanco) voor een lege cel; l (voor label) als de cel tekst bevat; v (voor waarde) anders. Bijvoorbeeld:
  • Als cel A1 de tekst "Hallo wereld!" bevat, geeft de formule =CEL("type"; A1) als resultaat l.
  • Als cel A2 het getal 2 bevat, retourneert de formule =CEL("type"; A2) v.
  • Als cel A3 leeg is, retourneert de formule =CEL("type"; A3) b.

De formule =CEL("type") geeft altijd v terug.

WIDTH Retourneert de breedte van de kolom waarin de cel ligt. De eenheid is het aantal nul (0) tekens dat in de kolom past op basis van het standaardlettertype. Bijvoorbeeld:
  • Stel dat de formule =CEL("width"; C2) momenteel de waarde 11 retourneert.
  • Het wijzigen van de breedte van kolom C heeft invloed op het resultaat van de formule. Als u de breedte van de kolom vergroot, neemt de geretourneerde waarde toe. Als u de breedte van de kolom verkleint, neemt de geretourneerde waarde af. U moet mogelijk Gegevens ▸ Berekenen ▸ Werkblad opnieuw berekenen gebruiken nadat u de kolombreedte hebt gewijzigd.


Beschrijving van retourwaarden voor het FORMAT Infotype-argument
Retourwaarde Betekenis
Getallen
, (komma) Geeft aan dat de cel is opgemaakt om getallen weer te geven met scheidingstekens voor duizendtallen. Het aantal decimalen dat door de celopmaak is opgegeven, wordt achter de komma toegevoegd. Bijvoorbeeld:
  • Met het getal 123.456.7890 weergegeven in cel A3 (formaatcode #.###,0000), retourneert de formule =CEL("format"; A3) ,4.
F Geeft aan dat de cel is opgemaakt om getallen weer te geven zonder scheidingstekens voor duizendtallen. Het aantal decimalen dat is opgegeven door de celopmaak wordt toegevoegd na de letter F. Bijvoorbeeld:
  • Met het getal 123456,79 weergegeven in cel A4 (formaatcode 0.00), retourneert de formule =CEL("format"; A4) F2.
  • Met het getal 123456,789 weergegeven in cel A5 (OpmaakcodeStandaard), retourneert de formule =CEL("format"; A5) F0. Merk op dat het veld Aantal decimalen op het tabblad Getallen van het dialoogvenster Cellen opmaken leeg is wanneer de Opmaak Standaard is geselecteerd.
C Geeft aan dat de cel is opgemaakt om getallen in valuta-opmaak weer te geven. Het aantal decimalen dat is opgegeven door de celopmaak wordt toegevoegd na de letter C. Bijvoorbeeld:
  • Met de waarde € 2.345.68 weergegeven in cel A6 (formaatcode [$€-413]#.##0,00;-[$€-413]#.##0,00), de formule =CEL( "format"; A6) geeft C2 terug.
S Geeft aan dat de cel is opgemaakt om getallen in wetenschappelijke (exponentiële) weergave weer te geven. Het aantal decimalen dat is opgegeven door de celopmaak wordt toegevoegd na de letter S. Bijvoorbeeld:
  • Met de waarde 1.23E+45 weergegeven in cel A7 (formaatcode 0,00E+00), retourneert de formule =CEL("format"; A7) S2.
P Geeft aan dat de cel is opgemaakt om percentages weer te geven. Het aantal decimalen dat is opgegeven door de celopmaak wordt toegevoegd na de letter P. Bijvoorbeeld:
  • Met de waarde 56,789% weergegeven in cel A8 (formaatcode 0,000%), retourneert de formule =CEL("format"; A8) P3.
Datums
D1 Datumnotaties met dag-, maand- en jaarwaarden. Bijvoorbeeld:
  • Met de datum 12-08-21 weergegeven in cel A12 (formaatcode MM-DD-JJ), retourneert de formule =CEL("format"; A12) D1.
D2 Datumnotaties bestaande uit dag- en maandwaarden (afgekorte alfabetische naam). Bijvoorbeeld:
  • Met de datum Dec 08 weergegeven in cel A13 (Opmaakcode MMM DD), retourneert de formule =CEL("format"; A13) D2. (Werkt alleen in de Engelse versie. In NL zijn geen maanden beginnend met een hoofdletter)
D3 Datumopmaak bestaande uit maand- en jaarwaarden. Bijvoorbeeld:
  • Met de datum 12-21 weergegeven in cel A14 (opmaakcode MM-JJ), retourneert de formule =CEL("format"; A14) D3.
D4 Datum- en tijdopmaak bestaande uit seconde-, minuut-, uur-, dag-, maand- en jaarwaarden (zonder AM/PM-indicator). Bijvoorbeeld:
  • Met de datum/tijd 12-08-2021 20:25:46 weergegeven in cel A15 (formaatcode MM-DD-JJJJ UU:MM:SS), de formule =CEL("format" ; A15) geeft D4 terug.
D5 Datumopmaak bestaande uit dag- en maand (numerieke) waarden. Bijvoorbeeld:
  • Met de datum 12-08 weergegeven in cel A16 (opmaakcode MM-DD), retourneert de formule =CEL("format"; A16) D5.
D6 Tijdopmaak inclusief seconde-, minuut- en uurwaarden, met AM/PM-indicator. Bijvoorbeeld:
  • Met de tijd 08:33:35 PM weergegeven in cel A17 (opmaakcode UU:MM:SS AM/PM), retourneert de formule =CEL("format"; A17) D6.
D7 Tijdopmaak inclusief minuut- en uurwaarden, met AM/PM-indicator. Bijvoorbeeld:
  • Met de tijd 08:33 PM weergegeven in cel A18 (opmaakcodeUU:MM AM/PM), retourneert de formule =CELL("format"; A18) D7.
D8 Tijdopmaak inclusief seconde-, minuut- en uurwaarden, zonder AM/PM-indicator. Bijvoorbeeld:
  • Met de tijd 20:33:35 weergegeven in cel A19 (opmaakcode UU:MM:SS), retourneert de formule =CEL("format"; A19) D8.
D9 Tijdopmaak inclusief minuten- en uurwaarden, zonder AM/PM-indicator. Bijvoorbeeld:
  • Met de tijd 20:33 weergegeven in cel A20 (formaatcode UU:MM), retourneert de formule =CEL("format"; A20) D9.
G Alle andere datum- en tijdopmaak. Bijvoorbeeld:
  • Met de datum/tijd 08-12-2021 20:33:35 weergegeven in cel A21 (opmaakcode DD-MM-JJJJ HH:MM:SS), de formule =CEL("format"; A21) geeft G terug.
Aanvullende notities

Een - (min) wordt toegevoegd aan het einde van de geretourneerde tekenreeks wanneer de cel is opgemaakt om negatieve getallen in kleur weer te geven. Bijvoorbeeld:

  • Met de waarde € 12.34 weergegeven in cel A9 (formaat code [$€-413] #.##0,00;[RED][$€-413] #.##0,00-, de formule =CEL("format"; A9) geeft C2- terug.

() (haakjes) worden toegevoegd aan het einde van de geretourneerde tekenreeks wanneer de opmaakcode van de cel een haakje links bevat. Bijvoorbeeld:

  • Met de waarde (789) weergegeven in cel A10 (formaatcode 0_);(0)), retourneert de formule =CEL("format"; A10) F0().
  • Met de waarde 789,012 weergegeven in cel A11 (formaatcode #.###,000_);[RED](#.###,000)), de formule =CEL("format"; A11) geeft als resultaat ,3-(). Deze complexe opmaakcode toont negatieve waarden in rood, omgeven door haakjes.
  • Als Infotype niet overeenkomt met één van de verwachte tekenreeksen, rapporteert CEL ongeldig argument (Fout:502).
  • Als Verwijzing niet overeenkomt met een geldige verwijzing, meldt de CEL als fout #VERW!.
  • Als Infotype is ingesteld op 'CONTENTS' en Verwijzing is weggelaten, retourneert CEL een kringverwijzingsfout (Fout:522).

Aanvullende details:

Geen

Voorbeelden:

Zie voorbeelden in de tabellen in het gedeelte #Argumenten: hierboven.

Gerelateerde LibreOffice-functies:

Geen

ODF standaard:

Section 6.13.3, part 2

Gelijkwaardige Excel-functies:

CEL