Documentazione/Funzioni di Calc/CELLA

TDF LibreOffice Document Liberation Project Blog comunitari Weblate Nextcloud Redmine Ask LibreOffice Donazione

• Pagina principale
• Sviluppo
• Design
• Controllo qualità
• Eventi
• Documentazione
• Sito web
• Traduzione
• Accessibilità
• Commerciale
• Inclusione
• Aiuto

• Documentazione
• Pubblicazione
• Altre risorse
• Domande frequenti
• How to
• Macro
• Redazione della documentazione

Funzioni di Calc | Elenco delle funzioni | Abbreviazioni

Nome funzione:

CELLA

Categoria:

Informazione

Riepilogo:

Fornisce le informazioni richieste sulla posizione, sulle proprietà di formattazione o sul contenuto di una cella.

Sintassi:

CELLA(Tipo di informazioni[; Riferimento])

Restituisce:

Restituisce un valore il cui tipo dipende dalla natura delle informazioni richieste.

Argomenti:

Tipo di informazioni è una stringa di testo, o un riferimento a una cella contenente una stringa di testo, che determina il tipo di informazione da restituire. Tipo di informazioni non fa distinzione tra maiuscole e minuscole e deve corrispondere a una delle seguenti opzioni consentite – "INDIRIZZO", "COL", "COLORE", "CONTENTS", "COORD", "FILENAME", "FORMAT", "PARENTHESES", "PREFIX", "PROTECT", "RIF.RIGA", "FOGLIO", "TIPO" o "WIDTH". Maggiori dettagli su ciascuna di queste opzioni sono forniti nella tabella seguente.

Riferimento è un riferimento alla cella per la quale devono essere restituite le informazioni. Se viene omesso Riferimento, vengono restituite le informazioni per la cella in cui si trova la formula. Riferimento può essere uno dei seguenti:

• Un riferimento ad una singola cella.
• Un riferimento a un intervallo di celle (per esempio, D6:E12).
• Il nome di un intervallo nominato.
• Il nome di un intervallo in una base di dati.

Dove Riferimento specifica più celle, CELLA restituisce le informazioni per la parte superiore sinistra di tali celle.

Nota: Il contenuto delle due tabelle seguenti include aspetti che dipendono dalle impostazioni locali, come i formati dei numeri e delle date. Tutti gli esempi in questa pagina sono stati testati nella lingua locale inglese (USA), ma il comportamento potrebbe essere diverso in altre impostazioni locali.

Descrizione delle stringhe di argomento Tipo di informazione valide

