Dokumentation/Calc Funktionen/NBW

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/NPV and the translation is 100% complete.
    Other languages:

    Funktionsname:

    NBW

    Kategorie:

    Finanzmathematik

    Zusammenfassung:

    Berechnet den Kapitalwert (manchmal auch Nettobarwert genannt) aus einer Reihe von zukünftigen periodischen Cash Flows. Die Analyse des Kapitalwertes wird finanztechnisch oft zur Ermittlung der wahrscheinlichen Wirtschaftlichkeit eines Projektes oder Investition genutzt.

    NBW setzt voraus, dass die Cash Flows regelmäßig am Ende gleich langer Perioden stattfinden. Cash Flow Werte können zwischen den Perioden variieren und stellen entweder Einzahlungen (positiv) oder Auszahlungen (negativ) dar. Jeder Cash Flow ist durch einen konstanten Diskontsatz abgezinst auf seinen Barwert und die Summe dieser Barwerte wird zurückgegeben.

    Syntax:

    NBW(Diskontsatz; Wert 1[; Wert 2[; … [; Wert 254]]])

    Rückgabewerte:

    Gibt den Barwert der angegebenen Reihe von Cash Flows als Dezimalzahl oder als Referenz auf eine Zelle, die diese Dezimalzahl enthält zurück. Dabei wird der angegebene Diskontsatz verwendet. Dieser Rückgabewert ist in der gleichen Währung wie die angegebenen Cash Flows und standardmäßig in der lokalisierungsabhängigen Währung formatiert.

    Argumente:

    Diskontsatz ist der periodische Diskontsatz als Dezimalzahl (ausgedrückt als Prozentsatz wie 2,5 % oder als gebrochene Dezimalzahl wie 0,025) oder als Refernz auf eine Zelle die die Dezimalzahl enthält. Typische Perioden sind monatlich, vierteljährlich, halbjährlich oder jährlich, die Länge wird aber nicht an NBW übergeben Es ist wichtig, dass der Diskontsatz an die wahre Länge zwischen den Cash Flows angepasst ist.

    Zahl 1, Zahl 2, ... , Zahl 255 geben das Set aus Dezimalzahlen an, aus denen das Produkt errechnet werden. Jedes Argument kann eine der folgenden Formen annehmen:

    • Eine Dezimalzahl oder ein Ausdruck, der einer Dezimalzahl entspricht.
    • Eine Referenz auf eine einzelne Zelle, die eine Dezimalzahl enthält.
    • Eine einfache Referenz auf einen Zellbereich, der Dezimalzahlen enthält (z. Bsp. A1:B9).
    • Der Name eines benannten Zellbereiches, der Dezimalzahlen enthält.
    • Der Name eines Datenbankbereiches, deren Zellen Dezimalzahlen enthalten.
    • Eine Aufzählung aus Dezimalzahlen (z. Bsp. {1,1; 2,2; 3,3; 4,4})

    Die folgenden Punkte sollten mit Blick auf die Cash Flows beachtet werden.

    • Jeder Cash Flow sollte in der selben Währung angegeben sein.
    • Jeder Cash Flow kann positiv (Einzahlung), Null oder negativ (Auszahlung) sein.
    • Ein Cash Flow sollte für jede Periode während der Laufzeit des Projektes oder der Investition gezahlt werden. Der Wert 0 sollte für jede Periode mit einem Cash Flow von 0 angegeben werden - falls dieser fehlt, werden die folgenden Cash Flows falsch diskontiert.
    • NBW erwartet, dass die Cash Flows in chronologischer Folge kommen und berechnet sie in der angegebenen Reihenfolge - Zahl 1, Zahl 2 und so weiter. Bereichsreferenzen und Aufzählungen werden zeilenweise augewertet, beginnend oben links.
    • Die Reihenfolge der Cash Flows für NBW ist wichtig. Zum Beispiel gibt die Formel =NBW({10 %, 100, 200, 300}) 481,59 Währungseinheiten zurück, während die Formel =NBW({10 %, 300, 200, 100}) 513,15 Währungseinheiten zurückgibt.
    • Obwohl NBW bis zu 254 Zahl n Argumente akzeptiert, kann jedes Argument Zellbereiche angeben. Damit kann die Anzahl der verrechneten Cash Flows (theoretisch) größer als 254 sein.

    Die folgenden Fälle (inklusive Fehler) können auftreten:

    • Falls der Diskontsatz nicht numerisch ist, dann gibt NBW einen #WERT!-Fehler zurück.
    • Falls der Diskontsatz auf -100 % oder -1 gesetzt wird, dann gibt NBW einen #ZAHL!-Fehler zurück.
    • Zellen mit dem Zahl n-Argument, die leer sind oder Text enthalten, werden ignoriert.
    • Falls eine Zahl n nicht einer der obigen Formen entspricht, dann meldet NBW einen parameter list error (Fehler:504).

    Zusätzliche Informationen:

    • Der Diskontsatz zinst jede Periode auf und so ist die Formel zur Funktion NBW:
    [math]\displaystyle{ \text{NPW}~=~\sum_{i=1}^{n}\frac{ZW_{i}}{(1+r)^{i}} }[/math]
    wobei:
    n = der Gesamtzahl der angegebenen Cash Flows
    ZWi = Wert des iten Cash Flow
    r = periodischer Diskontsatz
    • Falls das Ergebnis positiv ist (und die Eingabedaten sonst soweit richtig sind), dann sollten die vom Projekt oder der Investition generierten Einzahlungen die gegenüberstehenden Auszahlungen übersteigen.
    • Bitte beachten Sie, wenn das Projekt oder die Investition nicht nur Cash Flows am Ende der Laufzeit hat, sondern auch am Anfang der Laufzeit einen Cash Flow für die Deckung der Startkosten benötigt. Dies kann in einer von zwei Möglichkeiten passieren:
    1. Eine einfache Lösung wäre es, Angaben zum Start-Cash Flow aus der Liste der Cash Flows in den Argumenten für NBW zu streichen. Danach addieren Sie einfach den Start-Cash Flow (der keine Abzinsung benötigt) zum Rückgabewert von NBW dazu, um einen kompletten Kapitalwert zu erhalten.
    2. Eine andere Methode wäre es, den Start-Cash Flow für NBW als ersten Wert in der Liste der Cash Flows anzugeben. Der Rückgabewert sollte dann mit dem Faktor (1 + Diskontsatz) multipliziert werden um die Überdiskontierung für alle Cash Flows zu kompensieren.
    Beispiele zu diesen zwei Methoden sind in den #Beispiele: angegeben.
    • Es ist ausserdem möglich, NBW zu verwenden, wenn die Cash Flows am Anfang jeder Periode stattfinden. In diesem Fall sollte der Rückgabewert wieder mit dem Faktor (1 + Diskontsatz) multipliziert werden, um die Überdiskontierung für alle Cash Flows zu kompensieren. Ein Beispiel dieser Methode ist bei den #Beispiele: angegeben.
    • Um den Kapitalwert für eine Reihe nicht periodischer Cash Flows zu berechnen wird die Funktion XKAPITALWERT verwendet.
    • NBW ist ähnlich der Funktion IKV – bei einer gegebenen Reihe von Cash Flows ist der Kapitalwert (IKV) der Diskontsatz, für den die Funktion NBW 0 zurückgibt.
    • Für mehr Hintergrundinformationen über den Kapitalwert, siehe Wiki unter Kapitalwert.

    Beispiele:

    Die folgende Tabelle zeigt die Daten aus dem ersten unten stehenden Beispiel.

    Beispieldaten zur Funktion NBW
    A B C D E
    1 Diskontsatz 2,5%
    2
    3 Q1 Q2 Q3 Q4
    4 Year 1 100 150 200 250
    5 Year 2 300 350 400 450
    6 Year 3 500 550 600 650

    Beachten Sie bitte, dass die Formatierung der Ergebnisse in den folgenden Beispielen die Lokaliserung für English (USA) nutzen könnte.

    Formel Beschreibung Ergebnis
    =NBW(B1; B4:E6)

    wobei die Zellen B1 und B4:E6 die Werte aus der obigen Tabelle enthalten.

    Hier berechnet die Funktion den Kapitalwert für zwölf vierteljährliche Cash Flows mit einem konstanten Diskontsatz in Höhe von 2,5 % pro Quartal. Die Funktion gibt den Wert 3.695,96 Währungseinheiten zurück. Beachten Sie, dass die Formeln =NBW(B1; B4:E4; B5:E5; B6:E6) und =NBW(B1; B4; C4; D4; E4; B5; C5; D5; E5; B6; C6; D6; E6) das selbe Ergebnis liefern.

    $3.695,96
    =NBW(0,0875; {1000; 2000; 3000}) - 4500

    Ein vorgeschlagenes Projekt hat anfängliche Startkosten in Höhe von 4500 Währungseinheiten und liefert Cash Flows in Höhe von 1000, 2000 und 3000 Währungseinheiten am Ende der drei Jahren des Projektes. Der Kapitalwert für diese Cash Flows wird mit dem Diskontsatz von 8,75 % berechnet.

    Hier gibt die Formel die Startkosten nicht als Argument für die Funktion NBW an, sondern addiert die Kosten als nicht diskontierten Cash Flow zum Ergebnis dazu. Die Formel gibt 443,21 Währungseinheiten zurück und dieser positive Wert zeigt an, dass das Projekt profitabel sein sollte (vorausgesetzt, die zugrundeliegenden Annahmen stimmen).

    $443,21
    =1,0875*NBW(0,0875; {−4500; 1000; 2000; 3000})

    Dieses Beispiel berechnet den Kapitalwert für exakt das selbe Projekt und Cash Flows aus dem vorherigen Beispiel.

    Hier gibt die Formel die Startkosten als Argument an die Funktion NBW und damit wird der Rückgabewert mit dem Faktor 1,0875 (1 + Diskontsatz) multipliziert, um die diskontierten Werte aus den Cash Flows zu korrigieren. Die Formel gibt wieder 443,21 Währungseinheiten zurück.

    $443,21
    =NBW(8,75%; −1000; 2500; 3500) - 4000

    Ein vorgeschlagenes Projekt hat anfängliche Startkosten in Höhe von 4000 Währungseinheiten und liefert Cash Flows in Höhe von −1000, 2500 und 3500 Währungseinheiten am Ende der drei Jahren des Projektes. Der Kapitalwert für diese Cash Flows wird mit dem Diskontsatz von 8,75 % berechnet.

    Hier gibt die Formel die Startkosten nicht als Argument für die Funktion NBW an, sondern addiert die Kosten als nicht diskontierten Cash Flow zum Ergebnis dazu. Die Formel gibt −84,33 Währungseinheiten zurück und dieser negative Wert zeigt an, dass das Projekt unprofitabel sein sollte (vorausgesetzt, die zugrundeliegenden Annahmen stimmen).

    −$84,33
    =1,0875*NBW(8,75%; −4000; −1000; 2500; 3500)

    Dieses Beispiel berechnet den Kapitalwert für exakt das selbe Projekt und Cash Flows aus dem vorherigen Beispiel.

    Hier gibt die Formel die Startkosten als Argument an die Funktion NBW und damit wird der Rückgabewert mit dem Faktor 1,0875 (1 + Diskontsatz) multipliziert, um die diskontierten Werte aus den Cash Flows zu korrigieren. Die Formel gibt wieder −84,33 Währungseinheiten zurück.

    −$84,33
    =1,1*NBW(10%; −700; 200; 300; 400)

    Ein vorgeschlagenes Projekt liefert Cash Flows in Höhe von −700, 200, 300 und 400 Währungseinheiten am Beginn jedes der vier Jahre des Projektes. Der Kapitalwert aus diesen Cash Flows wird mit einem Diskontsatz von 10 % berechnet.

    Hier gibt die Formel alle Cash Flows als Argument für die Funktion NBW an und multipliziert den Rückgabewert mit dem Faktor 1,1 (1 + Diskontsatz) um die diskontierten Werte zu korrigieren. Die Formel gibt 30,28 Währungseinheiten zurück.

    $30,28

    Ähnliche LibreOffice Funktionen:

    IKV

    BW

    XKAPITALWERT

    ODF Standard:

    Kapitel 6.12.30, Teil 2.

    Betroffene (oder ähnliche) EXCEL-Funktionen:

    NPV