Jump to content

Documentation/Fonctions Calc/CELLULE

From The Document Foundation Wiki
This page is a translated version of the page Documentation/Calc Functions/CELL and the translation is 100% complete.


Nom de la fonction :

CELLULE

Catégorie :

Information

Résumé :

Fournit les informations demandées sur l'emplacement, les propriétés de formatage ou le contenu d'une cellule.

Syntaxe :

CELLULE(Type information[; Référence])

Renvoie :

Renvoie une valeur dont le type dépend de la nature des informations demandées.

Arguments :

Type information est une chaîne de texte, ou une référence à une cellule contenant une chaîne de texte, qui détermine le type d'informations à renvoyer. Type information est insensible à la casse et doit correspondre à l'une des options autorisées suivantes : "ADRESSE", "COL", "COULEUR", "CONTENU", "COORD", "NOMFICHIER", "FORMAT", "PARENTHESES", "PREFIX", "PROTECTION", "LIGNE", "FEUILLE", "TYPE" ou "LARGEUR". Le tableau ci-dessous détaille chacune de ces options.

Référence est une référence à la cellule pour laquelle les informations doivent être renvoyées. Si Référence est omise, les informations renvoyées correspondent à la cellule contenant la formule. Référence peut être l'une des valeurs suivantes :

  • Une référence à une cellule seule.
  • Une référence à une plage de cellules (par exemple: D6:E12).
  • Le nom d'une plage nommée
  • Le nom d'une plage de base de données.

Lorsque Référence spécifie plusieurs cellules, CELLULE renvoie des informations pour le coin supérieur gauche de ces cellules.

Note :
Le contenu des deux tableaux suivants inclut des aspects dépendant des paramètres régionaux, tels que les formats de nombres et de dates. Tous les exemples de cette page ont été testés en anglais (États-Unis), mais le comportement peut varier selon les paramètres régionaux.

Description des chaînes d'arguments de Type information valides
Chaîne Type information Signification
ADRESSE Renvoie l'adresse absolue de la cellule. Par exemple :
  • Avec la formule située dans la cellule A1, =CELLULE("adresse") renvoie $A$1.
  • =CELLULE("adresse"; D7) renvoie $D$7.
  • =CELLULE("adresse"; Feuille.E7) renvoie $Feuille.$E$7.
  • =CELLULE("adresse"; 'file:///C:/spreadsheets/test.ods'#$Sheet1.D10) renvoie 'file:///C:/spreadsheets/test.ods'#$Sheet1.D10.

Les exemples ci-dessus supposent le paramètre par défaut de Calc A1 pour le menu Syntaxe de formule dans la boîte de dialogue Outils ▸ Options ▸ LibreOffice Calc ▸ Formule (LibreOffice ▸ Préférences ▸ LibreOffice Calc ▸ Formule sur macOS).

COL Renvoie le numéro de colonne de la cellule (colonne A est 1, colonne B est 2, etc.). Par exemple :
  • Avec la formule située dans la cellule A1, =CELLULE("col") renvoie 1.
  • =CELLULE("col"; D7) renvoie 4.
  • =CELLULE("col"; Feuille2.E7) renvoie 5.
COULEUR Renvoie une valeur indiquant si les valeurs négatives sont mises en couleur dans la cellule (1 = mise en couleur, 0 = non mise en couleur). Par exemple :
  • La formule =CELLULE("couleur") renvoie 1 dans une cellule qui a été formatée de telle sorte que l'option Nombres négatifs en rouge a été sélectionnée dans l'onglet Nombres de la boîte de dialogue Format ▸ Cellules.
  • La formule =CELLULE("couleur"; D7) renvoie 0 si la cellule D7 a été formatée de telle sorte que l'option Nombres négatifs en rouge a été désélectionnée dans l'onglet Nombres de la boîte de dialogue Format ▸ Cellules.
CONTENTS Renvoie le contenu de la cellule, sans mise en forme. Par exemple :
  • La cellule E2 contient le nombre -1234,567, formatée sans décimales et avec les nombres négatifs en rouge (code de format « 0 ; [ROUGE]-0 »). La formule =CELLULE("contenu"; E2) renvoie -1234,567, sans la mise en forme appliquée à la cellule E2.
  • La cellule E3 contient le texte « Bonjour le monde ! », mis en gras, en italique et souligné. La formule =CELLULE("contenu"; E3) renvoie "Bonjour le monde !", sans la mise en forme appliquée à la cellule E3.
  • La cellule E4 contient la date du 05/12/2021. La formule =CELLULE("contenu"; E4) renvoie le nombre 44535, le numéro de série date-heure du 05/12/2021 (en supposant que la date de début de la conversion interne des jours en nombres est définie par défaut sur le 30/12/1899).
  • La cellule E5 contient la valeur booléenne VRAI. La formule =CELLULE("contenu"; E5) renvoie 1.
  • Si la formule =CELLULE("contenu") est placée dans une cellule, alors CELLULE signale une erreur de référence circulaire (Err :522).
COORD Renvoie l'adresse complète de la cellule en utilisant une notation héritée, dans laquelle la position de la feuille est indiquée par une lettre (A indique la feuille de calcul à gauche de la zone d'onglets, B la feuille suivante à droite, etc.). Par exemple :
  • Avec la formule située dans la cellule A1 de la huitième feuille, =CELLULE("coord") renvoie $H:$A$1.
  • Avec la formule située dans la sixième feuille, =CELLULE("coord"; D7) renvoie $F:$D$7.

