Documentazione/Funzioni di Calc/SE
TDF LibreOffice Document Liberation Project Blog comunitari Weblate Nextcloud Redmine Ask LibreOffice Donazione
Nome funzione:
SE
Categoria:
Logica
Riepilogo:
Determina se una singola condizione è soddisfatta, restituendo un valore se la condizione è soddisfatta e un valore diverso se la condizione non è soddisfatta.
Per formule più potenti, combinate SE con altre funzioni logiche (come E e O) e annidate le istruzioni SE l'una dentro l'altra.
Sintassi:
SE(Test[; [Allora il valore][; [Altrimenti il valore]]])
Restituisce:
Restituisce un valore che dipende dagli argomenti, come segue:
- Se gli argomenti Allora il valore e Altrimenti il valore vengono omessi, SE restituisce VERO oppure FALSO per indicare se la condizione specificata dall'argomento Test è soddisfatta.
- Se la condizione data dall'argomento Test è soddisfatta e l'argomento Allora il valore viene omesso, SE restituisce VERO.
- Se la condizione data dall'argomento Test è soddisfatta e viene fornito l'argomento Allora il valore, SE restituisce Allora il valore.
- Se la condizione specificata dall'argomento Test non è soddisfatta e l'argomento Altrimenti il valore viene omesso, SE restituisce FALSO.
- Se la condizione specificata dall'argomento Test non è soddisfatta e viene fornito l'argomento Altrimenti il valore, SE restituisce Altrimenti il valore.
Argomenti:
Test è un'espressione, o un riferimento a una cella contenente un'espressione, che può essere valutata come un valore logico VERO o FALSO. Se Test viene valutato come un numero anziché come un valore logico, il valore 0 (zero) viene trattato come FALSO, mentre qualsiasi valore diverso da zero viene trattato come VERO. Tutti gli operatori comparativi di Calc = (uguale), <> (disuguaglianza), > (maggiore di), >= (maggiore o uguale a), < (minore di) e <= (minore o uguale a) possono essere utilizzati per creare condizioni nell'argomento Test.
Allora Valore è un'espressione, o un riferimento a una cella contenente un'espressione, che viene valutata e restituita quando Test viene valutato come VERO.
Altrimenti Valore è un'espressione, o un riferimento a una cella contenente un'espressione, che viene valutata e restituita quando Test viene valutato come FALSO.
- Se Test non può essere valutato come valore logico, allora SE riporta un errore #VALORE!.
- La funzione SE valuta solo uno tra Allora Valore e Altrimenti Valore. Ad esempio, la formula
=SE(1=2; 1/0; RADQ(4))
restituisce 2, la radice quadrata di 4. Mentre ci si potrebbe aspettare che1/0
generi un errore #DIV/0!, in questo caso la divisione non viene tentata.
Dettagli aggiuntivi:
Informazione generale riguardo alle funzioni logiche di Calc
Calc utilizza i numeri 0 (FALSO) e 1 (VERO) per rappresentare valori logici. Ad esempio, inserite 1 in una cella che ha il formato numerico generale predefinito. Quindi selezionate
▸ sulla barra dei menu per visualizzare la finestra di dialogo Formato celle, selezionate l'opzione Valore booleano nell'area Categoria della scheda Numeri, e fate clic sul pulsante . Notate che il numero 1 è ora visualizzato come VERO. Per tornare alla visualizzazione del numero 1, ripetete la procedura ma selezionate Numero invece di Valore booleano.Per inserire un valore logico in una cella, digitate semplicemente VERO o FALSO (senza distinzione tra maiuscole e minuscole) nella cella. Calc riconoscerà il valore logico, lo visualizzerà in lettere maiuscole e cambierà il formato della cella in quello appropriato ai valori booleani.
Le funzioni di calcolo che producono un risultato logico restituiscono un numero, 0 o 1. Nel caso di una formula che chiama semplicemente tale funzione logica e si trova in una cella che ha il formato numerico generale predefinito, la cella passa al formato valore booleano e il valore restituito viene visualizzato come FALSO o VERO. Ad esempio =VERO()
restituisce il valore 1, che viene visualizzato come VERO; se poi si cambia il formato in un formato numerico, viene visualizzato come il numero 1.
Le funzioni di calcolo che verificano un risultato logico valutano sempre l'espressione da testare e controllano se è uguale a 0. Il valore 0 viene considerato FALSO e qualsiasi altro valore viene considerato VERO. Ad esempio, =NON(0)
restituisce VERO e =NON(57.89)
restituisce FALSO.
A differenza di Calc, Microsoft Excel ha un tipo separato per i valori logici: non sono numeri ma a volte vengono convertiti in numeri. Fate attenzione quindi se avete bisogno di compatibilità.
Esempi:
Esempi base
Formula | Descrizione | Restituisce |
---|---|---|
=SE(A1>5; 100; "troppo piccolo") | Restituisce il numero 100 se A1 è più grande di 5, e il testo "troppo piccolo" altrimenti. | 100 o "troppo piccolo" |
=SE(1>2; "non ha senso") | Restituisce FALSO, perché l'argomento Altrimenti Valore è stato omesso e 1 non è maggiore di 2. | FALSO |
=SE(2>1) | Restituisce VERO, perché entrambi gli argomenti Allora Valore e Altrimenti Valore sono stati omessi e 2 è maggiore di 1. | VERO |
=SE(D1; D2; D3)
dove le celle D1, D2 e D3 contengono rispettivamente i numeri 123, 456 e 789. |
Determina che Test è un valore diverso da zero e quindi viene trattato come VERO. Viene restituito il valore dell'argomento Allora Valore. | 456 |
Annidamento dei SE
Supponiamo che la cella A1 contenga un numero che rappresenta un angolo Φ espresso in radianti e compreso nell'intervallo 0 ≤ Φ < 2π. Potremmo scrivere una formula che utilizza chiamate nidificate alla funzione SE e determina il quadrante di un cerchio in cui si trova il valore corrente di Φ.

