Dokumentation/Calc Funktionen/DEZIMAL
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende
Funktionsname:
DEZIMAL
Kategorie:
Text
Zusammenfassung:
Konvertiert die textuelle Entsprechung einer Zahl mit der angegebenen Basis in eine Dezimalzahl
Die Funktion DEZIMAL ist komplementär zur Funktion BASIS.
Syntax:
DEZIMAL(Text; Basis)
Rückgabewerte:
Gibt eine nicht-negative Ganzzahl zurück, die der dezimalen Zahl der textuellen Entsprechung zur angegebenen Basis entspricht.
Argumente:
Text ist eine Zeichenkette (in Anführungszeichen) oder eine Referenz auf eine Zelle die die Zeichenkette enthält. Diese Zeichenkette besteht aus den Ziffern einer Zahl die in eine Dezimalzahl umzurechnen ist. Für jeden gültigen Wert der Basis und falls die zu konvertierende Zahl nur Ziffern (0 bis 9) enthält, kann sie auch als Zahl oder als Referenz auf eine Zelle mit der Zahl angegeben werden. In einem solchen Fall scheint der Text dezimal zu sein, aber DEZIMAL erkennt sie korrekt anhand der angegebenen Basis.
Basis ist eine Ganzzahl im Bereich 2 ≤ r ≤ 36 oder eine Referenz auf eine Zelle mit dieser Ganzzahl, die als Basis für die Konversion dient.
- Falls der Text ungültige Zeichen zur angegebenen Basis enthält, dann meldet DEZIMAL einen invalid argument error (Fehler:502). Die folgenden Regeln bestimmen die Gültigkeit der Zeichen im Text.
- Führende Leerzeichen und Tabulatoren sind gültig und werden ignoriert.
- Führende Nullen sind gültig und werden ignoriert.
- Wo Buchstaben im Text auftauchen dürfen, sind sowohl Groß- als auch Kleinbuchstaben akzeptiert und werden gleich behandelt.
- Die folgende Tabelle listet die gültigen Zeichen im Text für jeder Basis. Aus Gründen der besseren Lesbarkeit werden in der Tabelle nur Großbuchstaben aufgelistet.
| Basis | Erwartete Zeichen |
|---|---|
| 2 (binär) | Ziffern 0 und 1. Üblicherweise wird ein "B" oder "b" der binären Zahl hinten angestellt. z. Bsp. "100111B". DEZIMAL akzeptiert einen solchen Suffix. |
| 3 | Ziffern 0 bis 2 |
| 4 | Ziffern 0 bis 3 |
| 5 | Ziffern 0 bis 4 |
| 6 | Ziffern 0 bis 5 |
| 7 | Ziffern 0 bis 6 |
| 8 (oktal) | Ziffern 0 bis 7 |
| 9 | Ziffern 0 bis 8 |
| 10 (dezimal) | Ziffern 0 bis 9 |
| 11 | Ziffern 0 bis 9 und Buchstabe A (10) |
| 12 | Ziffern 0 bis 9 und Buchstaben A (10) und B (11) |
| 13 | Ziffern 0 bis 9 und Buchstaben A (10) bis C (12) |
| 14 | Ziffern 0 bis 9 und Buchstaben A (10) bis D (13) |
| 15 | Ziffern 0 bis 9 und Buchstaben A (10) bis E (14) |
| 16 (hexadezimal) | Ziffern 0 bis 9 und Buchstaben A (10) bis F (15). Üblicherweise wird ein "0x", "X" oder "x" der hexadezimalen Zahl vorangestellt. z. Bsp. "0X1AF". DEZIMAL akzeptiert einen solchen Präfix. Es ist genauso üblich, einen Suffix "H" oder "h" zu einer hexadezimalen Zahl zu verwenden. Z. Bsp. "1AFH".DEZIMAL akzeptiert einen solchen Suffix. |
| 17 | Ziffern 0 bis 9 und Buchstaben A (10) bis G (16) |
| 18 | Ziffern 0 bis 9 und Buchstaben A (10) bis H (17) |
| 19 | Ziffern 0 bis 9 und Buchstaben A (10) bis I (18) |
| 20 | Ziffern 0 bis 9 und Buchstaben A (10) bis J (19) |
| 21 | Ziffern 0 bis 9 und Buchstaben A (10) bis K (20) |
| 22 | Ziffern 0 bis 9 und Buchstaben A (10) bis L (24) |
| 23 | Ziffern 0 bis 9 und Buchstaben A (10) bis M (22) |
| 24 | Ziffern 0 bis 9 und Buchstaben A (10) bis N (23) |
| 25 | Ziffern 0 bis 9 und Buchstaben A (10) bis O (24) |
| 26 | Ziffern 0 bis 9 und Buchstaben A (10) bis P (25) |
| 27 | Ziffern 0 bis 9 und Buchstaben A (10) bis Q (26) |
| 28 | Ziffern 0 bis 9 und Buchstaben A (10) bis R (27) |
| 29 | Ziffern 0 bis 9 und Buchstaben A (10) bis S (28) |
| 30 | Ziffern 0 bis 9 und Buchstaben A (10) bis T (29) |
| 31 | Ziffern 0 bis 9 und Buchstaben A (10) bis U (30) |
| 32 | Ziffern 0 bis 9 und Buchstaben A (10) bis V (31) |
| 33 | Ziffern 0 bis 9 und Buchstaben A (10) bis W (32) |
| 34 | Ziffern 0 bis 9 und Buchstaben A (10) bis X (33) |
| 35 | Ziffern 0 bis 9 und Buchstaben A (10) bis Y (34) |
| 36 | Ziffern 0 bis 9 und Buchstaben A (10) bis Z (35) |
- Falls der Text eine leere Zeichenkette ist, gibt DEZIMAL unabhängig von der Basis 0 zurück.
- Falls die Basis nicht numerisch ist, dann meldet DEZIMAL einen #WERT! Fehler.
- Falls die Basiskeine Ganzzahl ist, verkürzt sie DEZIMAL auf eine Ganzzahl.
- Falls die Basis nach einer eventuellen Verkürzung kleiner als 2 oder größer als 36 ist, dann meldet DEZIMAL einen invalid argument error (Fehler:502).
Zusätzliche Informationen:
Die Zahlensysteme zu jeder Basis haben vorgegebene Namen, die in der Wiki unter List of numeral systems aufgelistet sind.
Für nicht negative Ganzzahlen x und eine gültige Basis b gilt: x = DEZIMAL(BASIS(x; b); b).
Beispiele:
| Formel | Beschreibung | Ergebnis |
|---|---|---|
| =DEZIMAL(1111; 2) | Hier gibt die Funktion die Zahl 15 zurück. Das ist der dezimale Wert von binär 1111. Der selbe Wert wird zurückgegeben, wenn das erste Argument mit "1111b" angegeben wird - der Wert muss als Text angegeben werden, falls irgendwelche nicht-numerische Zeichen angegeben werden. | 15 |
| =DEZIMAL(" 0017"; 8,3) | Hier gibt die Funktion die Zahl 15 zurück. Das ist der dezimale Wert von oktal "17". DEZIMAL ignoriert die führenden Leerzeichen und Nullen im Text des ersten Argumentes und verkürzt das zweite Argument auf die Basis 8. | 15 |
| =DEZIMAL(D1; D2) wobei die Zellen D1 und D2 die Zahlen 56 und 10 enthalten. | Hier gibt die Funktion die Zahl 56 zurück. | 56 |
| =DEZIMAL("AF"; 16) | Hier gibt die Funktion die Zahl 175 zurück. Das ist der dezimale Wert von hexadezimal "AF". Der selbe Wert wird zurückgegeben, wenn das erste Argument durch "af", "xAF", "0XAF" oder "AFh" ersetzt wird. | 175 |
| =DEZIMAL("AV"; 32) | Hier gibt die Funktion die Zahl 351 zurück. Das ist der dezimale Wert von duotrigesimal (Basis 32) "AV". | 351 |
| =DEZIMAL("az"; 36) | Hier gibt die Funktion die Zahl 395 zurück. Das ist der dezimale Wert von hexatrigesimal (Basis 36) "az". | 395 |
| =DEZIMAL("FACE"; 16) | Hier gibt die Funktion die Zahl 64206 zurück. Das ist der dezimale Wert von hexadezimal "FACE". | 64206 |
Ähnliche LibreOffice Funktionen:
ODF Standard:
Betroffene (oder ähnliche) EXCEL-Funktionen:
DECIMAL seit Version 2013.