Dokumentation/Calc Funktionen/SUMME
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende
Funktionsname:
SUMME
Kategorie:
Mathematisch
Zusammenfassung:
Berechnet die Summe aus einem Set von Dezimalzahl durch Addition.
Syntax:
SUMME(Zahl 1[; Zahl 2[; ...[; Zahl 255]]])
Rückgabewerte:
Gibt das Ergebnis der Addition aus den angegebenen Zahlen als Dezimalzahl zurück.
Argumente:
Zahl 1, Zahl 2, ... , Zahl 255 geben das Set aus Dezimalzahlen an, aus denen die Summe errechnet werden. Jedes Argument kann eine der folgenden Formen annehmen:
- Eine Dezimalzahl oder ein Ausdruck, die einer Dezimalzahl entspricht.
- Eine Referenz auf eine einzelne Zelle, die eine Dezimalzahl enthält.
- Eine Referenz auf einen Zellbereich, der Dezimalzahlen enthält (z.Bsp. A1:B9).
- Der Name eines benannten Bereiches, der Dezimalzahlen enthält.
- Der Name eines Datenbankbereiches, der Dezimalzahlen enthält.
- Ein Zahlenfeld Dezimalzahlen (z. Bsp. {1,1, 2,2, 3,3, 4,4}).
SUMME akzeptiert bis zu 255 Argumente. Trotzdem können Zellbereiche angeben werden. Dadurch können auch viel mehr als 255 Dezimalzahlen verarbeitet werden.
Die folgenden Fälle (inklusive Fehler) können auftreten:
- Falls ein Argument ein Text in Anführungszeichen ist, dann meldet SUMME einen #WERT!-Fehler oder einen invalid argument error (Fehler:502).
- Text und leere Zellen in einem Zellbereich werden ignoriert.
- Falls keine gültigen Ziffern angegeben sind, dann gibt SUMME den Wert 0 zurück.
- Falls nur ein Wert angegeben wird, dann gibt SUMME diesen Wert zurück.
Zusätzliche Informationen:
- Für das Set aus k Werten N1…Nk, implementierrt SUMME die folgende Formel:
[math]\displaystyle{ \text{SUMME}(N_{1}; N_{2}; ...; N_{k})=N_{1}+N_{2}+...+N_{k} }[/math]
- SUMME ignoriert jeden Text oder leere Zellen in einem Zellbereich. Falls Sie falsche Ergebnisse vermuten, kontrollieren Sie, ob Texte in den angegebenen Zellbereich(en) sind. Um Textinhalte hervorzuheben, nutzen Sie den Punkt ▸ .
Beispiele:
Basis Beispiele
| Formel | Beschreibung | Ergebnis |
|---|---|---|
| =SUMME(2; 3; 4) | Hier berechnet die Funktion 2 + 3 + 4 und gibt das Ergebnis zurück. | 9 |
| =SUMME(A1:A3; B1:B2) wobei die Zellen A1, A2, A3, B1 und B2 die Zahlen 2,2, 3, -5, 1,3 und -7 enthalten. | Hier berechnet die Funktion 2,2 + 3 + (-5) + 1,3 + (-7) und gibt das Ergebnis zurück. | −5,5 |
| =SUMME({2; 4; 6; 8}) | Hier berechnet die Funktion 2 + 4 + 6 + 8 und gibt das Ergebnis zurück. | 20 |
SUMME mit Bedingungen in einer Matrix-Formel
Sie haben Rechnungsdaten in eine Calc Tabelle eingegeben. Nun wollen Sie die Funktion SUMME nutzen um eine Formel zur Berechnung des Gesamtwertes aller Rechnungen im Januar 2008 zu erzeugen.
Spalte A enthält die Rechnungsdaten (im ISO 8601 Format) und Spalte B enthält die Rechnungssummen (in US-Dollar). Die Rechnungsdaten sind im Zellbereich A2:A20 und die zugehörigen Summen im Zellbereich B2:B20.
Zur Vereinfachung ist das Datum des Zinsbeginnes (01.01.2008) in Zelle E2 und der letzte Tag im Monat (01.02.2008) in Zelle E3.
Die Daten sind in folgender Tabelle zusammengestellt.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Rechnungsdatum | Rechnungssumme | |||
| 2 | 2008-01-19 | $2,032 | Startdatum | 2008-01-01 | |
| 3 | 2008-01-29 | $3,491 | Enddatum | 2008-01-31 | |
| 4 | 2008-02-20 | $1,660 | |||
| 5 | 2008-02-27 | $1,146 | Endsumme | $10,889 | |
| 6 | 2008-02-27 | $1,790 | |||
| 7 | 2008-03-18 | $3,814 | |||
| 8 | 2008-04-04 | $4,045 | |||
| 9 | 2008-04-18 | $3,060 | |||
| 10 | 2008-04-29 | $1,316 | |||
| 11 | 2008-05-06 | $575 | |||
| 12 | 2008-06-02 | $2,213 | |||
| 13 | 2008-06-03 | $1,819 | |||
| 14 | 2008-01-25 | $3,116 | |||
| 15 | 2008-01-27 | $2,095 | |||
| 16 | 2008-01-28 | $155 | |||
| 17 | 2008-02-27 | $4,433 | |||
| 18 | 2008-04-02 | $1,355 | |||
| 19 | 2008-04-25 | $2,564 | |||
| 20 | 2008-05-12 | $3,887 |
Um die Gesamtsumme der Rechnungen im Januar zu berechnen, wird die Formel in Zelle E5 als Matrix-Formel eingegeben.
=SUMME((A2:A20>=E2)*(A2:A20<=E3)*B2:B20)
Um diese Formel als Matrix-Formel anzugeben, wird mit Umschalt + Strg + Eingabe statt einfach nur mit Eingabe bestätigt, wenn die Formel in der Formel-Zeile eingegeben ist. Die Formel wird dann in der Formel-Zeile in Klammern (die Klammern werden automatisch eingefügt und können bei der Eingabe nicht manuell eingegeben werden) eingeschlossen gezeigt.
{=SUMME((A2:A20>=E2)*(A2:A20<=E3)*B2:B20)}
Das einzelne Argument, das an SUMME übergeben wird dann im Matrix-Modus ausgewertet, bevor es als Ergebnis an SUMME übergeben wird.
Die Formel nutzt die Tatsache, dass das Ergebnis eines Vergleichs 1 ist, wenn das Kriterium erfüllt ist und 0, wenn das Kriterium nicht erfüllt ist. Die Ergebnisse der individuellen Vergleiche werden als Matrix behandelt und in einer Matrizen Multiplikation verwendet, und am Ende werden die individuellen Summen als Ergebnis zurückgemeldet ($ 10,889),
Ähnliche LibreOffice Funktionen:
ODF Standard:
Betroffene (oder ähnliche) EXCEL-Funktionen:
SUM