stringa di Tipo di informazione	Significato
INDIRIZZO	Restituisce l'indirizzo assoluto della cella. Per esempio: Con la formula che si trova nella cella A1, =CELLA("address") restituisce $A$1. =CELLA("address"; D7) restituisce $D$7. =CELLA("address"; Foglio2.E7) restituisce $Foglio2.$E$7. =CELLA("address"; 'file:///C:/spreadsheets/test.ods'#$Foglio1.D10) restituisce 'file:///C:/spreadsheets/test.ods'#$Foglio1.D10. Gli esempi precedenti presuppongono l'impostazione predefinita di Calc A1 per il menu Sintassi della formula nella finestra di dialogo Strumenti ▸ Opzioni ▸ LibreOffice Calc ▸ Formula (LibreOffice ▸ Preferenze ▸ LibreOffice Calc ▸ Formula su macOS).
COL	Restituisce il numero di colonna della cella (colonna A è 1, colonna B è 2 e così via). Per esempio: Con la formula che si trova nella cella A1, =CELLA("col") restituisce 1. =CELLA("col"; D7) restituisce 4. =CELLA("col"; Foglio2.E7) restituisce 5.
COLORE	Restituisce un valore che indica se i valori negativi sono formattati a colori nella cella (1=formattato a colori, 0=non formattato a colori). Per esempio: La formula =CELLA("color") restituisce 1 in una cella che è stata formattata in modo tale che l'opzione Numeri negativi rossi è stato selezionato nella scheda Numeri della finestra di dialogo Formato ▸ Celle. La formula =CELLA("color"; D7) restituisce 0 se la cella D7 è stata formattata in modo tale che Numeri negativi rossi l'opzione è stata deselezionata nella scheda Numeri della finestra di dialogo Formato ▸ Celle.
CONTENTS	Restituisce il contenuto della cella, senza alcuna formattazione. Per esempio: La cella E2 contiene il numero -1234,567, con la cella formattata per non mostrare cifre decimali e numeri negativi in ​​rosso (codice formato 0;[RED]-0). La formula =CELLA("contents"; E2) restituisce -1234,567, senza la formattazione applicata alla cella E2. La cella E3 contiene il testo "Ciao mondo!", formattato con grassetto, corsivo e sottolineato. La formula =CELLA("contents"; E3) restituisce "Ciao mondo!", senza la formattazione applicata alla cella E3. La cella E4 contiene la data 05-12-2021. La formula =CELLA("contents"; E4) restituisce il numero 44535, il numero di serie data-ora di 05-12-2021 (assumendo che la data di inizio per la conversione interna da giorni a numeri è impostata sul valore predefinito 30-12-1899). La cella E5 contiene il valore booleano VERO. La formula =CELLA("contents"; E5) restituisce 1. Se la formula =CELLA("contents") viene inserita in una cella, allora CELLA riporta un errore di riferimento circolare (Err:522).
COORD	Restituisce l'indirizzo completo della cella utilizzando una notazione legacy, in cui la posizione del foglio è indicata da una lettera (A indica il foglio di calcolo a sinistra dell'area della scheda del foglio, B il foglio successivo a destra e così via). Per esempio: Con la formula situata nella cella A1 dell'ottavo foglio, =CELLA("coord") restituisce $H:$A$1. Con la formula situata nel sesto foglio, =CELLA("coord"; D7) restituisce $F:$D$7. L'opzione "COORD" per l'argomento Tipo di informazioni non è un requisito di ODF 1.2.
FILENAME	Restituisce il nome del file e il nome del foglio in cui si trova la cella. Per esempio: Con la formula nella cella D7 del Foglio1 nel file C:/spreadsheets/test.ods, =CELLA("filename") restituisce 'file: ///C:/spreadsheets/test.ods'#$Foglio1. Nello stesso file, =CELLA("filename"; $Foglio3.F5) restituirebbe 'file:///C:/spreadsheets/test .ods'#$Foglio3. Con la formula nella cella D7 del Foglio1 in un nuovo foglio di calcolo (non salvato), =CELLA("filename") restituisce "#$Foglio1.
FORMAT	Restituisce una stringa di caratteri che indica il formato numerico della cella. I possibili valori restituiti sono definiti in una tabella separata di seguito.
PARENTHESES	Restituisce 1 se il codice del formato della cella contiene una parentesi aperta e restituisce 0 altrimenti. Per esempio: Se il codice formato #,##0_);(#,##0) viene applicato alla cella D3, allora =CELLA("parentheses" ; D3) restituisce 1.
PREFIX	Restituisce una stringa di singolo carattere che indica l'allineamento del testo nella cella, codificata come segue: ' (apostrofo) = allineato a sinistra " (virgolette) = allineato a destra ^ (accento circonflesso) = centrato \ (barra rovesciata) = allineamento riempito Per esempio: Se la cella D3 è allineata a destra, la formula =CELLA("prefix"; D3) restituisce una virgoletta ("). Restituisce il carattere null (Unicode U+0000) se la cella non contiene una stringa.
PROTECT	Restituisce lo stato della protezione della cella. 1 indica che la cella è protetta, mentre 0 indica che la cella non è protetta. Per esempio: Se la cella B1 è protetta, =CELLA("protect"; B1) restituisce 1. Tenete presente che la protezione delle celle è efficace solo dopo che il foglio corrente è stato protetto. La protezione delle celle può essere abilitata mentre un foglio non è protetto.
RIF.RIGA	Restituisce il numero di riga della cella. Per esempio: Con la formula che si trova nella cella A1, =CELLA("row") restituisce 1. =CELLA("row"; D7) restituisce 7. =CELLA("row"; Foglio2.E12) restituisce 12.
FOGLIO	Restituisce il numero del foglio di riferimento, 1 indica il foglio a sinistra dell'area della scheda del foglio, 2 il foglio successivo a destra e così via. Per esempio: Con la formula che si trova nella cella A1 del foglio Ricevute (2° da sinistra nell'area della scheda del foglio), =CELLA("sheet") restituisce 2. =CELLA("sheet"; Accounts.G7) restituisce 3 nel caso in cui il foglio Accounts sia il terzo da sinistra nell'area della scheda del foglio.
TIPO	Restituisce il tipo di dati nella cella. Una delle tre possibili stringhe a carattere singolo - b (per spazio vuoto) per una cella vuota; l (per etichetta) se la cella contiene testo; v (per valore) altrimenti. Per esempio: Se la cella A1 contiene il testo "Ciao mondo!", la formula =CELLA("type"; A1) restituisce l. Se la cella A2 contiene il numero 2, la formula =CELLA("type"; A2) restituisce v. Se la cella A3 è vuota, la formula =CELLA("type"; A3) restituisce b. La formula =CELLA("type") restituisce sempre v.
WIDTH	Restituisce la larghezza della colonna in cui si trova la cella. L'unità è il numero di caratteri zero (0) che rientrano nella colonna in base al carattere predefinito. Per esempio: Supponiamo che la formula =CELLA("width"; C2) restituisca attualmente il valore 11. La modifica della larghezza della colonna C influirà sul risultato della formula. Se aumentate la larghezza della colonna, il valore restituito aumenterà. Se riducete la larghezza della colonna, il valore restituito diminuirà. Potrebbe essere necessario utilizzare Dati ▸ Calcola ▸ Ricalcolo incondizionato dopo aver modificato la larghezza della colonna.

