Dokumentation/Calc Funktionen/ZELLE

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/CELL and the translation is 100% complete.
    Other languages:


    Funktionsname:

    ZELLE

    Kategorie:

    Information

    Zusammenfassung:

    Stellt Informationen über Lage, Formatierung oder Inhalt einer Zelle zur Verfügung.

    Syntax:

    ZELLE(Info Typ[; Referenz])

    Rückgabewerte:

    Gibt einen Wert zurück, dessen Typ von der Natur des gewählten Ergebnisses abhängt.

    Argumente:

    Info Typ ist eine Zeichenkette oder eine Referenz aufeine Zelle, die die Zeichenkette enhtält, die den Informationstyp bestimmt, der zurückgegeben werden soll. Info Typ ist nicht case-sensitiv und muss zu einer der folgenden erlaubten Optionen passen - "ADRESSE", "COL", "FARBE", "CONTENTS", "COORD", "FILENAME", "FORMAT", "PARENTHESES", "PREFIX", "PROTECT", "ZEILE", "TABELLE", "TYP" oder "WIDTH".

    Referenz ist eine Referenz auf eine Zelle, über die Informationen zurückgegeben werden soll. Falls die Referenz fehlt, wird die Information über die Zelle zurückgegeben, in der die Formel steht. Referenz kann folgende Formen annehmen:

    • Eine Referenz auf eine Zelle.
    • Eine Referenz auf einen Zellbereich (z. Bsp. D6:E12).
    • Der Name eines benannten Bereiches.
    • Der Name eines Datenbankbereiches.

    Wo die Referenz mehrere Zellen angibt, gibt ZELLE Informationen über die Zelle links oben zurück.

    Note pin.svg

    Anmerkung:
    Der Inhalt der folgenden zwei Tabellen enthält Aspekte, die vom Gebietsschema abhängen, wie z. B. Zahlen- und Datumsformate. Alle Beispiele auf dieser Seite wurden im englischen (USA) Gebietsschema getestet, doch das Verhalten kann in anderen Gebietsschemata anders sein.

    Beschreibung über gültige Info Typen
    Info Typ Bedeutung
    ADRESSE Gibt die absolute Adresse einer Zelle zurück. Zum Beispiel:
    • Mit der Formel in A1 gibt =ZELLE("ADRESSE") $A$1 zurück.
    • =ZELLE("ADRESSE"; D7) gibt $D$7 zurück.
    • =ZELLE("ADRESSE"; Tabelle2.E7) gibt $Tabelle2.$E$7 zurück.
    • =ZELLE("ADRESSE"; 'file:///C:/spreadsheets/test.ods'#$Tabelle1.D10) gibt 'file:///C:/spreadsheets/test.ods'#$Tabelle1.D10 zurück.

    Dieses Beispiel zeigt die Standard-Einstellungen von Calc A1 für die Formel-Syntax im Dialog Extras ▸ Optionen... ▸ LibreOffice Calc ▸ Formel (LibreOffice ▸ Preferences ▸ LibreOffice Calc ▸ Formel unter macOS).

    COL Gibt die Spaltennummer der Zelle zurück (Spalte A ist 1, Spalte B ist 2 und so weiter). Zum Beispiel:
    • Mit der Formel in Zelle A1 gibt =ZELLE("col") 1 zurück.
    • =ZELLE("col"; D7) gibt 4 zurück.
    • =ZELLE("col"; Tabelle2.E7) gibt 5 zurück.
    FARBE Gibt einen Wert zurück, der anzeigt, ob negative Werte in der Zelle eingefärbt werden (1 = einfärben, 0 = nicht einfärben). Zum Beispiel
    • Die Formel =ZELLE("FARBE") gibt in einer Zelle, die eingefärbt wird, 1 zurück. Dazu wurde die Option Negativ in Rot im Tab Zahlen im Dialog Format ▸ Zellen... ausgewählt.
    • Die Formel =ZELLE("FARBE"; D7) gibt 0 zurück, falls Zelle D7 so formatiert ist, dass die Option Negativ in Rot im Tab Zahlen im Dialog Format ▸ Zellen... nicht ausgewählt wurde.
    CONTENTS Gibt den Inhalt einer Zelle ohne jegliche Formatierung zurück.

    Zum Beispiel:

    • Zelle E2 enthält die Zahl -1234.567, wobei die Zelle Zahlen ohne Dezimalstellen anzeigt und negative Zahlen in rot dargestellt werden. (Format Code 0;[ROT]-0). Die Formel =ZELLE("contents"; E2) gibt -1234.567 ohne Formatierung in der Zelle E2 zurück.
    • Zelle E3 enthält den Text "Hallo Welt!", formatiert fett, kursiv und unterstrichen. Die Formel =ZELLE("contents"; E3) gibt "Hallo Welt!" zurück, ohne den Formatierungen in Zelle E3.
    • Zelle E4 enthält das Datum 05.12.2021. Die Formel =ZELLE("contents"; E4) gibt die Zahl 44535, den Zeitstempel des 05.12.2021 (vorausgesetzt, das Startdatum für die interne Konversion von Tagen in Zahlen ist der Standard am 30.12.1899), zurück.
    • Zelle E5 enthält den Wahrheitswert WAHR. Die Formel =ZELLE("contents"; E5) gibt 1 zurück.
    • Falls die Formel =ZELLE("contents") in einer Zelle platziert ist, dann meldet ZELLE einen Kreisbezug (Fehler:522).
    COORD Gibt die komplette Zell-Adresse in alter Notation wieder, in welcher die Tabellen Position durch einen Buchstaben angezeigt wird. (A gibt die Tabelle links im Tabellen-Tab, B ist die nächste Tabelle und so weiter). Zum Beispiel;
    • Wenn die Formel in Zelle A1 der achten Tabelle ist, gibt =ZELLE("coord") $H:$A$1 zurück.
    • Wenn die Formel in der sechsten Tabelle ist gibt =ZELLE("coord"; D7) $F:$D$7 zurück.

    Die Option "COORD" des Info Typs ist keine Anforderung des ODF 1.2.

    FILENAME Gibt den Dateinamen und den Namen der Tabelle an, in welcher die Zelle liegt. Zum Beispiel:
    • Mit der Formel in Zelle D7 der Tabelle1 in der Datei C:/spreadsheets/test.ods, gibt =ZELLE("filename") 'file:///C:/spreadsheets/test.ods'#$Tabelle1 an.
    • In der selben Datei meldet =ZELLE("filename"; $Tabelle3.F5) 'file:///C:/spreadsheets/test.ods'#$Tabelle3.
    • Mit der Formel in Zelle D7 der Tabelle1 in einer neuen

    (ungespeicherten) Tabelle meldet =ZELLE("filename") "#$Tabelle1.

    FORMAT Gibt eine Zeichenkette zurück, die das Zahlenformat der Zelle anzeigt. Die möglichen Rückgabewerte sind in folgender Tabelle aufgelistet.
    PARENTHESES Gibt 1 zurück, falls der Formatierungs Code der Zelle eine linke Klammer hat, ansonsten 0. Zum Beispiel:
    • Falls der Formatierungscode #,##0_);(#,##0) für Zelle D3 angewendet wird, dann meldet =ZELLE("parentheses"; D3) 1.
    PREFIX Gibt ein einzelnes Zeichen zurück, das die Ausrichtung des Textes in der Zelle anzeigt, kodiert wie folgt:
    • ' (Apostroph) = links ausgerichtet
    • " (Anführungszeichen) = rechts ausgerichtet
    • ^ (Zirkumflex) = zentriert
    • \ (Backslash) = Blocksatz

    Zum Beispiel:

    • Fals Zelle D3 rechts ausgerichtet ist, gibt die Formel ZELLE("prefix"; D3) ein Anführungszeichen zurück (").

    Gibt das Null-Zeichen (Unicode U+0000) zurück, wenn die Zelle kein Zeichen enthält.

    PROTECT Gibt den Status des Zellschutzes für die Zelle zurück. 1 zeigt an, dass die Zelle geschützt ist, während 0 anzeigt, dass die Zelle nicht geschützt ist. Zum Beispiel:
    • Falls Zelle B1 geschützt ist, dann gibt =ZELLE("protect"; B1) 1 zurück.

    Der Zellschutz ist nur aktiv, wenn die ganze Tabelle geschützt ist. Zellschutz ist nicht aktiv, wenn die Tabelle nicht geschützt ist.

    ZEILE Gibt die Zeilennummer der Zelle zurück. Zum Beispiel:
    • Mit der Formel in Zelle A1 gibt =ZELLE("row") 1 zurück.
    • =ZELLE("row"; D7) gibt 7 zurück.
    • =ZELLE("row"; Tabelle2.E12) gibt 12 zurück.
    TABELLE Gibt die Nummer der referenzierten Tabelle zurück. 1 gibt die Tabelle links im Tabellen-Tab an, 2 die nächste Tabelle und so weiter. Zum Beispiel:
    • Mit der Formel in Zelle A1 in der Tabelle Rezepte (2. Tabelle von links im Tabellen-Tab) gibt =ZELLE("Tabelle") 2 zurück.
    • =ZELLE("Tabelle"; Konten.G7) gibt 3 zurück, wenn die Tabelle "Konten" die 3. Tabelle von links im Tabellen-Tab ist.
    TYP Gibt den Typ der Daten in der Zelle zurück. Eine der drei möglichen einstelligen Zeichenketten - b (für blank) für eine leere Zelle; l (für label) falls die Zelle Text enthält und sonst v (für value).

    Zum Beispiel:

    • Falls die Zelle A1 den Text "Hallo Welt!" enthält, gibt die Formel =ZELLE("TYP"; A1) l zurück.
    • Falls die Zelle A2 die Zahl 2 enthält, gibt die Formel =ZELLE("TYP"; A2) v zurück.
    • Falls die Zelle A3 leer ist, gibt die Formel =ZELLE("TYP"; A3) b zurück.

    Die Formel =ZELLE("TYP") gibt immer v zurück.

    WIDTH Gibt die Breite der Spalte an, in der die Zelle liegt. Die Einheit ist die Anzahl der Nullen (0) der Standardschrift, die in die Spalte passen. Zum Beispiel:
    • Angenommen, die Formel =ZELLE("width"; C2) gibt gegenwärtig die Zahl 11 zurück.
    • Änderungen in der Breite von Spalte C wirkt sich auf die Formel aus. Wenn die Breite der Spalte erhöht wird, erhöht sich der zurückgegebene Wert. Vermindert sich die Breite der Spalte, dann vermindert sich der zurückgegebene Wert. Nach Veränderung der Spaltenbreite kann Daten ▸ Berechnen ▸ Unbedingte Neuberechnung verwendet werden.


    Beschreibung der Rückgabewerte des Info Typs FORMAT
    Rückgabewert Bedeutung
    Zahlen
    , (Komma) Zeigt an, dass die Zelle formatiert ist, Zahlen mit Tausender-Trennzeichen anzuzeigen. Die Anzahl der Nachkommastellen aus dem Zellenformat wird nach dem Komma angehängt. Zum Beispiel:
    • Bei der Zahl 123.456,7890 in Zelle A3 (Format-Code ist #.##0,0000) gibt die Formel =ZELLE("Format"; A3) 0,4 zurück.
    F Zeigt an, dass die Zelle formatiert ist, Zahlen ohne Tausender-Trennzeichen anzuzeigen. Die Zahl der Nachkommastellen aus dem Zellenformat wird an den Buchstaben F angehängt. Zum Beispiel:
    • Bei der Zahl 123456,7890 in Zelle A4 (Format-Code ist 0,00) gibt die Formel =ZELLE("Format"; A4) F2 zurück.
    • Bei der Zahl 123456,789 in Zelle A5 (Format-Code ist Standard) gibt die Formel =ZELLE("Format"; A3) F0 zurück. Das Feld für die Nachkommastellen im Zahlen Tab im Dialog Zellen formatieren ist beim Format Standard leer.
    C Zeigt an, dass die Zelle formatiert ist, Zahlen als Währung anzuzeigen. Die Anzahl an Nachkommastellen aus dem Zellenformat wird an den Buchstaben C angehängt. Zum Beispiel:
    • Bei der Zahl 2.345,68 € in der Zelle A6 (Format-Code #.##0 [$€-407];-#.##0 [$€-407]) gibt die Formel =ZELLE("Format"; A6) C2 zurück.
    S Zeigt an, dass die Zelle formatiert ist, Zahlen wissenschaftlicher (exponentieller) Notation anzuzeigen. Die Anzahl der vom Zellenformat definierten Nachkommastellen wird nach dem Buchstaben S angehängt. Zum Beispiel:
    • Bei der Zahl 1,23E+45 in Zelle A7 (Format-Code ist 0,00E+00) gibt die Formel =ZELLE("Format"; A7) S2 zurück.
    P Zeigt an, dass die Zelle formatiert ist, Zahlen als Prozent anzuzeigen. Die Anzahl der vom Zellenformat definierten Nachkommastellen wird nach dem Buchstaben P angehängt. Zum Beispiel:
    • Bei der Zahl 56,789 % in Zelle A8 (Format-Code ist 0,000" "%) gibt die Formel =ZELLE("Format"; A8) P3 zurück.
    Datum
    D1 Datumsformat mit Tages-, Monats- und Jahresangabe. Zum Beispiel:
    • Beim Datum 08.12.2021 in Zelle A12 (Format-Code TT.MM.JJJJ) gibt die Formel =ZELLE("Format"; A12) D1 zurück.
    D2 Datumsformat mit Tages- und Monatsangabe (abgekürzter alphabetischer Name). Zum Beispiel:
    • Beim Datum 08.Dez in Zelle A13 (Format-Code TT.MMM) gibt die Formel =ZELLE("Format"; A13) D2 zurück.
    D3 Datumsformat mit Monats- und Jahresangabe. Zum Beispiel:
    • Beim Datum 12.21 in Zelle A14 (Format-Code MM.JJ) gibt die Formel =ZELLE("Format"; A14) D3 zurück.
    D4 Datums- und Zeitformat mit Sekunden-, Minuten-, Stunden-, Tages-, Monats und Jahresangabe . Zum Beispiel:
    • Beim Datum/Zeit 08.12.2021 20:25:46 in Zelle A15 (Format-Code TT.MM.JJJJ HH:MM:SS) gibt die Formel =ZELLE("Format"; A15) D4 zurück.
    D5 Datumsformat mit Tages- und Monatsangabe (numerischer Name). Zum Beispiel:
    • Beim Datum 12-08 in Zelle A16 (Format-Code MM-TT) gibt die Formel =ZELLE("Format"; A16) D5 zurück.
    D6 Zeitformat mit Sekunden-, Minuten- und Stundenangabe (mit Angabe vorm./nachm.). Zum Beispiel:
    • Bei der Uhrzeit 08:33:35 nachm. in Zelle A17 (Format-Code HH:MM:SS AM/PM) gibt die Formel =ZELLE("Format"; A17) D6 zurück.
    D7 Zeitformat mit Minuten- und Stundenangabe (mit Angabe vorm./nachm.). Zum Beispiel:
    • Bei der Uhrzeit 08:33 nachm. in Zelle A18 (Format-Code HH:MM AM/PM) gibt die Formel =ZELLE("Format"; A18) D7 zurück.
    D8 Zeitformat mit Sekunden-, Minuten- und Stundenangabe ohne Angabe vorm./nachm.. Zum Beispiel:
    • Bei der Uhrzeit 20:33:35 nachm. in Zelle A18 (Format-Code HH:MM:SS) gibt die Formel =ZELLE("Format"; A19) D8 zurück.
    D9 Zeitformat mit Minuten- und Stundenangabe ohne Angabe vorm./nachm.. Zum Beispiel:
    • Bei der Uhrzeit 20:33 in Zelle A20 (Format-Code HH:MM) gibt die Formel =ZELLE("Format"; A20) D9 zurück.
    G Alle anderen Datums- und Zeitformate. Zum Beispiel:
    • Bei der Datum/Zeit 2021-12-08 20:33:35 in Zelle A21 (Format-Code JJJJ-MM-TT HH:MM:SS) gibt die Formel =ZELLE("Format"; A21) G zurück.
    Zusätzliche Angaben

    Ein - (Minus) wird ans Ende der zurückzugebenden Zeichenkette angehängt, wenn die Zelle formatiert ist, negative Zahlen in rot anzuzeigen Zum Beispiel:

    • Beim Wert 12,34 € in Zelle A9 (Format-Code 0,000 [$€-407];[ROT]-0,000 [$€-407]) gibt die Formel =ZELLE("Format"; A9) C2- zurück.

    () (Klammern) werden am Ende der zurückzugebenden Zeichenkette angehängt, wenn der Format-Code der Zelle eine linke Klammer enthält. Zum Beispiel:

    • Bei der Zahl (789) in Zelle A19 (Format-Code 0_);(0) gibt die Formel ZELLE("Format"; A10) F0() zurück.
    • Bei der Zahl 789,012 in Zelle A11 (Format-Code #.##0,000_);[ROT](#.##0,000)) gibt die Formel =ZELLE("Format"; A11) ,3-() zurück. Dieser komplexe Format-Code zeigt negative Zahlen in rot umgeben von Klammern.
    • Falls Info Typ zu keiner der erwarteten Zeichenketten passt, dann meldet ZELLE einen invalid argument error (Fehler:502).
    • Falls Referenz keiner gültigen Referenz entspricht, meldet ZELLE einen #BEZUG! Fehler.
    • Falls der Info Typ auf "CONTENTS" steht und Referenz fehlt, dann meldet ZELLE einen Kreisbezug (Fehler:522).

    Zusätzliche Informationen:

    Nichts

    Beispiele:

    Siehe Beispiele im Abschnitt #Argumente:

    Ähnliche LibreOffice Funktionen:

    Nichts.

    ODF Standard:

    Kapitel 6.13.3, Teil 2.

    Betroffene (oder ähnliche) EXCEL-Funktionen:

    CELL