Dokumentation/Calc Funktionen/TEILERGEBNIS

This page is a translated version of the page Documentation/Calc Functions/SUBTOTAL and the translation is 100% complete.

TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende

Other languages:

Calc Funktionen Start | Liste der Funktionen | Abkürzungen

Funktionsname:

TEILERGEBNIS

Kategorie:

Mathematisch

Zusammenfassung:

Berechnet ein Teilergebnis mittels einer ausgewählten mathematischen Funktion. TEILERGEBNIS ist auf eine einfache rechteckige Tabelle ausgelegt, wobei die Daten in senkrechten Spalten organisiert sind.

Falls der Zellbereich für TEILERGEBNIS bereits Teilergebnisse enthält, werden diese ignoriert, um Daten nicht doppelt zu verrechnen. Falls eine Zeile ausgeblendet wird, werden die Daten von TEILERGEBNIS ignoriert. TEILERGEBNIS kann optional Daten innerhalb des manuell ausgeblendeten Bereiches einschliessen oder ausschliessen.

Anmerkung:
Calc bietet eine mächtige und verständlichere Alternative zu TEILERGEBNIS unter Daten ▸ Teilergebnisse... in der Menüzeile. Genauere Einzelheiten finden sich im Hilfesystem unter "Teilergebnisse verwenden".

Syntax:

TEILERGEBNIS(Funktion; Bereich)

Rückgabewerte:

Gibt das gewünschte Teilergebnis als Zahl zurück - Siehe die Seite, die die gewählte Funktion für mehr Einzelheiten über die Natur des zurückgegebenen Werts in jedem Fall beschreibt.

Argumente:

Funktion ist eine Ganzzahl oder eine Referenz auf eine Zelle, die diese Ganzzahl enthält. Diese Ganzzahl ist ein Index, der anzeigt, welche Funktion für das Teilergebnis angewendet werden soll und ob ausgeblendete Zeilen ein- oder ausgeschlossen werden sollen. Funktion muss entweder im Bereich [1, 11] oder im Bereich [101, 111] liegen. Die Bedeutung jedes möglichen Wertes gibt die folgende Tabelle.

Zuordnung der Argumente zu den Funktionen
ausgeblendete Zeilen einschliessen	ausgeblendete Zeilen ausschliessen	Teilergebnis Funktion
1	101	MITTELWERT
2	102	ANZAHL
3	103	ANZAHL2
4	104	MAX
5	105	MIN
6	106	PRODUKT
7	107	STABW
8	108	STABWN
9	109	SUMME
10	110	VARIANZ
11	111	VARIANZEN

Bereich gibt das Set aus Dezimalzahlen, woraus das Teilergebnis berechnet werden soll. Bereich hat üblicherweise eine der folgenden Formen:

Eine einfache Referenz auf einen Zellenbereich (zum Beispiel A1:A25).
Der Name eines benannten Zellbereiches, der die Dezimalzahlen beinhaltet.
Der Name eines Datenbankbereichs, der die Dezimalzahlen beinhaltet.

Zusätzlich erzeugen die folgenden Formen des Bereiches keinen Fehler, sind aber nicht besonders hilfreich.

Eine Dezimalzahl oder ein Ausdruck, der eine Dezimalzahl darstellt. Zum Beispiel gibt die Formel =TEILERGEBNIS(1; 3) 3 zurück.
Eine Referenz auf eine einzelne Zelle, die eine Dezimalzahl beinhaltet. Wenn zum Beispiel die Zelle D1 die Zahl 123 beinhaltet, liefert die Formel =TEILERGEBNIS(1; D1) 123 zurück.
Eine Aufzählung von Dezimalzahlen (wie z.Bsp. {1,1; 2,2; 3,3; 4,4}). Die Formel =TEILERGEBNIS(6; {1; 2; 3; 4; 5}) gibt zum Beispiel 120 zurück.

Die folgenden Fälle (inklusive Fehler) können auftreten:

Falls die Funktion nicht numerisch ist, meldet TEILERGEBNIS einen #WERT! Fehler.
Falls Funktion ein nicht ganzzahliger Wert ist, verkürzt ihn TEILERGEBNIS auf eine Ganzzahl.
Falls die Funktion weder im Bereich [1, 11] noch im Bereich [101, 111] liegt, dann meldet TEILERGEBNIS einen invalid argument error (Fehler:502).

Zusätzliche Informationen:

Die Syntax im obigen Abschnitt #Syntax: ist im Calc Funktionsassistenten hinterlegt. Trotzdem können mehrere Bereiche an TEILERGEBNIS übergeben werden, indem der zweite Bereich als drittes Argument angegeben wird. Der dritte Bereich ist dann das vierte Argument und so weiter. Dies dient der Kompatibilität zu Microsoft EXCEL.
Ausgeblendete Spalten haben keinen Einfluß auf das Ergebnis der Funktion TEILERGEBNIS.
Siehe die individuellen Seiten für mehr Einzelheiten über jede der elf möglichen Teilergebnis Funktionen.

Beispiele:

Einer Klasse mit 12 Schülern wurde ein Test vorgesetzt. Ihre Ergebnisse wurden in einer Tabelle wie folgt erfasst.

	A	B
1	Schüler	Ergebnis
2	Ann	2
3	Brian	10
4	Edward	8
5	James	*
6	Jeffrey	5
7	Linette	10
8	Monica	8
9	Ray	3
10	Robert	4
11	Tamara	6
12	Victoria	7
13	William	9

