Documentación/Funciones de Calc/SUBTOTALES

This page is a translated version of the page Documentation/Calc Functions/SUBTOTAL and the translation is 25% complete.

Outdated translations are marked like this.

TDF LibreOffice en español Document Liberation Project Blogs comunitarios Weblate Nextcloud Redmine Preguntas y respuestas Donar

Other languages:

Inicio Funciones Calc | Lista de funciones | Abreviaturas

Nombre de la función:

SUBTOTALES

Categoría:

Matemáticas

Resumen:

Calcula un subtotal utilizando una función matemática seleccionada. SUBTOTALES está diseñado para usarse con una tabla simple de datos, que ocupa un área de hoja de cálculo rectangular, con los datos organizados verticalmente en columnas.

Si el rango de datos procesado por SUBTOTALES ya contiene subtotales, estos se ignoran para evitar contar los valores dos veces. Si se filtra cualquier fila dentro del rango de datos, SUBTOTALES ignora sus datos. SUBTOTALES puede incluir o excluir opcionalmente datos de filas dentro del rango de datos que se han ocultado manualmente.

Nota:

Nota:
Calc proporciona una alternativa poderosa y más completa a la función SUBTOTALES, a la que se accede seleccionando Datos ▸ Subtotales en la barra de menú. Puede encontrar más detalles en la ayuda del sistema buscando "herramienta de subtotales".

Sintaxis:

SUBTOTALES(Function; Range)

Devuelve:

Devuelve un número que es el subtotal requerido. Consulte la página que describe la función de subtotales seleccionada, para obtener más información sobre la naturaleza del valor devuelto en cada caso.

Argumentos:

Función es un número entero, o una referencia a una celda que contiene ese número entero, que es un índice que indica qué función debe usarse para calcular el subtotal y si las filas ocultas deben incluirse o excluirse. Función debe estar en el rango [1, 11] o en el rango [101, 111], con el significado de cada valor posible dado en la siguiente tabla.

Asignación de valores de argumento de función
Incluir filas ocultas	Excluir filas ocultas	Función subtotales
1	101	PROMEDIO
2	102	CONTAR
3	103	CONTARA
4	104	MAX
5	105	MIN
6	106	PRODUCTO
7	107	DESVEST
8	108	DESVESTP
9	109	SUMA
10	110	VAR
11	111	VARP

Rango da el conjunto de números reales para los cuales se calculará el subtotal. Rango toma normalmente una de las siguientes formas:

Una simple referencia a un rango de celdas, que contiene números reales (por ejemplo, A1:A25).
El nombre de un rango con nombre, que comprende celdas que contienen números reales.
El nombre de un rango de base de datos, que comprende celdas que contienen números reales.

Además, las siguientes formas para el argumento Rango no provocan un error, pero no es probable que sean particularmente útiles:

Un número real, o una expresión que se evalúa como un número real. Por ejemplo, la fórmula =SUBTOTALES(1; 3) devuelve 3.
Una referencia a una sola celda, que contiene un número real. Por ejemplo, si la celda D1 contiene el número 123, la fórmula =SUBTOTALES(1; D1) devuelve 123.
Una matriz en línea de números reales (como {1.1, 2.2, 3.3, 4.4}). Por ejemplo, la fórmula =SUBTOTALES(6, {1,2,3,4,5}) devuelve 120.

A simple reference to a cell range containing real numbers (for example, A1:A25).
The name of a named range, comprising cells containing real numbers.
The name of a database range, comprising cells containing real numbers.

In addition, the following forms for the Range argument do not cause an error but are not likely to be particularly useful:

A real number, or an expression that evaluates to a real number. For example, the formula =SUBTOTALES(1; 3) returns 3.
A reference to a single cell containing a real number. For example, if cell D1 contains the number 123, the formula =SUBTOTALES(1; D1) returns 123.
An inline array of real numbers (such as {1,1; 2,2; 3,3; 4,4}). For example, the formula =SUBTOTALES(6; {1; 2; 3; 4; 5}) returns 120.

Puede encontrar las siguientes condiciones (errores incluidos):

Si Función no es numérica, SUBTOTALES mostrará el error #¡VALOR!.
Si Función no es un valor entero, SUBTOTALES lo truncará a un entero.
Si Función no está en el rango [1, 11] ni en el rango [101, 111], SUBTOTALES mostrará un error de argumento no válido (Err: 502).

If Function in non-numeric, then SUBTOTALES reports a #¡VALOR! error.
If Function is a non-integer value, then SUBTOTALES truncates it to an integer.
If Function is neither in the range [1, 11] nor in the range [101, 111], then SUBTOTALES reports an invalid argument error (Err:502).

Detalles adicionales:

* La sintaxis proporcionada en la sección #Sintaxis: anterior está alineada con la del Asistente de funciones de Calc. Sin embargo, es posible proporcionar varios rangos a SUBTOTALES, pasando el segundo rango como tercer argumento, el tercer rango como cuarto argumento, y así sucesivamente. Lo cual proporciona interoperabilidad con Microsoft Excel.
* Ocultar columnas no tiene impacto en los resultados producidos por la función SUBTOTALES.
* Consulte las páginas individuales, para obtener más información sobre cada una de las once funciones posibles de subtotal.

Ejemplos:

A una clase de 12 estudiantes se le puso una prueba de módulo y sus puntuaciones se introdujeron en una hoja de cálculo como se muestra en la siguiente tabla.

	A	B
1	Estudiante	Puntuación
2	Ann	2
3	Brian	10
4	Edward	8
5	James	*
6	Jeffrey	5
7	Linette	10
8	Monica	8
9	Ray	3
10	Robert	4
11	Tamara	6
12	Victoria	7
13	William	9

Los nombres de los estudiantes se enumeran en orden alfabético en las celdas A2:A13 y sus puntuaciones se enumeran en las celdas B2:B13. El asterisco (*) en la celda B5 indica que James estuvo ausente y no pudo realizar la prueba. Los siguientes ejemplos se basan en los datos de la tabla anterior.

Fórmula	Descripción	Devuelve
=SUBTOTALES(2; B2:B13)	Aquí, la función usa la función CONTAR de Calc, para contar el número de puntuaciones (CONTAR ignora las cadenas, por lo que se ignora el asterisco en la celda B5). Como no hay filas ocultas en los datos, la fórmula `=SUBTOTALES(102; B2:B13)` devuelve el mismo valor.	11
=SUBTOTALES(3; B2:B13)	Aquí, la función usa la función CONTARA de Calc, para contar el número de puntuaciones (CONTARA incluye cadenas, por lo que se cuenta el asterisco en la celda B5). Como no hay filas ocultas en los datos, la fórmula `=SUBTOTALES(103; B2:B13)` devuelve el mismo valor.	12
=SUBTOTALES(4; B2:B13)	Aquí, la función utiliza la función MAX de Calc, para determinar el valor de puntuación máxima. Como no hay filas ocultas en los datos, la fórmula `=SUBTOTALES(104; B2:B13)` devuelve el mismo valor.	10
=SUBTOTALES(5; B2:B13)	Aquí, la función utiliza la función MIN de Calc, para determinar el valor de puntuación mínima. Como no hay filas ocultas en los datos, la fórmula `=SUBTOTALES(105; B2:B13)` devuelve el mismo valor.	2

Para los siguientes ejemplos, se usa la misma tabla de datos, pero la fila 2 está oculta (haciendo clic con el botón derecho en el número de fila y seleccionando Ocultar filas en el menú contextual).

Fórmula	Descripción	Devuelve
=SUBTOTALES(2; B2:B13)	Aquí, la función usa la función CONTAR de Calc, para contar el número de puntuaciones (CONTAR ignora las cadenas, por lo que se ignora el asterisco en la celda B5). En este caso, SUBTOTALES incluye valores en filas ocultas.	11
=SUBTOTALES(102; B2:B13)	Aquí, la función usa la función CONTAR de Calc, para contar el número de puntuaciones (CONTAR ignora las cadenas, por lo que se ignora el asterisco en la celda B5). En este caso, SUBTOTALES ignora los valores en las filas ocultas.	10
=SUBTOTALES(5; B2:B13)	Aquí, la función utiliza la función MIN de Calc, para determinar el valor de puntuación mínima. En este caso, SUBTOTALES incluye valores en filas ocultas.	2
=SUBTOTALES(105; B2:B13)	Aquí, la función utiliza la función MIN de Calc, para determinar el valor de puntuación mínima. En este caso, SUBTOTALES ignora los valores en las filas ocultas.	3

Para los ejemplos finales, la tabla de datos vuelve a su estado original, mostrando la fila 2 (seleccionando los números de fila para las filas 1 y 3, haciendo clic con el botón derecho en cualquiera de los números de fila seleccionados y seleccionando Mostrar filas del menú contextual). Luego, se aplican los autofiltros, haciendo clic con el botón izquierdo dentro del rango de celdas A1: B13 y seleccionando Datos ▸ AutoFiltros en la barra de menú. Finalmente, presione la flecha hacia abajo en el encabezado de la columna Puntuación, desmarque la casilla de verificación junto al número 10 cerca de la parte inferior del cuadro de diálogo y presione el botón Aceptar. Las filas 3 y 7 aparecerán ahora filtradas.

Fórmula	Descripción	Devuelve
=SUBTOTALES(2; B2:B13)	Aquí, la función usa la función CONTAR de Calc, para contar el número de puntuaciones (CONTAR ignora las cadenas, por lo que se ignora el asterisco en la celda B5). Como no hay filas ocultas en los datos, la fórmula `=SUBTOTALES(102; B2:B13)` devuelve el mismo valor.	9
=SUBTOTALES(3; B2:B13)	Aquí, la función usa la función CONTARA de Calc, para contar el número de puntuaciones (CONTARA incluye cadenas, por lo que se cuenta el asterisco en la celda B5). Como no hay filas ocultas en los datos, la fórmula `=SUBTOTALES(103; B2:B13)` devuelve el mismo valor.	10
=SUBTOTALES(4; B2:B13)	Aquí, la función utiliza la función MAX de Calc, para determinar el valor de puntuación máxima. Como no hay filas ocultas en los datos, la fórmula `=SUBTOTALES(104; B2:B13)` devuelve el mismo valor.	9

Funciones de LibreOffice relacionadas:

Norma ODF:

Sección 6.16.60, parte 2

Funciones equivalentes de Excel:

SUBTOTAL