La seguente formula restituisce una stringa che descrive il quadrante in cui si trova il valore nella cella A1.
|
- Se la cella A1 contiene il numero 0,785398163397448 (π/4, 45°), la formula restituisce la stringa "1° quadrante".
- Se la cella A1 contiene il numero 2,35619449019234 (3π/4, 135°), la formula restituisce la stringa "2° quadrante".
- Se la cella A1 contiene il numero 3,92699081698724 (5π/4, 225°), la formula restituisce la stringa "3° quadrante".
- Se la cella A1 contiene il numero 5,49778714378214 (7π/4, 315°), la formula restituisce la stringa "4° quadrante".
Utilizzo di SE in una formula di matrice
Sono disponibili i risultati dell'ultimo esame di matematica e il docente ha deciso di inserirli in un foglio di calcolo Calc in base alla seguente tabella. Digita i nomi degli studenti nelle celle da A2 ad A11 e i loro voti nelle celle da B2 a B11.
Sfortunatamente, gli studenti che non raggiungono il punteggio di passaggio del 45% (inserito nella cella B13) devono ripetere (e superare) l'esame prima di continuare gli studi. Il docente decide che quando pubblica i risultati, deve sottolineare quali studenti dovranno sostenere nuovamente l'esame e sceglie di usare la funzione SE di Calc in una formula di matrice per farlo.
A | B | C | |
---|---|---|---|
1 | Studente | Punteggio esame (%) | È necessario ripetere l'esame? |
2 | Aaron | 46 | |
3 | Betty | 35 | SÌ |
4 | Brian | 43 | SÌ |
5 | Claudia | 72 | |
6 | Ethan | 80 | |
7 | Gary | 64 | |
8 | Jay | 41 | SÌ |
9 | Kaitlyn | 60 | |
10 | Samantha | 65 | |
11 | Shane | 41 | SÌ |
12 | |||
13 | Limite sufficienza | 45 |
Le celle C2:C11 sono popolate come segue:
- Selezionate le celle C2:C11 utilizzando il cursore.
- Digitate la formula
=SE(B2:B11>=$B$13; ""; "sì")
nella riga di input nella barra della formula. Non premete Invio quando avete finito di digitare la formula. - Una volta completata la digitazione, premere Template:Tasto (Template:Tasto su macOS) per immettere la formula come formula di matrice.
Calc inserisce una stringa vuota nella colonna C per gli studenti che hanno superato l'esame, mentre la stringa "SÌ" appare nella colonna C per gli studenti che hanno ottenuto un punteggio inferiore al 45% e dovranno ripetere l'esame.
Nota che ogni cella nell'intervallo C2:C11 contiene la formula {=SE(B2:B11>=$B$13; ""; "SÌ")}, dove Calc ha aggiunto le parentesi graffe per indicare una formula di matrice.
Non puoi aggiungere queste parentesi tu stesso.
Funzioni di LibreOffice correlate:
Standard ODF:
Funzioni equivalenti (o simili) di Excel:
IF