Documentación/Funciones de Calc/MULTIPLO.INFERIOR.MAT

This page is a translated version of the page Documentation/Calc Functions/FLOOR.MATH and the translation is 91% complete.

TDF LibreOffice en español Document Liberation Project Blogs comunitarios Weblate Nextcloud Redmine Preguntas y respuestas Donar

Other languages:

Inicio Funciones Calc | Lista de funciones | Abreviaturas

Nombre de la función:

MULTIPLO.INFERIOR.MAT

Categoría:

Matemáticas

Resumen:

Redondea un número al múltiplo más cercano de un valor significativo. En la mayoría de los casos, el número se redondea hacia abajo (hacia -∞). Sin embargo, se proporciona un parámetro de modo y cuando se establece en un valor distinto de cero, los números negativos se redondean hacia arriba (hacia +∞).

Sintaxis:

MULTIPLO.INFERIOR.MAT(Number [; Significance [; Mode]])

Devuelve:

Devuelve un número real que es el valor redondeado y es un múltiplo entero del valor significativo.

Argumentos:

Número es un número real, o una referencia a una celda que contiene ese número, que es el valor que se va a redondear.

Significatividad es un número real, o una referencia a una celda que contiene ese número, ese es el valor de significatividad que se utilizará. Si se omite, el valor predeterminado de Significatividad es 1. Se ignora el signo de Significatividad.

Modo es un número real, o una referencia a una celda que contiene ese número, que es un indicador de modo booleano. Modo solo es efectivo cuando Número es negativo. Si Modo está presente y es igual a cualquier valor distinto de cero (incluido VERDADERO), los números negativos se redondean hacia arriba (hacia +∞). Si se omite Modo, o es igual a cero o FALSO, los números negativos se redondean hacia abajo (hacia -∞).

Si algún argumento no es numérico, MULTIPLO.INFERIOR.MAT mostrará el error #¡VALOR!.
Si Número o Significatividad es igual a 0, MULTIPLO.INFERIOR.MAT devolverá 0.

Detalles adicionales:

Detalles específicos de la función MULTIPLO.INFERIOR.MAT

Con Significatividad configurada en -1 o +1, o predeterminada en 1, y Modo configurado o predeterminado en 0 o FALSO, MULTIPLO.INFERIOR.MAT proporciona una funcionalidad, que implementa la definición matemática estándar de un valor inferior.
MULTIPLO.INFERIOR.MAT es similar a la función MULTIPLO.INFERIOR, la diferencia entre las dos radica en la interpretación del argumento Significatividad. La función MULTIPLO.INFERIOR requiere que los argumentos Significatividad y Número tengan el mismo signo, mientras que para MULTIPLO.INFERIOR.MAT se ignora el signo de el argumento Significatividad.

Información general sobre las funciones de múltiplo inferior (floor) de Calc

Nota:
Para mayor comodidad, la información de esta subsección se repite en todas las páginas que describen las funciones de múltiplo inferior (floor) de Calc.

Puede encontrar información general introductoria sobre las funciones de múltiplos en la página de Wikipedia Funciones de parte entera o múltiplos superior (techo) e inferior (suelo).

Calc proporciona cuatro funciones que se pueden usar para calcular el número entero más próximo a un número real por debajo de este, y estas son:

La más importante de ellas para muchos usuarios será la función MULTIPLO.INFERIOR, que implementa los requisitos establecidos en Sección 6.17.3 de ODF 1.2, Parte 2.

Calc proporciona las funciones MULTIPLO.INFERIOR.MAT y MULTIPLO.INFERIOR.EXACTO para aumentar la interoperabilidad con Microsoft Excel, que proporciona dos funciones similares con los mismos nombres.

La función MULTIPLO.INFERIOR de Microsoft Excel acepta dos argumentos, por lo que no cumple con ODF 1.2. Esta diferencia de comportamiento podría generar problemas de interoperabilidad, pero estos se evitan mediante la provisión de la función MULTIPLO.INFERIOR.XCL, de la siguiente manera:

Cuando Calc guarda una hoja de cálculo en formato Excel 2007-365 (*.xlsx), cualquier llamada a la función MULTIPLO.INFERIOR de Calc se convierte en una llamada a la función MULTIPLO.INFERIOR.MAT de Excel. , y cualquier llamada a la función MULTIPLO.INFERIOR.XCL se convierte en una llamada a la función MULTIPLO.INFERIOR de Excel.
Cuando Calc abre una hoja de cálculo en formato Excel 2007-365 (*.xlsx), cualquier llamada a la función MULTIPLO.INFERIOR de Excel se convierte en una llamada a la función MULTIPLO.INFERIOR.XCL de Calc.

Ejemplos:

Fórmula	Descripción	Devuelve
=MULTIPLO.INFERIOR.MAT(11,5)	El valor predeterminado de Significatividad es 1 y el valor predeterminado de Modo es 0. La función redondea hacia abajo 11,5 al múltiplo entero más cercano a 1.	11
=MULTIPLO.INFERIOR.MAT(−11,5)	El valor predeterminado de Significado es 1 y el valor predeterminado de Modo es 0. La función redondea hacia abajo -11,5 al múltiplo entero más cercano a 1.	−12
=MULTIPLO.INFERIOR.MAT(7; 2,3)	El valor predeterminado de Modo es 0. La función redondea 7 al múltiplo entero más cercano a 2,3.	6,9
=MULTIPLO.INFERIOR.MAT(−7; −2,3)	El valor predeterminado de Modo es 0. La función redondea hacia abajo -7 al múltiplo entero más cercano a 2,3 (se ignora el signo del valor significativo).	−9,2
=MULTIPLO.INFERIOR.MAT(D1; D2; D3) donde las celdas D1, D2 y D3 contienen los números 10, 3 y 1 respectivamente.	La función redondea hacia abajo el valor 10 al múltiplo entero más cercano a 3. El valor de Modo no es significativo para un número positivo.	9
=MULTIPLO.INFERIOR.MAT(−10; −3; 0)	Con Modo establecido en 0, la función redondea hacia abajo el valor -10 al múltiplo entero más cercano a 3 (se ignora el signo del valor significativo).	−12
=MULTIPLO.INFERIOR.MAT(−10; −3; 7,6)	Con Modo establecido en un valor distinto de cero, la función redondea hacia arriba el valor de -10 al múltiplo entero más cercano a 3 (se ignora el signo del valor significativo).	−9
=MULTIPLO.INFERIOR.MAT(−3,6; ; VERDADERO())	El valor predeterminado de Significatividad es 1. Con Modo establecido en un valor distinto de cero, la función redondea el valor de -3,6 al múltiplo entero más cercano a 1.	−3