Dokumentation/Calc Funktionen/WENN

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/IF and the translation is 100% complete.
    Other languages:


    Funktionsname:

    WENN

    Kategorie:

    Logisch

    Zusammenfassung:

    Bestimmt, ob eine einzelne Bedingung zutrifft und gibt einen Wert zurück, wenn die Bedingung zutrifft, und den anderen Wert, wenn sie nicht zutrifft.

    Für mächtigere Formeln wird WENN mit anderen logischen Formeln (wie z. Bsp. UND und ODER) kombiniert und WENN Anweisungen ineinander verschachtelt.

    Syntax:

    WENN(Test[; [Dann Teil][; [Sonst Teil]]])

    Rückgabewerte:

    Gibt einen Wert zurück, der von den Argumenten wie folgt abhängt:

    • Falls Dann Teil und Sonst Teil fehlen, dann gibt WENN entweder WAHR oder FALSCH zurück, je nachdem, ob Test stimmt oder nicht.
    • Falls die Bedingung von Test zutrifft und der Dann Teil fehlt, dann gibt WENN WAHR zurück.
    • Falls die Bedingung von Test zutrifft und der Dann Teil angegeben ist, dann gibt WENN den Dann Teil zurück.
    • Falls die Bedingung von Test nicht zutrifft und der Sonst Teil fehlt, dann gibt WENN FALSCH zurück.
    • Falls die Bedingung von Test nicht zutrifft und der Sonst Teil angegeben ist, dann gibt WENN den Sonst Teil zurück.

    Argumente:

    Test ist ein Ausdruck oder eine Referenz auf eine Zell, die einen Ausdruck enthält, der einen logischen Wert WAHR oder FALSCH enthalten kann. Falls Test eine Zahl statt eines logischen Wertes enthält, wird 0 (Null) als FALSCH und jeder andere Zahl als WAHR behandelt. Jeder Vergleichsoperator in Calc = (ist gleich), <> (ist ungleich), > (größer als), >= (größer oder gleich), < (kleiner als) und <= (kleiner oder gleich) kann genutzt werden, um Bedingungen im Test zu erzeugen.

    Dann Teil ist ein Ausdruck oder eine Referenz auf eine Zelle, die einen Ausdruck enthält der ausgewertet wird und zurückgegeben wird, wenn Test WAHR ist.

    Sonst Teil ist ein Ausdruck oder eine Referenz auf eine Zelle, die einen Ausdruck enthält der ausgewertet wird und zurückgegeben wird, wenn Test FALSCH ist.

    • Falls Test nicht als logischer Wert gewertet dann meldet WENN einen #WERT! Fehler.
    • Die Funktion WENN erkennt nur einen Dann Teil oder Sonst Teil. Die Formel =WENN(1 = 2; 1/0; WURZEL(4)) zum Beispiel gibt 2 zurück, die Quadratwurzel von 4. Da 1/0 einen #DIV/0! Fehler erzeugt, ist die Division in diesem Fall nicht berücksichtigt.

    Zusätzliche Informationen:

    Allgemeine Informationen über die logischen Funktionen in Calc

    Note pin.svg

    Anmerkung:
    Der Einfachheit halber werden die Informationen dieses Unterabschnittes auf allen Seiten der logischen Funktionen in Calc wiederholt.

    Calc verwendet die Zahlen 0 (FALSCH) und 1 (WAHR) um logische Werte auszudrücken. Geben Sie zum Beispiel 1 in eine Zelle im allgemeinen Zahlenformat ein. Gehen Sie dann auf Format ▸ Zellen... in der Menüleiste, wählen Sie Wahrheitswert im Feld Kategorie des Tabs Zahlen und klicken auf OK. Beachten Sie, das die Zahl 1 jetzt als WAHR angezeigt wird. Um die Anzeige zurückzustellen, wiederholen Sie den Vorgang, wählen Sie aber Dezimalzahl anstatt Wahrheitswert.

    Um einen logischen Wert in eine Zelle einzugeben, tippen Sie einfach WAHR oder FALSCH (case-insensitive) in die Zelle ein. Calc erkennt den logischen Wert, zeigt ihn in Großbuchstaben an und ändert die Formatierung der Zelle auf Wahrheitswert.

    Calc Funktionen, die einen Wahrheitswert erzeugen, geben ihn als Zahl, entweder 0 oder 1, zurück. Im Fall einer Formel, die eine solche logische Funktion aufruft und in einer Zelle mit einer Formatierung zur Dezimalzahl wird die Formatierung der Zelle auf einen Wahrheitswert geändert. Dabei wird der Rückgabewert als FALSCH oder WAHR angezeigt. Zum Beispiel gibt =WAHR() den Wert 1 zurück. Dieser wird als WAHR angezeigt. Falls Sie die Formatierung der Zelle auf Dezimalzahl ändern, wird die Zahl 1 angezeigt.

    Calc Funktionen, die auf einen Wahrheitswert testen, tun dies immer, in dem Sie den Ausdruck auf den Wert 0 testen. Der Wert 0 wird als FALSCH angesehen. Jeder andere Wert wird als WAHR angesehen. Zum Beispiel gibt =NICHT(0) WAHR zurück, während =NICHT(57.89) FALSCH zurückgibt.

    Im Gegensatz zu Calc hat Microsoft EXCEL einen seperaten Typ für logische Werte - sie sind keine Zahlen sondern werden manchmal in Zahlen umgewandelt. Also Vorsicht bei Kompatibilitätsbedarf.

    Beispiele:

    Basis Beispiele

    Formel Beschreibung Ergebnis
    =WENN(A1>5; 100; "zu klein") Hier gibt die Funktion die Zahl 100 zurück, falls A1 größer als 5 ist und sonst den Text "zu klein". 100 oder "zu klein"
    =WENN(1>2; "Unsinn") Hier gibt die Funktion FALSCH zurück, weil der Sonst Teil fehlt und 1 nicht größer als 2 ist. FALSCH
    =WENN(2>1) Hier gibt die Funktion WAHR zurück, weil sowohl der Dann Teil als auch der Sonst Teil fehlen und 2 größer ist als 1. WAHR
    =WENN(D1; D2; D3)

    wobei die Zellen D1, D2 und D3 die Zahlen 123, 456 und 789 enthalten.

    Hier stellt die Funktion fest, dass Test eine Zahl ungleich 0 ist und damit als WAHR gewerted wird. Der Inhalt des Dann Teils wird zurückgegeben. 456

    verschachtelte WENNs

    Zelle A1 enthält eine Zahl mit dem Winkel Φ im Bogenmaß. Dieser liegt im Bereich 0 ≤ Φ < 2π. Wir können eine Formel erstellen, die verschachtelte Aufrufe der Funktion WENN verwendet und den Quadranten ermittelt, in dem der aktuelle Wert von Φ liegt.

    Die vier Quadranten eines Kreises

    Die folgende Formel gibt eine textuelle Beschreibung zurück, in welchem Quadranten der Wert aus Zelle A1 liegt.

    =WENN(UND(A1>=0; A1<PI()/2); 
         "1. Quadrant"; 
          WENN(UND(A1>=PI()/2; A1<PI()); 
              "2. Quadrant"; 
               WENN(UND(A1>=PI(); A1<3*PI()/2); 
                   "3. Quadrant"; 
                    "4. Quadrant")))
    
    • Falls Zelle A1 die Zahl 0,785398163397448 (π/4, 45°) enthält, gibt die Formel den Text "1. Quadrant" zurück.
    • Falls Zelle A1 die Zahl 2,35619449019234 (3π/4) enthält, gibt die Formel den Text "2. Quadrant" zurück.
    • Falls Zelle A1 die Zahl 3,92699081698724 (5π/4) enthält, gibt die Formel den Text "3. Quadrant" zurück.
    • Falls Zelle A1 die Zahl 5,49778714378214 (7π/4) enthält, gibt die Formel den Text "4. Quadrant" zurück.

    WENN in einer Matrix-Formel

    Die Ergebnisse der letzten Mathe Arbeit sind da. Der Korrektor hat entschieden, die Ergebnisse in eine Calc Tabelle in Übereinstimmung mit folgender Tabelle zu geben. Er tippt die Namen der Schüler in die Zellen A2 bis A11 und ihre Noten in die Zellen B2 bis B11.

    Unglücklicherweise müssen die Schüler, die die Arbeit nicht mit mindestens 45 % bestanden haben, nachsitzen und die Arbeit nochmal schreiben, um ihre Studien fortführen zu dürfen. Der Korrektor entscheidet, dass er bei Veröffentlichung der Ergebnisse hervorheben will, welche Schüler die Arbeit wiederholen müssen und nutzt dafür die Funktion WENN aus Calc in einer Matrix-Formel.

    A B C
    1 Schüler Ergebnis (%) Durchgefallen?
    2 Aaron 46
    3 Betty 35 JA
    4 Brian 43 JA
    5 Claudia 72
    6 Ethan 80
    7 Gary 64
    8 Jay 41 JA
    9 Kaitlyn 60
    10 Samantha 65
    11 Shane 41 JA
    12
    13 Bestanden 45

    Die Zellen C2:C11 werden wie folgt gefüllt:

    1. Auswahl der Zellen C2:C11.
    2. Eingabe der Formel =WENN(B2:B11>=$B$13; ""; "YES") in die Eingabezeile in der Formelzeile ein. Die Eingabe wird nicht mit Enter bestätigt.
    3. Die Eingabe wird mit Strg + ⇧ Shift + ↵ Enter (⌘ Command + ⇧ Shift + ↵ Enter unter macOS) als Matrix-Formel bestätigt.

    Calc stelt einen leeren Text in Spalte C für die Schüler, die ihre Arbeit bestanden haben, während der Text "JA" in Spalte C für die Schüler erscheint, die weniger als 45 % erreicht haben und die Arbeit wiederholen müssen. Jede Zelle im Bereich C2:C11 enthält die Formel {=WENN(B2:B11>=$B$13; ""; "YES")}, wobei Calc die geschweiften Klammern zur Kennzeichnung als Matrix-Formel ergänzt hat. Diese Klammern können nicht selbst ergänzt werden.

    Ähnliche LibreOffice Funktionen:

    UND

    FALSCH

    WENNFEHLER

    WENNNV

    WENNS

    NICHT

    ODER

    SCHALTER

    WAHR

    XODER

    ODF Standard:

    Kapitel 6.15.4, Teil 2.

    Betroffene (oder ähnliche) EXCEL-Funktionen:

    IF