Descrizione dei valori restituiti per l'argomento FORMATO nel Tipo di informazioni

Valore di ritorno	Significato
Numeri
, (virgola)	Indica che la cella è formattata per visualizzare i numeri con separatori delle migliaia. Il numero di cifre decimali specificato dal formato cella viene aggiunto dopo la virgola. Per esempio: Con il numero 123.456.7890 visualizzato nella cella A3 (codice formato #,###.0000), la formula =CELLA("format"; A3) restituisce ,4.
F	Indica che la cella è formattata per visualizzare i numeri senza separatori delle migliaia. Il numero di cifre decimali specificato dal formato della cella viene aggiunto dopo la lettera F. Ad esempio: Con il numero 123456,79 visualizzato nella cella A4 (codice formato 0,00), la formula =CELLA("format"; A4) restituisce F2 . Con il numero 123456,789 visualizzato nella cella A5 (codice formato Generale), la formula =CELLA("format"; A5) restituisce F0 . Tenete presente che il campo Posizioni decimali nella scheda Numeri della finestra di dialogo Formato celle è vuoto quando è selezionato il formato Generale.
C	Indica che la cella è formattata per visualizzare i numeri in formato valuta. Il numero di cifre decimali specificato dal formato della cella viene aggiunto dopo la lettera C. Ad esempio: Con il valore $2,345.68 visualizzato nella cella A6 (codice formato [$$-409]#,##0.00;-[$$-409]#,##0.00), la formula =CELLA("format"; A6) restituisce C2.
S	Indica che la cella è formattata per visualizzare i numeri in rappresentazione scientifica (esponenziale). Il numero di cifre decimali specificato dal formato della cella viene aggiunto dopo la lettera S. Ad esempio: Con il valore 1.23E+45 visualizzato nella cella A7 (codice formato 0.00E+00), la formula =CELLA("format"; A7) restituisce S2.
P	Indica che la cella è formattata per visualizzare le percentuali. Il numero di cifre decimali specificato dal formato della cella viene aggiunto dopo la lettera P. Ad esempio: Con il valore 56,789% visualizzato nella cella A8 (codice formato 0,000%), la formula =CELLA("format"; A8) restituisce P3.
Date
D1	Formati di data che comprendono valori di giorno, mese e anno. Per esempio: Con la data 8/12/21 visualizzata nella cella A12 (codice formato G/M/AA), la formula =CELLA("format"; A12)</codice> restituisce D1.
D2	Formati di data comprendenti i valori del giorno e del mese (nome alfabetico abbreviato). Per esempio: Con la data 08 dic visualizzata nella cella A13 (codice formato GG MMM), la formula =CELLA("format"; A13) restituisce D2.
D3	Formati di data comprendenti valori di mese e anno. Per esempio: Con la data 12/21 visualizzata nella cella A14 (codice formato MM/AA), la formula =CELLA("format"; A14) restituisce D3.
D4	Formati di data e ora comprendenti valori di secondi, minuti, ore, giorno, mese e anno (senza indicatore AM/PM). Per esempio: Con la data/ora 12/08/2021 20:25:46 visualizzata nella cella A15 (codice formato MM/GG/AAAA HH:MM:SS), la formula =CELL("format"; A15) restituisce D4.
D5	Formato della data comprendente i valori del giorno e del mese (numerici). Per esempio: Con la data 12-08 visualizzata nella cella A16 (codice formato MM-GG), la formula =CELLA("format"; A16) restituisce D5.
D6	Formati orari inclusi valori di secondi, minuti e ore, con indicatore AM/PM. Per esempio: Con l'ora 08:33:35 PM visualizzata nella cella A17 (codice formato HH:MM:SS AM/PM), la formula =CELLA( "format"; A17) restituisce D6.
D7	Formati orari compresi i valori dei minuti e delle ore, con indicatore AM/PM. Per esempio: Con l'ora 08:33 visualizzata nella cella A18 (codice formato HH:MM AM/PM), la formula =CELLA("format"; A18) restituisce D7.
D8	Formati orari che includono valori di secondi, minuti e ore, senza indicatore AM/PM. Per esempio: Con l'ora 08:33:35 visualizzata nella cella A19 (codice formato HH:MM:SS), la formula =CELLA("format", A19) restituisce D8.
D9	Formati orari che includono valori di minuti e ore, senza indicatore AM/PM. Per esempio: Con l'ora 20:33 visualizzata nella cella A20 (codice formato HH:MM), la formula =CELLA("format"; A20) restituisce D9.
G	Tutti gli altri formati di data e ora. Per esempio: Con la data/ora 2021-12-08 20:33:35 visualizzata nella cella A21 (codice formato AAAA-MM-GG HH:MM:SS), la formula =CELL("format"; A21) restituisce G.
Note aggiuntive Un - (meno) viene aggiunto alla fine della stringa restituita quando la cella viene formattata per visualizzare i numeri negativi a colori. Per esempio: Con il valore $12.34 visualizzato nella cella A9 (codice formato [$$-409]#,##0.00;[RED]-[$$-409]#,##0.00), la formula = CELLA("format"; A9) restituisce C2-. () (parentesi) vengono aggiunte alla fine della stringa restituita quando il codice di formato della cella include una parentesi aperta. Per esempio: Con il valore (789) visualizzato nella cella A10 (codice formato 0_);(0)), la formula =CELLA("format"; A10) restituisce F0(). Con il valore 789.012 visualizzato nella cella A11 (codice formato #,###.000_);[RED](#,###.000)), la formula =CELLA("format"; A11) restituisce ,3-(). Questo codice di formato complesso mostra i valori negativi in ​​rosso, circondati da parentesi.

• Se Tipo di informazioni non corrisponde a una delle stringhe previste, allora CELLA segnala un errore di argomento non valido (Err:502).
• Se Riferimento non corrisponde a un riferimento valido, CELLA riporta un errore #RIF! errore.
• Se Tipo di informazioni è impostato su “CONTENTS” e Riferimento viene omesso, allora CELLA segnala un errore di riferimento circolare (Err:522).

Dettagli aggiuntivi:

Nessuno

Esempi:

Vedi gli esempi all'interno delle tabelle nella sezione #Argumenti: sopra.

Funzioni di LibreOffice correlate:

Nessuno.

Standard ODF:

Section 6.13.3, part 2

Funzioni equivalenti (o simili) di Excel:

CELL