Documentatie/Calc-functies/SOM
TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren
Functienaam:
SOM
Categorie:
Wiskundig
Samenvatting:
Berekent de som van een reeks reële getallen door ze op te tellen.
Syntaxis:
SOM(Getal 1 [; Getal 2 [; … [; Getal 255]]])
Retourneert:
Retourneert een reëel getal dat het resultaat is van het optellen van de opgegeven getallen.
Argumenten:
Getal 1, Getal 2, … , Getal 255 geven de reeks reële getallen waarvoor de som moet worden berekend. Elk argument kan één van de volgende vormen aannemen:
- Een reëel getal of een uitdrukking die resulteert in een reëel getal.
- Een verwijzing naar een enkele cel met een reëel getal.
- Een eenvoudige verwijzing naar een celbereik dat reële getallen bevat (bijvoorbeeld A1:B9).
- De naam van een benoemd bereik, bestaande uit cellen die reële getallen bevatten.
- De naam van een databasebereik, bestaande uit cellen die reële getallen bevatten.
- Een ingebedde matrix van reële getallen (bijvoorbeeld {1.1, 2.2, 3.3, 4.4}).
Merk op dat hoewel SOM tot 255 argumenten kan accepteren, elk argument een celbereik kan specificeren. Dit betekent dat het aantal verwerkte reële getallen veel meer dan 255 kan zijn.
De volgende omstandigheden (inclusief fouten) kunnen optreden:
- Als een argument een string tussen aanhalingstekens is, retourneert SOM als fout #WAARDE!
- Tekst in cellen en lege cellen worden genegeerd.
- Als er geen getallen zijn opgegeven, retourneert SOM de waarde 0.
- Als er slechts één waarde wordt opgegeven, retourneert SOM die waarde.
Aanvullende details:
- Als N1, N2, …, Nk een set van ' vertegenwoordigen 'k reële getallen doorgegeven aan de functie, de formule voor SOM is:
[math]\displaystyle{ \text{SOM}(N_{1}; N_{2}; ...; N_{k})=N_{1}+N_{2}+...+N_{k} }[/math]
- SOM negeert alle tekst in cellen of lege cellen. Als u verkeerde resultaten vermoedt, zoek dan naar tekst binnen het (de) opgegeven gegevensbereik(en). Gebruik de functie ▸ van Calc om tekstinhoud binnen een gegevensbereik te markeren.
Voorbeelden:
Basisvoorbeelden
| Formule | Beschrijving | Retourneert |
|---|---|---|
| =SOM(2; 3; 4) | Hier berekent de functie 2+3+4 en geeft het resultaat terug. | 9 |
| =SOM(A1:A3; B1:B2) waarbij de cellen A1, A2, A3, B1 en B2 respectievelijk de nummers 2,2, 3, -5, 1,3 en -7 bevatten. | Hier berekent de functie 2,2+3+(-5)+1,3+(-7). | −5,5 |
| =SOM({2; 4; 6; 8}) | Hier berekent de functie 2+4+6+8 en geeft het resultaat terug. | 20 |
SOM gebruiken met voorwaarden in een matrixformule
U hebt factuurgegevens in een Calc-blad ingevoerd en u wilt de functie SOM gebruiken om een formule te maken die de totale waarde van alle facturen met een datum in januari 2008 als resultaat geeft.
Kolom A bevat de factuurdatums (in ISO 8601-formaat) en kolom B bevat de factuurwaarden (in Amerikaanse dollars). De factuurdatums bevinden zich in het celbereik A2:A20 en de bijbehorende factuurwaarden bevinden zich in het celbereik B2:B20.
Gemakshalve wordt de datum van de eerste dag van de maand van rente (01-01-2008) ingevoerd in cel E2 en die van de laatste dag van dezelfde maand (2008-02-01) in cel E3.
De gegevens zijn georganiseerd zoals in de volgende tabel.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Factuurdatum | Factuurwaarde | |||
| 2 | 2008-01-19 | $2,032 | Begindatum | 2008-01-01 | |
| 3 | 2008-01-29 | $3,491 | Einddatum | 2008-01-31 | |
| 4 | 2008-02-20 | $1,660 | |||
| 5 | 2008-02-27 | $1,146 | Totale waarde | $10,889 | |
| 6 | 2008-02-27 | $1,790 | |||
| 7 | 2008-03-18 | $3,814 | |||
| 8 | 2008-04-04 | $4,045 | |||
| 9 | 2008-04-18 | $3,060 | |||
| 10 | 2008-04-29 | $1,316 | |||
| 11 | 2008-05-06 | $575 | |||
| 12 | 2008-06-02 | $2,213 | |||
| 13 | 2008-06-03 | $1,819 | |||
| 14 | 2008-01-25 | $3,116 | |||
| 15 | 2008-01-27 | $2,095 | |||
| 16 | 2008-01-28 | $155 | |||
| 17 | 2008-02-27 | $4,433 | |||
| 18 | 2008-04-02 | $1,355 | |||
| 19 | 2008-04-25 | $2,564 | |||
| 20 | 2008-05-12 | $3,887 |
Om de totale waarde van de facturen in januari 2008 te berekenen, wordt de volgende formule als matrixformule in cel E5 ingevoerd.
=SOM((A2:A20>=E2)*(A2:A20<=E3)*B2:B20)
Om dit als matrixformule in te voeren, drukt u op de toetsen Shift + Ctrl + Enter in plaats van gewoon op de Enter-toets te drukken wanneer u de formule in de formulebalk hebt getypt. De formule wordt dan weergegeven in de formulebalk tussen accolades (de accolades worden automatisch toegevoegd en mogen niet worden getypt bij het invoeren van de formule).
{=SOM((A2:A20>=E2)*(A2:A20<=E3)*B2:B20)}
Het enkele argument dat aan SOM wordt doorgegeven, wordt vervolgens geëvalueerd in de matrixmodus voordat het resultaat aan SOM wordt doorgegeven.
De formule gebruikt het feit dat het resultaat van een vergelijking 1 is als aan het criterium wordt voldaan en 0 als niet aan het criterium wordt voldaan. De individuele vergelijkingsresultaten worden behandeld als een matrix en gebruikt bij matrixvermenigvuldiging en aan het einde worden de individuele waarden opgeteld om het resultaat te geven ($ 10.889).
Gerelateerde LibreOffice-functies:
ODF standaard:
Gerelateerde (of gelijkwaardige) Excel-functies:
SUM