L'option "COORD" pour l'argument Type information n'est pas une exigence d'ODF 1.2.

FILENAME Renvoie le nom du fichier et celui de la feuille dans laquelle se trouve la cellule. Par exemple :
  • Avec la formule dans la cellule D7 de Feuille1 dans le fichier C:/spreadsheets/test.ods, =CELLULE("nomfichier") renvoie 'file:///C:/spreadsheets/test.ods'#$Sheet1.
  • Dans le même fichier, =CELLULE("nomfichier"; $Sheet3.F5) renverrait 'file:///C:/spreadsheets/test.ods'#$Sheet3.
  • Avec la formule dans la cellule D7 de Feuille1 dans une nouvelle feuille de calcul (non enregistrée), =CELLULE("nomfichier") renvoie "#$Sheet1.
FORMAT Renvoie une chaîne de caractères indiquant le format numérique de la cellule. Les valeurs de retour possibles sont définies dans un tableau séparé ci-dessous.
PARENTHESES Renvoie 1 si le code de format de la cellule contient une parenthèse gauche et 0 dans le cas contraire. Par exemple :
  • Si le code de format #,##0_);(#,##0) est appliqué à la cellule D3, alors =CELLULE("parentheses"; D3) renvoie 1.
PREFIX Renvoie une chaîne de caractères unique indiquant l'alignement du texte dans la cellule, codée comme suit :
  • ' (apostrophe) = aligné à gauche
  • " (guillemets) = aligné à droite
  • ^ (circonflexe) = centré
  • \ (barre oblique inverse) = alignement rempli

