Documentatie/Calc-functies/ALS

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/IF and the translation is 100% complete.

    TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren

    Other languages:


    Functienaam:

    ALS

    Categorie:

    Logisch

    Samenvatting:

    Bepaalt of aan een enkele voorwaarde wordt voldaan, waarbij één waarde wordt geretourneerd als aan de voorwaarde wordt voldaan en een andere waarde als niet aan de voorwaarde wordt voldaan.

    Combineer, voor krachtigere formules, ALS met andere logische functies (zoals EN en OF) en nest ALS-statements in elkaar.

    Syntaxis:

    ALS(Test[; [Dan Waarde][; [Anders Waarde]]])

    Retourneert:

    Retourneert als volgt een waarde die afhankelijk is van de argumenten:

    • Als de argumenten Dan Waarde en Anders Waarde worden weggelaten, retourneert ALS WAAR of ONWAAR om aan te geven of aan de voorwaarde van het argument Test is voldaan.
    • Als aan de voorwaarde van het argument Test is voldaan en het argument Dan Waarde wordt weggelaten, retourneert ALS WAAR.
    • Als aan de voorwaarde van het argument Test is voldaan en het argument Dan Waarde is opgegeven, retourneert ALS Dan Waarde als resultaat.
    • Als niet aan de voorwaarde van het argument Test wordt voldaan en het argument Andere waarde wordt weggelaten, retourneert ALS ONWAAR.
    • Als niet wordt voldaan aan de voorwaarde die wordt gegeven door het argument Test en het argument Andere waarde wordt opgegeven, dan retourneert ALS Andere waarde.

    Argumenten:

    Test is een uitdrukking of een verwijzing naar een cel die een uitdrukking bevat, die kan worden geëvalueerd tot een logische waarde WAAR of ONWAAR. Als Test wordt geëvalueerd tot een getal in plaats van een logische waarde, wordt de waarde 0 (nul) behandeld als ONWAAR, terwijl elke waarde die niet nul is, wordt behandeld als WAAR. Elk van de vergelijkende operatoren van Calc = (gelijk aan), <> (ongelijkheid), > (groter dan), >= (groter dan of gelijk aan), < (kleiner dan) en <= (kleiner dan of gelijk aan) kan zijn gebruikt om voorwaarden te maken in het argument Test.

    Dan Waarde is een uitdrukking of een verwijzing naar een cel die een uitdrukking bevat, die wordt geëvalueerd en geretourneerd wanneer Test wordt geëvalueerd als WAAR.

    Anders Waarde is een uitdrukking of een verwijzing naar een cel die een uitdrukking bevat, die wordt geëvalueerd en geretourneerd wanneer Test wordt geëvalueerd als ONWAAR.

    • Als Test niet kan worden geëvalueerd als een logische waarde, dan retourneert ALS een foutcode #WAARDE!
    • De functie evalueert slechts één van Dan Waarde en Anders Waarde. De formule =ALS(1=2; 1/0; WORTEL(4)) retourneert bijvoorbeeld 2, de vierkantswortel van 4. Terwijl 1/0 misschien een foutcode #DELING.DOOR.0! verwacht, in dit geval wordt geen poging gedaan tot deling.

    Aanvullende details:

    Algemene informatie over de logische functies van Calc

    Note pin.svg

    NB:
    Voor het gemak wordt de informatie in deze subsectie herhaald op alle pagina's die de logische functies van Calc beschrijven.

    Calc gebruikt de getallen 0 (ONWAAR) en 1 (WAAR) om logische waarden weer te geven. Voer bijvoorbeeld 1 in in een cel met de standaard algemene getalopmaak. Selecteer vervolgens Opmaak ▸ Cellen op de Menubalk om het dialoogvenster Cellen opmaken weer te geven, selecteer de optie Booleaanse waarde in het gedeelteCategorie van het tabblad Getallen en klik op de knop OK. Merk op dat het getal 1 nu wordt weergegeven als WAAR. Om terug te keren naar het weergeven van het getal 1, herhaalt u het proces maar selecteert u Getal in plaats van Booleaanse waarde.

    Om een logische waarde in een cel in te voeren, typt u gewoon WAAR of ONWAAR (hoofdletterongevoelig) in de cel. Calc zal de logische waarde herkennen, deze in hoofdletters weergeven en de opmaak van de cel wijzigen in de opmaak die past bij Booleaanse waarden.

    Calc-functies die een logisch resultaat produceren, geven een getal terug, of 0 of 1. In het geval van een formule die zo'n logische functie eenvoudig aanroept en zich in een cel bevindt die de standaard algemene getalopmaak heeft, wordt de cel overgeschakeld naar de opmaak van de Booleaanse waarde en de geretourneerde waarde wordt weergegeven als ONWAAR of WAAR. Bijvoorbeeld =WAAR() retourneert de waarde 1, die wordt weergegeven als WAAR; als u de opmaak vervolgens wijzigt in een numerieke opmaak, wordt het weergegeven als het getal 1.

    Calc-functies die op een logisch resultaat testen, evalueren altijd de te testen uitdrukking en controleren of deze gelijk is aan 0. De waarde 0 wordt als ONWAAR beschouwd en elke andere waarde wordt als WAAR genomen. Bijvoorbeeld, =NIET(0) geeft WAAR terug en =NIET(57,89) geeft ONWAAR terug.

    In tegenstelling tot Calc heeft Microsoft Excel een apart type voor logische waarden - het zijn geen getallen maar worden soms geconverteerd naar getallen. Wees daarom voorzichtig als u compatibiliteit nodig heeft.

    Voorbeelden:

    Basisvoorbeelden

    Formule Beschrijving Retourneert
    =ALS(A1>5; 100; "te klein") Hier retourneert de functie het getal 100 als A1 groter is dan 5 en anders de tekst "te klein". 100 of "te klein"
    =ALS(1>2; "onzin") Hier retourneert de functie ONWAAR, omdat het argument Anders Waarde is weggelaten en 1 niet groter is dan 2. ONWAAR
    =ALS(2>1) Hier retourneert de functie WAAR, omdat zowel de argumenten Dan Waarde als Anders Waarde zijn weggelaten en 2 groter is dan 1. WAAR
    =ALS(D1; D2; D3)

    waarbij de cellen D1, D2 en D3 respectievelijk de nummers 123, 456 en 789 bevatten.

    		Hier bepaalt de functie dat Test een waarde is die niet nul is en daarom wordt behandeld als WAAR. De waarde van het argument Dan Waarde wordt geretourneerd. 456

    Geneste ALS-functies

    Stel dat cel A1 een getal bevat dat een hoek voorstelt, uitgedrukt in radialen en ligt in het bereik 0 Φ < 2π. We zouden een formule kunnen schrijven die gebruikmaakt van geneste aanroepen naar de functie ALS en het kwadrant bepaalt van een cirkel waarin de huidige waarde van Φ ligt.

    The four quadrants of a circle

    De volgende formule retourneert een tekenreeks die het kwadrant beschrijft waarin de waarde in cel A1 ligt. 

    =ALS(EN(A1>=0; A1<PI()/2); 
     "1e kwadrant"; 
      ALS(EN(A1>=PI()/2; A1<PI()); 
          "2e kwadrant"; 
           ALS(EN(A1>=PI(); A1<3*PI()/2); 
               "3e kwadrant"; 
                "4e kwadrant")))
    • Als cel A1 het getal 0,785398163397448 (π/4) bevat, retourneert de formule de tekenreeks "1e kwadrant".
    • Als cel A1 het getal 2,35619449019234 (3π/4) bevat, retourneert de formule de tekenreeks "2e kwadrant".
    • Als cel A1 het getal 3,92699081698724 (5π/4) bevat, retourneert de formule de tekenreeks "3e kwadrant".
    • Als cel A1 het getal 5,49778714378214 (7π/4) bevat, retourneert de formule de tekenreeks "4e kwadrant".

    ALS gebruiken in een matrixformule

    De resultaten van het recente wiskunde-examen zijn beschikbaar en de docent heeft besloten om de resultaten in een Calc-werkbladte zetten in overeenstemming met de volgende tabel. Hij typt de namen van de leerlingen in de cellen A2 tot en met A11 en hun cijfers in de cellen B2 tot en met B11.

    Helaas moeten leerlingen die het examencijfer van 45% (ingevoerd in cel B13) niet halen, het examen opnieuw doen (en slagen) voordat ze verder mogen studeren. De docent besluit dat hij bij het publiceren van de resultaten moet benadrukken welke leerlingen het examen opnieuw moeten afleggen en kiest ervoor om de functie ALS van Calc in een matrixformule te gebruiken om dit te doen.

    A B C
    1 Leerling Uitslag examen (%) Herexamen nodig?
    2 Aaron 46
    3 Betty 35 Ja
    4 Brian 43 Ja
    5 Claudia 72
    6 Ethan 80
    7 Gary 64
    8 Jay 41 Ja
    9 Kaitlyn 60
    10 Samantha 65
    11 Shane 41 Ja
    12
    13 Vereist minimum 45

    De cellen C2:C11 worden als volgt gevuld:

    1. Selecteer de cellen C2:C11 met de cursor.
    2. Typ de formule =ALS(B2:B11>=$B$13; ""; "Ja") op de invoerregel op de formulebalk. Druk NIET op Enter wanneer u klaar bent met het typen van de formule.
    3. Wanneer het typen is voltooid, drukt u op Ctrl + ⇧ Shift + ↵ Enter (⌘ Command + ⇧ Shift + ↵ Enter op macOS) om de formule in te voeren als een matrixformule.

    Calc plaatst een lege tekenreeks in kolom C voor leerlingen die geslaagd zijn voor het examen, terwijl de tekenreeks "Ja" in kolom C verschijnt voor die leerlingen die minder dan 45% hebben gescoord en het examen opnieuw moeten afleggen. Merk op dat elke cel in het bereik C2:C11 de formule {=ALS(B2:B11>=$B$13; ""; "Ja")} bevat, waarbij Calc de accolades heeft toegevoegd om een matrixformule aan te geven. U kunt deze haakjes niet zelf toevoegen.

    Gerelateerde LibreOffice-functies:

    EN

    ONWAAR

    ALS.FOUT

    ALS.NB

    ALS.VOORWAARDEN

    NIET

    OF

    SCHAKELEN

    WAAR

    EX.OF

    ODF standaard:

    Section 6.15.4, part 2

    Gerelateerde (of gelijkwaardige) Excel-functies:

    IF


    Retrieved from "https://wiki.documentfoundation.org/index.php?title=Documentation/Calc_Functions/IF/nl&oldid=728230"