Documentatie/Calc-functies/DDB

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/DDB and the translation is 100% complete.
    Other languages:

    Functienaam:

    DDB

    Categorie:

    Financieel

    Samenvatting:

    Berekent de afschrijving van een bezit voor een bepaalde periode met behulp van de degressieve methode met vaste rente. Deze methode berekent de afschrijving op basis van de huidige boekwaarde van het bezit (in plaats van de oorspronkelijke kostprijs) en deze neemt af van de ene periode naar de volgende. Dit leidt ertoe dat de afschrijving in eerdere perioden groter is en in latere perioden lager.

    DDB gebruikt een vast afschrijvingspercentage dat evenredig is met het omgekeerde van de geschatte gebruiksduur van het bezit. De evenredigheidsconstante wordt als argument doorgegeven.

    Syntaxis:

    DDB(Kosten; Restwaarde; Levensduur; Periode[; Factor])

    Retourneert:

    Retourneert een niet-negatief reëel getal dat de afschrijving is van het bezit gedurende een bepaalde periode met behulp van de degressieve methode met vaste rente. Het geretourneerde getal is in dezelfde valuta-eenheid als de opgegeven kosten- en restwaarden en wordt standaard opgemaakt in een landafhankelijke valuta-indeling.

    Argumenten:

    Kosten is een niet-negatief reëel getal of een verwijzing naar een cel die dat getal bevat, wat de kosten of waarde is van het activum vóór afschrijving.

    Restwaarde is een niet-negatief reëel getal, of een verwijzing naar een cel die dat getal bevat, wat de restwaarde is van het bezit aan het einde van zijn afgeschreven levensduur. Restwaarde moet in dezelfde valuta-eenheden zijn als Kosten.

    Levensduur is een positief reëel getal (Levensduur ≥ 1,0) of een verwijzing naar een cel die dat getal bevat, dat het aantal perioden definieert waarover het bezit wordt afgeschreven.

    Periode is een positief reëel getal of een verwijzing naar een cel die dat getal bevat, dat de periode aangeeft waarvoor de afschrijvingswaarde wordt geretourneerd.

    Factor is een positief reëel getal of een verwijzing naar een cel die dat getal bevat, dat de te gebruiken afschrijvingsfactor specificeert. Als er geen waarde is opgegeven, is de standaardwaarde 2,0. Als Factor = 2,0, dan gebruikt DDB de dubbele degressieve methode. Als Factor = 3,0, dan gebruikt DDB de driedubbele degressieve methode.

    • Als een argument niet-numeriek is, retourneert DDB als foutcode #WAARDE!
    • De functie retourneert als foutcode Ongeldig argument (Fout:502) in elk van de volgende omstandigheden:
    • Kosten < 0,0.
    • Restwaarde < 0 of Restwaarde > Kosten.
    • Levensduur < 1.0.
    • Periode < 1,0 of Periode > Levensduur.
    • Factor ≤ 0,0.

    Aanvullende details:

    • Om de afschrijving te berekenen, gebruikt DDB een vast tarief gedurende de levensduur van het bezit, gegeven door:
    [math]\displaystyle{ Kosten~=~Factor~\times~\frac{1}{Levensduur} }[/math]
    • De term [math]\displaystyle{ \frac{1}{Levensduur} }[/math] wordt vaak het lineaire afschrijvingspercentage genoemd.
    • De afschrijving in elke periode wordt berekend als:
    [math]\displaystyle{ \text{MIN}(Boek~waarde \times koers; Boek~waarde - Restwaarde) }[/math]
    waarbij Boekwaarde verwijst naar de waarde van het bezit aan het begin van de periode, die wordt berekend als Kosten verminderd met de totale afschrijvingskosten tot nu toe.
    • DDB schrijft het bezit niet af tot een waarde die lager is dan Restwaarde.
    • Ga voor meer achtergrondinformatie over afschrijving naar de pagina Depreciation op Wikipedia.

    Voorbeelden:

    Houd er rekening mee dat de opmaak van de geretourneerde waarden die in de volgende voorbeelden worden gegeven, uitgaat van de landinstelling Engels (VS).

    Eenvoudig voorbeeld met meerdere aanroepen naar DDB

    De volgende tabel illustreert het gedrag van de functie DDB.

    A B C D E
    1 Kosten 1200 Periode Afschrijving
    2 Restwaarde 200 1 $600.00
    3 Levensduur 4 2 $300.00
    4 Factor 2 3 $100.00
    5 4 $0.00
    6
    9 Totaal $1,000.00

    De gegevens in cellen B1:B4 bevatten de waarden voor vier van de argumenten die zijn doorgegeven in DDB functieaanroepen. De functie wordt vier keer aangeroepen, één keer voor elke waarde van het argument Periode in de cellen D2 tot D5. Cel E2 bevat de formule =DDB($B$1; $B$2; $B$3; $D2; $B$4); cel E3 bevat de formule =DDB($B$1; $B$2; $B$3; $D3; $B$4); enzovoort.

    De waarden die worden geretourneerd door de DDB-aanroepen worden weergegeven in cellen E2:E5 en cel E7 bevat de som van alle waarden in cellen E2:E5. In deze resultaten zijn de volgende kenmerken te zien:

    • Periode 1. DDB gebruikt een vast tarief gegeven door [math]\displaystyle{ Factor \times \frac{1}{Levensduur}~ }[/math] of [math]\displaystyle{ ~2 \times \frac{1}{4}=0.5 }[/math]. De afschrijving voor deze periode is dus [math]\displaystyle{ 0,5 \times 1200 = 600 }[/math]. Merk op dat de resultaten van DDB standaard zijn opgemaakt als een valuta.
    • Periode 2. De waarde van het bezit aan het begin van deze periode is [math]\displaystyle{ 1200-600=600 }[/math]. Daarom is de afschrijving voor deze periode [math]\displaystyle{ 0,5 \times 600=300 }[/math].
    • Periode 3. De waarde van het bezit aan het begin van deze periode is [math]\displaystyle{ 1200-900=300 }[/math]. De afschrijving over deze periode als gevolg van toepassing van het vaste tarief zou [math]\displaystyle{ 0,5 \times 300=150 }[/math] zijn. Het toepassen van deze afschrijvingskosten zou de waarde van het bezit echter verlagen tot onder de Restwaarde-waarde. Daarom zijn de afschrijvingskosten in deze periode beperkt tot [math]\displaystyle{ 300-200=100 }[/math].
    • Periode 4. Aangezien het bezital is afgeschreven tot de Restwaarde-waarde, retourneert DDB 0,0 voor deze periode.
    • Merk op dat de totale afschrijving van 1.000,00 exact gelijk is aan het verschil tussen de kostprijs en de restwaarde van 1000 voor dit voorbeeld. Dit zal echter niet altijd het geval zijn - dezelfde gegevens als deze, afgezien van een factor van 1,25 (in plaats van 2) geven bijvoorbeeld een totale afschrijving van 931,92 over de vier perioden van de gebruiksduur van het bezit.

    Extra voorbeelden

    Formule Beschrijving Retourneert
    =DDB(75000; 10000; 5; 1; 1.5) Een computersysteem met een initiële kostprijs van 75.000 valutaeenheden wordt in 5 jaar afgeschreven. De restwaarde is 10.000 valuta-eenheden en de afschrijvingsfactor is 1,5. De degressieve afschrijving van het computersysteem over het eerste jaar is 22.500 valuta-eenheden. $22,500.00
    =DDB(75000; 10000; 5; 2; 1.5) Een computersysteem met een initiële kostprijs van 75.000 valutaeenheden wordt in 5 jaar afgeschreven. De restwaarde is 10.000 valuta-eenheden en de afschrijvingsfactor is 1,5. De degressieve afschrijving van het computersysteem over het tweede jaar is 15.750 valuta-eenheden. $15,750.00
    =DDB(28000; 5000; 7; 5) Een auto met een initiële kostprijs van 28.000 valutaeenheden wordt in 7 jaar afgeschreven. De restwaarde is 5.000 valuta-eenheden en de afschrijvingsfactor is weggelaten en is dus standaard 2. De degressieve afschrijving van de auto over het vijfde jaar is 2.082,47 valuta-eenheden. De formule =DDB(28000; 5000; 7; 5; 2) geeft hetzelfde resultaat. $2,082.47

    Gerelateerde LibreOffice-functies:

    AMORDEGRC

    AMORLINC

    DB

    LIN.AFSCHR

    SYD

    VDB

    JAAR.DEEL

    ODF standaard:

    Sectie 6.12.14, deel 2

    Gerelateerde (of gelijkwaardige) Excel-functies:

    DDB