Par exemple :

  • Si la cellule D3 est alignée à droite, la formule =CELLULE("prefix"; D3) renvoie un guillemet (").

Renvoie le caractère nul (Unicode U+0000) si la cellule ne contient pas de chaîne.

PROTECT Renvoie l'état de protection de la cellule. 1 indique que la cellule est protégée, tandis que 0 indique qu'elle ne l'est pas. Par exemple :
  • Si la cellule B1 est protégée, alors =CELLULE("protection"; B1) renvoie 1.

Notez que la protection des cellules n'est effective qu'une fois la feuille active protégée. La protection de cellule peut être activée même si la feuille n'est pas protégée.

LIGNE Renvoie le numéro de ligne de la cellule. Par exemple :
  • Avec la formule située dans la cellule A1, =CELLULE("ligne") renvoie 1.
  • =CELLULE("ligne"; D7) renvoie 7.
  • =CELLULE("ligne"; Feuille2.E12) renvoie 12.
FEUILLE Renvoie le numéro de la feuille référencée : 1 indique la feuille à gauche de l'onglet, 2 la feuille suivante à droite, et ainsi de suite. Par exemple :
  • Avec la formule située dans la cellule A1 de la feuille Recettes (2e à partir de la gauche dans la zone d'onglets de la feuille), =CELLULE("feuille") renvoie 2.
  • =CELLULE("feuille"; Comptes.G7) renvoie 3 dans le cas où la feuille Comptes est la 3ème à partir de la gauche dans la zone d'onglets de la feuille.
TYPE Renvoie le type de données de la cellule. L'une des trois chaînes de caractères possibles : b (pour blank) pour une cellule vide ; l (pour label) si la cellule contient du texte ; v (pour value) dans le cas contraire. Par exemple :
  • Si la cellule A1 contient le texte "Bonjour le monde !", alors la formule =CELLULE("type"; A1) renvoie l.
  • Si la cellule A2 contient le nombre 2, alors la formule =CELLULE("type"; A2) renvoie v.
  • Si la cellule A3 est vide, la formule =CELLULE("type"; A3) renvoie b.

La formule =CELLULE("type") renvoie toujours v.

WIDTH Renvoie la largeur de la colonne contenant la cellule. L'unité est le nombre de caractères zéro (0) que la colonne peut contenir, selon la police par défaut. Par exemple :
  • Supposons la formule =CELLULE("largeur"; C2) renvoie actuellement la valeur 11.
  • Modifier la largeur de la colonne C affectera le résultat de la formule. Si vous augmentez la largeur de la colonne, la valeur renvoyée augmentera. Si vous réduisez la largeur de la colonne, la valeur renvoyée diminuera. Vous devrez peut-être utiliser Données ▸ Calculer ▸ Recalculer après avoir modifié la largeur de la colonne.


Description des valeurs de retour pour l'argument Type information FORMAT
Valeur de renvoie Signification
Nombres
, (virgule) Indique que la cellule est formatée pour afficher les nombres avec séparateurs de milliers. Le nombre de décimales spécifié par le format de cellule est ajouté après la virgule. Par exemple :
  • Avec le nombre 123 456,7890 affiché dans la cellule A3 (code de format #,###.0000), la formule =CELLULE("format"; A3) renvoie ,4.
F Indique que la cellule est formatée pour afficher les nombres sans séparateur de milliers. Le nombre de décimales spécifié par le format de cellule est ajouté après la lettre F. Par exemple :
  • Avec le nombre 123456,79 affiché dans la cellule A4 (code de format 0,00), la formule =CELLULE("format"; A4) renvoie F2.
  • Avec le nombre 123456,789 affiché dans la cellule A5 (code de format Général), la formule =CELLULE("format"; A5) renvoie F0. Notez que le champ Décimales de l'onglet Nombres de la boîte de dialogue Format de cellules est vide lorsque le format Général est sélectionné.
C Indique que la cellule est formatée pour afficher les nombres au format monétaire. Le nombre de décimales spécifié par le format de cellule est ajouté après la lettre C. Par exemple :
  • Avec la valeur 2,345.68 $ affichée dans la cellule A6 (code de format [$$-409]#,##0.00;-[$$-409]#,##0.00), la formule =CELLULE("format"; A6) renvoie C2.
S Indique que la cellule est formatée pour afficher les nombres en représentation scientifique (exponentielle). Le nombre de décimales spécifié par le format de cellule est ajouté après la lettre S. Par exemple :
  • Avec la valeur 1,23E+45 affichée dans la cellule A7 (code de format 0,00E+00), la formule =CELLULE("format"; A7) renvoie S2.
P Indique que la cellule est formatée pour afficher des pourcentages. Le nombre de décimales spécifié par le format de cellule est ajouté après la lettre P. Par exemple :
  • Avec la valeur 56,789 % affichée dans la cellule A8 (code de format 0,000 %), la formule =CELLULE("format"; A8) renvoie P3.
Dates
D1 Formats de date comprenant les valeurs de jour, de mois et d'année. Par exemple :
  • Avec la date du 12/8/21 affichée dans la cellule A12 (code de format M/D/AA), la formule =CELLULE("format"; A12) renvoie D1.
D2 Formats de date comprenant les valeurs de jour et de mois (nom alphabétique abrégé). Par exemple :
  • Avec la date Dec 08 affichée dans la cellule A13 (code de format MMM JJ), la formule =CELLULE("format"; A13) renvoie D2.
D3 Formats de date comprenant les valeurs de mois et d'année. Par exemple :
  • Avec la date 12/21 affichée dans la cellule A14 (code de format MM/AA), la formule =CELLULE("format"; A14) renvoie D3.
D4 Formats de date et d'heure comprenant les secondes, les minutes, les heures, le jour, le mois et l'année (sans indicateur AM/PM). Par exemple :
  • Avec la date/heure 12/08/2021 20:25:46 affichée dans la cellule A15 (code de format MM/JJ/AAAA HH:MM:SS), la formule =CELLULE("format"; A15) renvoie D4.
D5 Format de date comprenant le jour et le mois (valeurs numériques). Par exemple :
  • Avec la date 12-08 affichée dans la cellule A16 (code de format MM-JJ), la formule =CELLULE("format"; A16) renvoie D5.
D6 Formats horaires incluant les secondes, les minutes et les heures, avec indication AM/PM. Par exemple :
  • Avec l'heure 08:33:35 PM affichée dans la cellule A17 (code de format HH:MM:SS AM/PM), la formule =CELLULE("format"; A17) renvoie D6.
D7 Formats horaires incluant les minutes et les heures, avec indication AM/PM. Par exemple :
  • Avec l'heure 08:33 PM affichée dans la cellule A18 (code de format HH:MM AM/PM), la formule =CELLULE("format"; A18) renvoie D7.
D8 Formats horaires incluant les secondes, les minutes et les heures, sans indication AM/PM. Par exemple :
  • Avec l'heure 20:33:35 affichée dans la cellule A19 (code de format HH:MM:SS), la formule =CELLULE("format", A19) renvoie D8.
D9 Formats horaires incluant les minutes et les heures, sans indicateur AM/PM. Par exemple :
  • Avec l'heure 20:33 affichée dans la cellule A20 (code de format HH:MM), la formule =CELLULE("format"; A20) renvoie D9.
G Tous les autres formats de date et d'heure. Par exemple :
  • Avec la date/heure 2021-12-08 20:33:35 affichée dans la cellule A21 (code de format AAAA-MM-JJ HH:MM:SS), la formule =CELLULE("format"; A21) renvoie G.
Remarques supplémentaires

Un signe moins (-) est ajouté à la fin de la chaîne renvoyée lorsque la cellule est formatée pour afficher les nombres négatifs en couleur. Par exemple :

  • Avec la valeur $12,34 affichée dans la cellule A9 (code de format [$$-409]#,##0.00;[RED]-[$$-409]#,##0.00), la formule =CELLULE("format"; A9) renvoie C2-.

Des parenthèses () sont ajoutées à la fin de la chaîne renvoyée lorsque le code de format de la cellule inclut une parenthèse gauche. Par exemple :

  • Avec la valeur (789) affichée dans la cellule A10 (code de format 0_);(0)), la formule =CELLULE("format"; A10) renvoie F0().
  • Avec la valeur 789,012 affichée dans la cellule A11 (code de format #,###.000_);[RED](#,###.000)), la formule =CELLULE("format"; A11) renvoie ,3-(). Ce code de format complexe affiche les valeurs négatives en rouge, entourées de parenthèses.
  • Si Type d'information ne correspond pas à l'une des chaînes attendues, alors CELLULE signale une erreur d'argument non valide (Err :502).
  • Si Référence ne correspond pas à une référence valide, CELLULE signale une erreur #REF !.
  • Si Type d'information est défini sur « CONTENU » et Référence est omis, alors CELLULE signale une erreur de référence circulaire (Err :522).

Détails complémentaires :

Aucun

Exemples :

Voir les exemples dans les tableaux de la section #Arguments: ci-dessus.

Fonctions LibreOffice associées :

Aucun.

Standard ODF :

Section 6.13.3, part 2

Fonctions Excel relatives (ou similaires) :

CELL