Documentación/Funciones de Calc/SUMA
TDF LibreOffice en español Document Liberation Project Blogs comunitarios Weblate Nextcloud Redmine Preguntas y respuestas Donar
Nombre de la función:
SUMA
Categoría:
Matemáticas
Resumen:
Calcula la suma de un conjunto de números reales sumándolos.
Sintaxis:
SUMA(Number 1 [; Number 2 [; … [; Number 255]]])
Devuelve:
Devuelve un número real, que es el resultado de sumar los números especificados.
Argumentos:
Número 1, Número 2, ... , Número 255 dan el conjunto de números reales para los que se va a calcular la suma. Cada argumento puede tomar una de las siguientes formas:
- Un número real, o una expresión que se evalúa como un número real.
- Una referencia a una sola celda que contiene un número real.
- Una referencia simple a un rango de celdas que contiene números reales (por ejemplo, A1:B9).
- El nombre de un rango con nombre, que comprende celdas que contienen números reales.
- El nombre de un rango de base de datos, que comprende celdas que contienen números reales.
- Una matriz en línea de números reales (por ejemplo, {1,1; 2,2; 3,3; 4,4}).
Tenga en cuenta que, aunque SUMA puede aceptar hasta 255 argumentos, cada argumento podría especificar un rango de celdas. Esto significa que la cantidad de números reales procesados podría ser mucho más de 255.
Puede encontrar las siguientes condiciones (incluidos los errores):
- Si algún argumento es una cadena entre comillas, SUMA mostrará el error #¡VALOR!.
- Se ignoran el texto y las celdas vacías.
- Si no hay números proporcionados, SUMA devolverá el valor 0.
- Si solo se proporciona un valor, SUMA devolverá ese valor.
Detalles adicionales:
- Si N1, N2, …, Nk representan un conjunto de k números reales pasados a la función, la fórmula para SUMA es:
[math]\displaystyle{ \text{SUMA (SUM)}(N_{1}; N_{2}; ...; N_{k})=N_{1}+N_{2}+...+N_{k} }[/math]
- SUMA ignora cualquier texto en celdas o celdas vacías. Si sospecha resultados erróneos, busque texto dentro de los rangos de datos proporcionados. Para resaltar contenido de texto dentro de un rango de datos, utilice la función ▸ de Calc.
Ejemplos:
Ejemplos básicos
| Fórmula | Descripción | Devuelve |
|---|---|---|
| =SUMA(2; 3; 4) | Aquí la función calcula 2+3+4 y devuelve el resultado. | 9 |
| =SUMA(A1:A3; B1:B2) donde las celdas A1, A2, A3, B1 y B2 contienen los números 2,2; 3; -5; 1,3 y -7 respectivamente. | Aquí la función calcula 2,2+3+(-5)+1,3+(-7). | −5,5 |
| =SUMA({2; 4; 6; 8}) | Aquí la función calcula 2+4+6+8 y devuelve el resultado. | 20 |
Usar SUMA con condiciones en una fórmula de matriz
Introdujo los datos de la factura en una hoja de cálculo y desea utilizar la función SUMA, para crear una fórmula que devuelva el valor total de todas las facturas con fecha de enero de 2008.
La columna A contiene las fechas de la factura (en formato ISO 8601) y la columna B contiene los valores de la factura (en dólares estadounidenses). Las fechas de factura están en el rango de celdas A2:A20 y los valores de factura correspondientes están en el rango de celdas B2:B20.
Por conveniencia se introduce la fecha del primer día del mes de interés (2008-01-01) en la celda E2, y la del último día del mismo mes (2008-02-01) se ingresa en la celda E3.
Los datos están organizados como en la siguiente tabla.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Fecha de la factura | Valor de la factura | |||
| 2 | 2008-01-19 | $2,032 | Fecha de inicio | 2008-01-01 | |
| 3 | 2008-01-29 | $3,491 | Fecha final | 2008-01-31 | |
| 4 | 2008-02-20 | $1,660 | |||
| 5 | 2008-02-27 | $1,146 | Valor total | $10,889 | |
| 6 | 2008-02-27 | $1,790 | |||
| 7 | 2008-03-18 | $3,814 | |||
| 8 | 2008-04-04 | $4,045 | |||
| 9 | 2008-04-18 | $3,060 | |||
| 10 | 2008-04-29 | $1,316 | |||
| 11 | 2008-05-06 | $575 | |||
| 12 | 2008-06-02 | $2,213 | |||
| 13 | 2008-06-03 | $1,819 | |||
| 14 | 2008-01-25 | $3,116 | |||
| 15 | 2008-01-27 | $2,095 | |||
| 16 | 2008-01-28 | $155 | |||
| 17 | 2008-02-27 | $4,433 | |||
| 18 | 2008-04-02 | $1,355 | |||
| 19 | 2008-04-25 | $2,564 | |||
| 20 | 2008-05-12 | $3,887 |
Para calcular el valor total de las facturas de enero de 2008, se introduce la siguiente fórmula en la celda E5, como una fórmula matricial.
=SUMA((A2:A20>=E2)*(A2:A20<=E3)*B2:B20)
Para introducir esto como una fórmula de matriz, presione las teclas Shift + Ctrl + Enter en lugar de simplemente presionar la tecla Enter cuando haya escrito la fórmula en la barra de fórmulas. La fórmula se mostrará en la barra de fórmulas entre llaves (las llaves se añaden automáticamente y no deben escribirse al introducir la fórmula).
{=SUMA((A2:A20>=E2)*(A2:A20<=E3)*B2:B20)}
El único argumento pasado a SUMA se evalúa luego en modo de matriz, antes de pasar el resultado a SUMA.
La fórmula utiliza el hecho de que el resultado de una comparación es 1 si se cumple el criterio y 0 si no se cumple. Los resultados de la comparación individual se tratarán como una matriz y se usarán en la multiplicación de matrices, y al final los valores individuales se sumarán para dar el resultado ($10,889).
Funciones de LibreOffice relacionadas:
Norma ODF:
Funciones equivalentes de Excel:
SUM