Documentation/Calc Functions/DDB
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Donate
Function name:
DDB
Category:
Financial Analysis
Summary:
Calculates the depreciation of an asset for a given period using the fixed rate declining balance method. This method calculates the depreciation based on the current book value of the asset (rather than its original cost) and this decreases from one period to the next. This leads to the depreciation being greater in earlier periods and less in later periods.
DDB uses a fixed depreciation rate that is proportional to the inverse of the asset's estimated useful life. The constant of proportionality is passed as an argument.
Syntax:
DDB(Cost; Salvage; Life; Period[; Factor])
Returns:
Returns a non-negative real number which is the depreciation of the asset for a specified period using the fixed rate declining balance method. The number returned is in the same currency unit as the specified cost and salvage values, and by default is formatted in a locale-dependent currency format.
Arguments:
Cost is a non-negative real number, or a reference to a cell containing that number, which is the cost or value of the asset before depreciation.
Salvage is a non-negative real number, or a reference to a cell containing that number, which is the residual value of the asset at the end of its depreciated life. Salvage must be in the same currency units as Cost.
Life is a positive real number (Life ≥ 1), or a reference to a cell containing that number, which defines the number of periods over which the asset is depreciated.
Period is a positive real number, or a reference to a cell containing that number, which specifies the period for which the depreciation value is returned.
Factor is a positive real number, or a reference to a cell containing that number, which specifies the depreciation factor to be used.
If a value is not specified, the default is 2.
If Factor = 2, then DDB uses the double declining balance method.
If Factor = 3, then DDB uses the triple declining balance method.
- If any argument is non-numeric then DDB reports a #VALUE! error.
- The function reports an invalid argument error (Err:502) in any of the following circumstances:
- Cost < 0.
- Salvage < 0 or Salvage > Cost.
- Life < 1.
- Period < 1 or Period > Life.
- Factor ≤ 0.
Additional details:
- To calculate the depreciation, DDB uses a fixed rate throughout the asset's life, given by:
- [math]\displaystyle{ Rate~=~Factor~\times~\frac{1}{Life} }[/math]
- The term [math]\displaystyle{ \frac{1}{Life} }[/math] is often called the straight-line depreciation rate.
- The depreciation in each period is calculated as:
- [math]\displaystyle{ \text{MIN}(Book~value \times Rate; Book~value - Salvage) }[/math]
- where Book value refers to the asset's value at the start of the period, which is calculated as Cost less the total depreciation expenses to date.
- DDB does not depreciate the asset to a value that is less than Salvage.
- For more background information about depreciation, visit Wikipedia’s Depreciation page.
Examples:
Note that the formatting of the return values given in the following examples might assume the English (USA) locale.
Simple example with multiple calls to DDB
The following table illustrates the behavior of the DDB function.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Cost: | 1200 | Period | Depreciation | |
| 2 | Salvage: | 200 | 1 | $600.00 | |
| 3 | Life: | 4 | 2 | $300.00 | |
| 4 | Factor: | 2 | 3 | $100.00 | |
| 5 | 4 | $0.00 | |||
| 6 | |||||
| 9 | Total | $1,000.00 |
The data in cells B1:B4 contain the values for four of the arguments passed in DDB function calls.
The function is called four times, once for each value of the Period argument given in cells D2 to D5.
Cell E2 contains the formula =DDB($B$1; $B$2; $B$3; $D2; $B$4); cell E3 contains the formula =DDB($B$1; $B$2; $B$3; $D3; $B$4); and so on.
The values returned from the DDB calls are shown in cells E2:E5 and cell E7 contains the sum of all the values in cells E2:E5. The following features can be seen in these results:
- Period 1. DDB uses a fixed rate given by [math]\displaystyle{ Factor \times \frac{1}{Life}~ }[/math] or [math]\displaystyle{ ~2 \times \frac{1}{4}=0.5 }[/math]. Hence the depreciation for this period is 0.5 × 1200 = 600. Note that by default, the results from DDB are formatted as a currency.
- Period 2. The value of the asset at the start of this period is 1200-600=600. Therefore the depreciation for this period is 0.5 × 600=300.
- Period 3. The value of the asset at the start of this period is 1200-900=300. The depreciation for this period as a result of applying the fixed rate would be 0.5 × 300=150. However, applying this depreciation expense would bring the value of the asset down below its Salvage value. Therefore, the depreciation expense in this period is limited to 300-200=100.
- Period 4. Since the asset has already been depreciated to its Salvage value, DDB returns 0 (zero) for this period.
- Note that the total depreciation of 1,000.00 is exactly equal to the difference between the cost and salvage values of 1200-200=1000 for this example. However, this will not always be the case - for example, the same data as this apart from a Factor of 1.25 (instead of 2) gives a total depreciation of 931.92 over the four periods in the asset's useful life.
Additional examples
| Formula | Description | Returns |
|---|---|---|
| =DDB(75000; 10000; 5; 1; 1.5) |
A computer system with an initial cost of 75,000 currency units is to be depreciated over 5 years. The salvage value is 10,000 currency units, and the depreciation factor is 1.5. The declining balance depreciation of the computer system over the first year is 22,500 currency units. |
$22,500.00 |
| =DDB(75000; 10000; 5; 2; 1.5) |
A computer system with an initial cost of 75,000 currency units is to be depreciated over 5 years. The salvage value is 10,000 currency units, and the depreciation factor is 1.5. The declining balance depreciation of the computer system over the second year is 15,750 currency units. |
$15,750.00 |
| =DDB(28000; 5000; 7; 5) |
A car with an initial cost of 28,000 currency units is to be depreciated over 7 years.
The salvage value is 5,000 currency units, and the depreciation factor is omitted and so defaults to 2.
The declining balance depreciation of the car over the fifth year is 2,082.47 currency units.
The formula |
$2,082.47 |
Related LibreOffice functions:
ODF standard:
Related (or similar) Excel functions:
DDB