Documentatie/Calc-functies/SUBTOTAAL
TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren
Functienaam:
SUBTOTAAL
Categorie:
Wiskundig
Samenvatting:
Berekent een subtotaal met behulp van een geselecteerde wiskundige functie. SUBTOTAAL is bedoeld voor gebruik met een eenvoudige gegevenstabel die een rechthoekig werkbladgebied beslaat, waarbij de gegevens verticaal in kolommen zijn gerangschikt.
Als het door SUBTOTAAL verwerkte gegevensbereik al subtotalen bevat, worden deze genegeerd om te voorkomen dat waarden dubbel worden geteld. Als een rij binnen het gegevensbereik wordt uitgefilterd, worden de gegevens ervan genegeerd door SUBTOTAAL. SUBTOTAAL kan optioneel gegevens opnemen of uitsluiten van rijen binnen het gegevensbereik die handmatig zijn verborgen.
 |
NB:
|
Syntaxis:
SUBTOTAAL(Functie; Bereik)
Retourneert:
Retourneert een getal dat het vereiste subtotaal is - zie de pagina in de Help die de geselecteerde subtotaalfunctie beschrijft voor meer details over de aard van de geretourneerde waarde in elk geval.
Argumenten:
Functie is een geheel getal of een verwijzing naar een cel die dat getal bevat, dat wil zeggen een index die aangeeft welke functie moet worden gebruikt voor het berekenen van het subtotaal en of verborgen rijen moeten worden opgenomen of uitgesloten. Functie moet ofwel in het bereik [1, 11] of in het bereik [101, 111] liggen, met de betekenis van elke mogelijke waarde in de volgende tabel.
| Inclusief verborgen rijen | Exclusief verborgen rijen | Subtotaal functie |
|---|---|---|
| 1 | 101 | GEMIDDELDE |
| 2 | 102 | AANTAL |
| 3 | 103 | AANTALARG |
| 4 | 104 | MAX |
| 5 | 105 | MIN |
| 6 | 106 | PRODUCT |
| 7 | 107 | STDEV |
| 8 | 108 | STDEVP |
| 9 | 109 | SOM |
| 10 | 110 | VAR |
| 11 | 111 | VARP |
Bereik geeft de reeks reële getallen waarvoor het subtotaal moet worden berekend. Bereik zal gewoonlijk één van de volgende vormen aannemen:
- Een eenvoudige verwijzing naar een celbereik dat reële getallen bevat (bijvoorbeeld A1:A25).
- De naam van een benoemd bereik, bestaande uit cellen die reële getallen bevatten.
- De naam van een databasebereik, bestaande uit cellen die reële getallen bevatten.
Bovendien veroorzaken de volgende vormen voor het argument Bereik geen fout, maar zijn ze waarschijnlijk niet bijzonder nuttig:
- Een reëel getal of een uitdrukking die resulteert in een reëel getal. De formule
=SUBTOTAAL(1; 3)geeft bijvoorbeeld 3 als resultaat. - Een verwijzing naar een enkele cel met een reëel getal. Als cel D1 bijvoorbeeld het getal 123 bevat, retourneert de formule =SUBTOTAAL(1; D1) 123.
- Een ingebedde matrix van reële getallen (zoals {1,1; 2,2; 3,3; 4,4}). De formule
=SUBTOTAAL(6; {1; 2; 3; 4; 5})geeft bijvoorbeeld 120 terug.
De volgende omstandigheden (inclusief fouten) kunnen optreden:
- Als Functie niet-numeriek is, dan retourneert SUBTOTAAL als fout #WAARDE!
- Als Functie een niet-gehele waarde is, wordt deze door SUBTOTAAL afgekapt tot een geheel getal.
- Als Functie niet in het bereik [1, 11] of het bereik [101, 111] ligt, retourneert SUBTOTAAL als fout Ongeldig argument (Fout:502).
Aanvullende details:
- De syntaxis die in de sectie #Syntax: hierboven wordt gegeven, is uitgelijnd met die in de Functie-assistent van Calc. Het is echter mogelijk om meerdere bereiken aan SUBTOTAAL te geven door het tweede bereik door te geven als het derde argument, het derde bereik als het vierde argument, enzovoort. Dit zorgt voor interoperabiliteit met Microsoft Excel.
- Het verbergen van kolommen heeft geen invloed op de resultaten die worden geproduceerd door de functie SUBTOTAAL.
- Zie hun individuele pagina's voor meer details over elk van de elf mogelijke subtotaalfuncties.
Voorbeelden:
Een klas van 12 studenten kreeg een moduletest en hun scores worden ingevoerd in een werkblad zoals weergegeven in de onderstaande tabel.
| A | B | |
|---|---|---|
| 1 | Student | Score |
| 2 | Ann | 2 |
| 3 | Brian | 10 |
| 4 | Edward | 8 |
| 5 | James | * |
| 6 | Jeffrey | 5 |
| 7 | Linette | 10 |
| 8 | Monica | 8 |
| 9 | Ray | 3 |
| 10 | Robert | 4 |
| 11 | Tamara | 6 |
| 12 | Victoria | 7 |
| 13 | William | 9 |
De namen van de studenten staan in alfabetische volgorde in de cellen A2:A13 en hun scores in de cellen B2:B13.
Het sterretje ((*)) in cel B5 geeft aan dat James afwezig was en de test niet kon afleggen.
De volgende voorbeelden zijn gebaseerd op de gegevens in de bovenstaande tabel.
| Formule | Beschrijving | Retourneert |
|---|---|---|
| =SUBTOTAAL(2; B2:B13) |
Gebruikt de functie AANTAL van Calc om het aantal scores te tellen.
(AANTALnegeert tekenreeksen en dus wordt de asterisk in cel B5 genegeerd).
Aangezien er geen verborgen rijen in de gegevens zijn, retourneert de formule |
11 |
| =SUBTOTAAL(3; B2:B13) |
Gebruikt de functie AANTALARG van Calc om het aantal scores te tellen.
(AANTALARG bevat tekenreeksen en dus wordt de asterisk in cel B5 geteld).
Aangezien er geen verborgen rijen in de gegevens zijn, retourneert de formule |
12 |
| =SUBTOTAAL(4; B2:B13) |
Gebruikt de functie MAX van Calc om de maximale scorewaarde te bepalen.
Aangezien er geen verborgen rijen in de gegevens zijn, retourneert de formule |
10 |
| =SUBTOTAAL(5; B2:B13) |
Gebruikt de functie MIN van Calc om de minimale scorewaarde te bepalen.
Aangezien er geen verborgen rijen in de gegevens zijn, retourneert de formule |
2 |
Voor de volgende voorbeelden wordt dezelfde gegevenstabel gebruikt, maar rij 2 is verborgen (door met de rechtermuisknop op het rijnummer te klikken en te selecteren in het contextmenu).
| Formule | Beschrijving | Retourneert |
|---|---|---|
| =SUBTOTAAL(2; B2:B13) |
Gebruikt de functie AANTAL van Calc om het aantal scores te tellen. (AANTAL negeert tekenreeksen en dus wordt de asterisk in cel B5 genegeerd). In dit geval bevat SUBTOTAAL waarden in verborgen rijen. |
11 |
| =SUBTOTAAL(102; B2:B13) |
Gebruikt de functie AANTAL van Calc om het aantal scores te tellen. (AANTAL negeert tekenreeksen en dus wordt de asterisk in cel B5 genegeerd). In dit geval negeert SUBTOTAAL waarden in verborgen rijen. |
10 |
| =SUBTOTAAL(5; B2:B13) |
Gebruikt de functie MIN van Calc om de minimale scorewaarde te bepalen. In dit geval bevat SUBTOTAAL waarden in verborgen rijen. |
2 |
| =SUBTOTAAL(105; B2:B13) |
Gebruikt de functie MIN van Calc om de minimale scorewaarde te bepalen. In dit geval negeert SUBTOTAAL waarden in verborgen rijen. |
3 |
Voor de laatste voorbeelden wordt de gegevenstabel teruggezet in de oorspronkelijke staat door rij 2 zichtbaar te maken (door de rijnummers voor rij 1 en 3 te selecteren, met de rechtermuisknop op één van de geselecteerde rijnummers te klikken en te selecteren in het contextmenu). Vervolgens wordt AutoFilter toegepast door met links te klikken in het celbereik A1:B13 en vervolgens te selecteren op de Menubalk. Druk tenslotte op de pijl omlaag in de kolomkop Score, schakel het selectievakje naast het getal 10 onderaan in het dialoogvenster uit en druk op de knop . Rijen 3 and 7 zijn nu uitgefilterd.
| Formule | Beschrijving | Retourneert |
|---|---|---|
| =SUBTOTAAL(2; B2:B13) |
Gebruikt de functie AANTAL van Calc om het aantal scores te tellen.
(AANTAL negeert tekenreeksen en dus wordt de asterisk in cel B5 genegeerd).
Aangezien er geen verborgen rijen in de gegevens zijn, retourneert de formule |
9 |
| =SUBTOTAAL(3; B2:B13) |
Gebruikt de functie AANTALARG van Calc om het aantal scores te tellen.
(AANTALARG bevat tekenreeksen en dus wordt de asterisk in cel B5 geteld).
Aangezien er geen verborgen rijen in de gegevens zijn, retourneert de formule |
10 |
| =SUBTOTAAL(4; B2:B13) |
Gebruikt de functie MAX van Calc om de maximale scorewaarde te bepalen.
Aangezien er geen verborgen rijen in de gegevens zijn, retourneert de formule |
9 |
Gerelateerde LibreOffice-functies:
ODF standaard:
Gerelateerde (of gelijkwaardige) Excel-functies:
SUBTOTAL