Dokumentation/Calc Funktionen/MEHRFACH.OPERATIONEN
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende
Funktionsname:
MEHRFACH.OPERATIONEN
Kategorie:
kein Assistent
Zusammenfassung:
Berechnet den Wert in einer Beispiel-Berechnung durch Ersetzen einer oder zwei Variablen aus einer Beispielberechnung mit laufenden Werten.
Syntax:
MEHRFACH.OPERATIONEN( Referenz Formelzelle; Referenz Zellenzeile; Referenz Ersatz-Zeile [; Referenz Zellenspalte; Referenz Ersatz-Spalte ] )
Rückgabewerte:
Gibt den Wert, den die Beispiel-Berechnung zurückgeben würde, wenn Sie mit den Beispiel-Werten aufgerufen würde.
Argumente:
| Formelzelle | Referenz auf die Zelle die die Beispielberechnung enthält |
| Zellenzeile | Referenz auf die Zelle die in der Formel für die Beispielberechnung für die erste Variable verwendet wird. |
| Ersatzzeile | Referenz auf die Zelle die die Ersatzvariable anstatt der ersten Variable für die Beispielberechnung enthält |
| Spaltenzelle | Referenz auf die Zelle die die Ersatzvariable anstatt der zweiten Variable für die Beispielberechnung enthält |
| Ersatzspalte | Referenz auf die Zelle die die Ersatzvariable anstatt der zweiten Variable für die Beispielberechnung enthält |
Zusätzliche Informationen:
Der Name "Zeile" und "Spalte" in den Argumenten zeigt, dass die Funktion genutzt werden kann, um eine zweidimensionale Tabelle zu erzeugen, so wie es unter ▸ gemacht wird. Tatsächlich können die aktuellen Werte beliebig abgelegt werden.
Die Formel in der Ergebniszelle der Beispielberechnung braucht keine direkte Referenz auf das, wovon es ursprünlich eine "Variable" war. Es reicht, wenn das Ergebnis indirekt von der Zelle der "Variable" abhängt.
Eine Zelle, welche das aktuelle Ergbnis enthält, darf nicht von von den Zellen aus der Beispielberechnung abhängen, weder direkt noch indirekt.
Die Funktion MEHRFACH.OPERATIONEN kann keine Literale, z. Bsp. Konstante Zahlen, als Argumente übernehmen. Die Argumente müssen Referenzen, also z. Bsp. E2 oder $Tabelle2.A1, sein.
Es ist möglich, dass die angegebenen Referenzen berechnet sind. Aber sie müssen Referenzen sein. Achtung: Die Funktion ADRESSE gibt einen Text zurück, keine Referenz!
Die Funktion MEHRFACH.OPERATIONEN kann keinen Zellbereich als Argumente übernehmen, auch nicht wenn die Funktion als Matrix-Formel eingesetzt wird.
Beispiele:
Beispiel A: Nutzung des Assistenten
Hilfe Seiten:
https://help.libreoffice.org/latest/de/text/scalc/01/12060000.html
Wir wollen eine Tabelle anlegen, die die Quadrate und Kubikzahlen von {2, 3, 5, 7} berechnet
Der Screenshot zeigt die Verwendung des Assistenten aus ▸
Die Zelle B3 enthält die Formel =B1^B2. Das ist die Beispielberechnung. Sie enthält die "Variable" B1 für die Basis und die "Variable" B2 für den Exponenten.
Der Zielbereich hat den Exponenten im Zeilenbereich E2:F2 und die Basis im Spaltenbereich D3:D6.
- Markiere den Zielbereich inklusive die Kopfzeile wie im Screenshot gezeigt. Wenn wir fertig sind, zeigt die Zelle E6 den Wert 49 (=7^2) und die Zelle F5 den Wert 125 (=5^3).
- Wähle das Menü ▸ . Der unten gezeigten Dialog erscheint.
- Setze den Cursor in das Feld Formeln, klicke dann auf Zelle B3. Die Zelle wird zur Beispielberechnung. Die $-Zeichen zum absoluten Zellbezug werden automatisch gesetzt.
- Setze den Cursor in das Feld Zeile der Eingabezellen. Die Zahlen 2 und 3 im Zeilenbereich E2:F2 sind die Zahlen, die wir als Exponenten nehmen wollen. So wird unsere 'Zeile der Eingabezellen' zu der Zelle, die den Exponenten für die Formel =B1^B2 enthält. Klicke auf Zelle B2.
- Setze den Cursor in das Feld Spalte der Eingabezellen. Die Zahlen 2, 3, 5 und 7 im Spaltenbereich D3:D6 sind die Zahlen, die wir als Basis nehmen wollen. So wird unsere 'Spalte der Eingabezellen' zur Zelle, welche die Basis für unsere Formel =B1^B2 enthält. Klicke auf Zelle B1.
- Du bist fertig. Klicke auf OK.
Die Zelle E6 enthält jetzt die Formel =MEHRFACH.OPERATIONEN($B$3;$B$1;$D6;$B$2;E$2)
Beachte wie der Assistent die ‘‘‘$‘‘‘ für die absolute Adressierung gesetzt hat.
Die Referenzen $B$1, $B$2 und $B$3 auf die Beispielberechnung haben $ Zeichen für Zeile und Spalte, weil der Ort der Beispielkalkulation sich nicht ändert, wenn die Formel woanders hin gezogen wird.
Die Referenz auf die Zelle $D6 hat das ‘‘‘$‘‘‘ Zeichen vor der Spalte, weil sich die Spalte nicht ändert, wenn man die Formel nach rechts zieht. Aber die Zeile muss sich anpassen, wenn man die Formel nach unten zieht.
Die Referenz auf die Zelle E$2 hat das ‘‘‘$‘‘‘ Zeichen vor der Spalte, weil sich die Zeile nicht ändert, wenn man die Formel nach unten zieht. Aber die Spalte muss sich anpassen, wenn man die Formel nach rechts zieht.
Beispiel B: Die Formel manuell angeben
Wir nutzen die selben Daten wie in Beispiel A. Anstatt den Assistenten zu nutzen, geben wir in Zelle E3 eine passende Formel ein und ziehen dann die Formel nach rechts unten so dass sie den ganzen Bereich E3:F6 umfasst.
Wir wollen jetzt den Zellbereich E2:F2 als Exponenten nutzen. Daher müssen wir sie mit Zelle B2 aus der Beispielrechnung in Verbindung bringen. Und wir müssen den Bereich D3:D6 mit der Zelle B1 aus der Beispielrechnung als Basis in Verbindung bringen.
Bei der Eingabe der Formel in E3 muss die Zeile 2 zum Runterziehen fixiert werden. Die Spalte D muss zum Rechts ziehen fixiert werden. Die Referenz auf E$2 wird beim Verschieben der Formel einen Bereich auf Zeile 2 überqueren. Die Referenz D$3 wird beim Verschieben einen Bereich auf Spalte D überqueren.
Wir können nun in Zelle E3 die Formel =MEHRFACH.OPERATIONEN($B$3; $B$1;$D3 ; $B$2;E$2) einfügen.
Wir können auch die Formel =MEHRFACH.OPERATIONEN($B$3; $B$2;E$2 ; $B$1;$D3) verwenden.
Probier es aus!
Entgegen der Benennung in der Syntax ist die Reihenfolge der 'Zeile' oder 'Spalte' egal. Wir müssen nur sicherstellen, dass die Zeilen- und Spalten-Bereiche mit der Zelle aus der Beispielberechnung in Verbindung stehen, die passen. In der obigen Formel befinden sich Leerzeichen zur Begrenzung der Paare.
Beispiel C: Verwendung einer "Variablen", die nicht in der Ergebniszelle ist
Wir können eine Zelle der Beispielberechnung verwenden, die nicht direkt in der Formel als Ergebniszelle genutzt wird. Im folgenden Beispiel hat die Formel =B7-B10 in der Ergebniszelle B11 keinen direkten Bezug zu Zelle B5. Die Funktion MEHRFACH.OPERATIONEN nutzt den ganzen Zellbaum welcher zur Berechnung des Wertes der Ergebniszelle genutzt wird.
Der Screenshot zeigt die genutzten Formeln in blau. Der Screenshot wurde aus der Datei Media:MultipleOperationExampleWithVariableNotInResult.ods erzeugt. (das Beispiel ist eine typische Schulbuch-Übung).
Ähnliche LibreOffice Funktionen:
ODF Standard:
Kapitel 6.14.10 MEHRFACH.OPERATIONEN, Teil 2, ODF 1.2
Betroffene (oder ähnliche) EXCEL-Funktionen:
Es gibt keine dierekte Entsprechung in EXCEL.
Ähnliche Funktionalität gibt es unter “Berechnen von mehreren Ergebnissen mit einer Datentabelle”.
ToDo: Wie muss die Tabelle aufgebaut sein, damit ein Export als "Datentabelle" möglich ist? Die Hilfe gibt einige Hinweise, ist aber nicht eindeutig.