Die Namen der Schüler sind in alphabetischer Reihenfolge in den Zellen B2:B13 erfasst. Der Asterisk (*) in Zelle B5 zeigt an, dass James nicht da war und am Test nicht teilnehmen konnte. Die folgenden Beispiele basieren auf den Daten in der obigen Tabelle.

Formel	Beschreibung	Ergebnis
=TEILERGEBNIS(2; B2:B13)	Verwende die Funktion ANZAHL, um die Anzahl der Ergebnisse zu zählen. ANZAHL ignoriert Texte und so wird der Asterisk in Zelle B5 ignoriert. Da es keine ausgeblendeten Zeilen in den Daten gibt, gibt die Formel `=TEILERGEBNIS(102; B2:B13)` den gleichen Wert zurück.	11
=TEILERGEBNIS(3; B2:B13)	Verwende die Funktion ANZAHL2, um die Anzahl der Ergebnisse zu zählen. ANZAHL2 zählt Texte mit und so wird der Asterisk in Zelle B5 gezählt. Da es keine ausgeblendeten Zeilen in den Daten gibt, gibt die Formel `=TEILERGEBNIS(103; B2:B13)` den gleichen Wert zurück.	12
=TEILERGEBNIS(4; B2:B13)	Verwende die Funktion MAX, um das beste Ergebnis zu bestimmen. Da es keine ausgeblendeten Zeilen in den Daten gibt, gibt die Formel `=TEILERGEBNIS(104; B2:B13)` den gleichen Wert zurück.	10
=TEILERGEBNIS(5; B2:B13)	Verwende die Funktion MIN, um das schlechteste Ergebnis zu bestimmen. Da es keine ausgeblendeten Zeilen in den Daten gibt, gibt die Formel `=TEILERGEBNIS(105; B2:B13)` den gleichen Wert zurück.	2

Für die folgenden Beispiele wird die selbe Tabelle verwendet, aber Zeile 2 wird ausgeblendet (durch einen Rechts-Klick auf die Zeilennummer und auswählen von Zeilen ausblenden aus dem Kontext-Menü).

Formel	Beschreibung	Ergebnis
=TEILERGEBNIS(2; B2:B13)	Verwende die Funktion ANZAHL, um die Anzahl der Ergebnisse zu zählen. ANZAHL ignoriert Texte und so wird der Asterisk in Zelle B5 ignoriert. In diesem Fall schliesst TEILERGEBNIS die Werte in den ausgeblendeten Zeilen mit ein.	11
=TEILERGEBNIS(102; B2:B13)	Verwende die Funktion ANZAHL, um die Anzahl der Ergebnisse zu zählen. ANZAHL ignoriert Texte und so wird der Asterisk in Zelle B5 ignoriert. In diesem Fall ignoriert TEILERGEBNIS die Werte in den ausgeblendeten Zeilen.	10
=TEILERGEBNIS(5; B2:B13)	Verwende die Funktion MIN, um das schlechteste Ergebnis zu bestimmen. In diesem Fall schliesst TEILERGEBNIS die Werte in den ausgeblendeten Zeilen mit ein.	2
=TEILERGEBNIS(105; B2:B13)	Verwende die Funktion MIN, um das schlechteste Ergebnis zu bestimmen. In diesem Fall ignoriert TEILERGEBNIS die Werte in den ausgeblendeten Zeilen.	3

Für die abschliessende Beispiele wird die Tabelle wieder in ihren ursprünglichen Zustand zurückversetzt, indem Zeile 2 wieder eingeblendet wird (durch Auswählen der Zeilennummer für Zeile 1 und 3, einem Rechts-Klick auf eine der ausgewählten Zeilennummern und Auswahl von Zeilen einblenden aus dem Kontext-Menü). Dann wird AutoFilter durch einen Links-Klick auf den Zellbereich A1:B1 und Auswahl von Daten ▸ AutoFilter in der Menü-Zeile. Drücken Sie bitte abschliessend den Pfeil nach unten im Spaltenkopf Ergebnis, nehmen Sie das Häckchen neben der Nummer 10 unten im Dialog und drücken den Knopf OK. Zeilen 3 und 10 sind nun ausgelendet.

Formel	Beschreibung	Ergebnis
=TEILERGEBNIS(2; B2:B13)	Verwende die Funktion ANZAHL, um die Anzahl der Ergebnisse zu zählen. ANZAHL ignoriert Texte und so wird der Asterisk in Zelle B5 ignoriert. Da es keine ausgeblendeten Zeilen in den Daten gibt, gibt die Formel `=TEILERGEBNIS(102; B2:B13)` den gleichen Wert zurück.	9
=TEILERGEBNIS(3; B2:B13)	Verwende die Funktion ANZAHL2, um die Anzahl der Ergebnisse zu zählen. ANZAHL2 zählt Texte mit und so wird der Asterisk in Zelle B5 gezählt. Da es keine ausgeblendeten Zeilen in den Daten gibt, gibt die Formel `=TEILERGEBNIS(103; B2:B13)` den gleichen Wert zurück.	10
=TEILERGEBNIS(4; B2:B13)	Verwende die Funktion MAX, um das beste Ergebnis zu bestimmen. Da es keine ausgeblendeten Zeilen in den Daten gibt, gibt die Formel `=TEILERGEBNIS(104; B2:B13)` den gleichen Wert zurück.	9

ODF Standard:

Kapitel 6.16.60, Teil 2.

Betroffene (oder ähnliche) EXCEL-Funktionen:

SUBTOTAL