Documentación/Funciones de Calc/SUMAR.SI

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/SUMIF and the translation is 99% complete.
    Other languages:


    Nombre de la función:

    SUMAR.SI

    Categoría:

    Matemáticas

    Resumen:

    En su forma más simple, SUMAR.SI determina qué celdas en un rango satisfacen un criterio específico y calcula la suma de los números en esas celdas coincidentes. En su segunda forma, SUMAR.SI determina qué celdas de un rango satisfacen un criterio específico y luego calcula la suma de los números en las celdas correspondientes de un segundo rango.

    El criterio pasado a SUMAR.SI puede utilizar comodines o expresiones regulares.

    Sintaxis:

    SUMAR.SI(Range; Criterion[; SumRange])

    Devuelve:

    Devuelve un número real, que es el resultado de sumar los números de las celdas correspondientes.

    Argumentos:

    Argumento de rango

    Rango especifica las celdas que se compararán y, cuando se omite el argumento Rango de suma, las celdas que se sumarán. Rango toma generalmente una de las siguientes formas:

    • Una referencia a un rango de celdas (por ejemplo, A1:A25). Si se omite Rango de suma, entonces Rango puede utilizar el operador de concatenación de referencia (~).
    • El nombre de un rango con nombre.
    • El nombre de un rango de base de datos.

    Argumento del criterio

    Criterio es el criterio de coincidencia, o una celda que contiene ese criterio. Criterio puede tomar una de las siguientes formas:

    • Un número, como 34,5. Las fechas y los valores lógicos (VERDADERO o FALSO) se tratan como números.
    • Una expresión, como 2/3, RAIZ($D$1) o FECHA(2021; 11; 1).
    • Una cadena de texto, como "golf" o "<>10".

    SUMAR.SI busca celdas en Rango que sean iguales a Criterio, a menos que Criterio sea una cadena de texto que empiece con un comparador (>, <, >=, < =, = o <>). En el último caso, SUMAR.SI compara las celdas en Rango con el resto de la cadena de texto (interpretada como un número si es posible y como texto en caso contrario). Por ejemplo, la condición ">4,5" prueba si el contenido de cada celda es mayor que el número 4,5; la condición "<perro" prueba si el contenido de cada celda viene alfabéticamente antes del texto "perro" y la condición "< >2021-11-01" prueba si el contenido de cada celda no es igual a la fecha especificada.

    Criterion admite los siguientes comportamientos específicos:

    • La cadena "=" coincide con celdas vacías. Por ejemplo, la fórmula =SUMAR.SI(B1:B10; "="; A1:A10) devuelve la suma de todos los valores del rango A1:A10 si todas las celdas del rango B1:B10 están vacías. Tenga en cuenta que "=0" no coincide con las celdas vacías.
    • La cadena "<>" coincide con celdas que no están vacías. Por ejemplo, la fórmula =SUMAR.SI(C1:C10; "<>"; A1:A10) devuelve la suma de todos los valores en el rango A1:A10 si no hay celdas vacías en el rango C1: C10.
    • Si el valor después del comparador <> no está vacío, Criterio coincide con cualquier contenido de celda excepto ese valor, incluidas las celdas vacías.

    Argumento de Rango de suma

    Rango de suma especifica las celdas a sumar y toma una de las formas listadas para Rango. Rango de suma debería tener normalmente las mismas dimensiones que Rango; si este no es el caso, SUMAR.SI sumará un rango de celdas empezando en la primera celda en Rango de suma y teniendo las mismas dimensiones que Rango.

    Condiciones de error

    • Si se proporciona el argumento Rango de suma y se utiliza el operador de concatenación de referencia dentro de Rango, SUMAR.SI mostrará un error de lista de parámetros (Err:504).

    Detalles adicionales:

    Detalles específicos de la función SUMAR.SI

    • SUMAR.SI solo permite un criterio de coincidencia. Si necesita sumar celdas según varios criterios, use la función SUMAR.SI.CONJUNTO.
    • La coincidencia predeterminada realizada por SUMAR.SI no distingue entre mayúsculas y minúsculas. Sin embargo, se puede realizar una coincidencia que distingue entre mayúsculas y minúsculas, cuando se usa una expresión regular al incluir un modificador de modo "(?-i)" dentro de la expresión regular, como se demuestra en uno de los ejemplos a continuación.
    • El comportamiento de SUMAR.SI se ve afectado por varias configuraciones, disponibles en el cuadro de diálogo Herramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular (LibreOffice ▸ Preferencias ▸ LibreOffice Calc ▸ Calcular en macOS).
    1. Si la casilla de verificación está marcada para Los criterios de búsqueda = y <> deben aplicarse a celdas completas, entonces la condición "rojo" coincidirá solo con "rojo"; si no se marca, coincidirá con "rojo", "Fred", "red herring".
    2. Si la casilla de verificación está marcada para Habilitar comodines en fórmulas, la condición coincidirá con comodines; por ejemplo, "b?g" coincidirá con "bag", "beg", "big", "bog ", y "error".
    3. Si la casilla de verificación está marcada para Habilitar expresiones regulares en fórmulas, la condición coincidirá con expresiones regulares; por ejemplo, "r.d" coincidirá con "red", "rid" y "rod", mientras que "red.*" coincidirá con "red", "redraw" y "redden".
    4. La configuración de la casilla de verificación Sensible a mayúsculas y minúsculas no tiene ningún impacto en el funcionamiento de SUMAR.SI.


    Información general sobre las expresiones regulares de Calc

    Note pin.svg

    Nota:
    Para mayor comodidad, la información de esta subsección se repite en todas las páginas que describen funciones que manipulan expresiones regulares.

    • Una expresión regular es una cadena de caracteres que define un patrón de texto que debe coincidir. Se puede encontrar información general más detallada en la página Expresión regular de Wikipedia.
    • Las expresiones regulares se usan ampliamente en muchos dominios y hay varios procesadores de expresiones regulares disponibles. Calc utiliza el paquete de expresiones regulares de código abierto de los componentes internacionales para Unicode (ICU), consulte su documentación Regular Expressions para obtener más detalles, incluida una definición completa de la sintaxis de expresiones regulares ICU.
    • Además, el sistema de ayuda de LibreOffice proporciona una lista de expresiones regulares de alto nivel .
    • El motor de expresiones regulares de Calc es compatible con grupos de captura numerados, que permiten identificar y usar sub-intervalos dentro de una coincidencia dentro del texto de reemplazo. Los paréntesis se utilizan para agrupar componentes de una expresión regular y crear un grupo de captura numerado. Para insertar un grupo de captura en un texto de reemplazo, use la forma "$n", donde n es el número del grupo de captura.


    Información general sobre los comodines de Calc

    Los comodines son caracteres especiales que se pueden usar en cadenas de búsqueda que se pasan como argumentos a algunas funciones de Calc; también se pueden utilizar para definir criterios de búsqueda en el cuadro de diálogo Buscar y Reemplazar. El uso de comodines permite la definición de parámetros de búsqueda más avanzados con una sola cadena de búsqueda.

    Calc admite comodines o expresiones regulares como argumentos, según la configuración actual de la aplicación. De forma predeterminada, se admiten comodines en lugar de expresiones regulares.

    Para asegurarse de que los comodines sean compatibles, vaya a Herramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular y verifique si la opción Permitir comodines en las fórmulas está seleccionada. Tenga en cuenta que puede usar este cuadro de diálogo para cambiar a expresiones regulares eligiendo Permitir expresiones regulares en las fórmulas o elegir Ningún comodín ni expresión regular en las fórmulas.

    La siguiente tabla identifica los comodines que admite Calc.

    Calc wildcards
    Comodín Descripción
    ? (signo de interrogación) Coincide con cualquier carácter individual. Por ejemplo, la cadena de búsqueda "b?g" coincide con "bag" y "beg", pero no con "boog" o "mug".

    Tenga en cuenta que tampoco coincidirá con "bg", ya que "?" debe coincidir exactamente con un carácter. El comodín "?" no se corresponde con una coincidencia de cero caracteres.
    * (asterisco) Coincide con cualquier secuencia de caracteres, incluida una cadena vacía. Por ejemplo, la cadena de búsqueda "*cast" coincidirá con "cast", "forecast" y "outcast", pero no coincidirá con "forecaster" usando la configuración predeterminada de Calc.

    Si la opción Los criterios de búsqueda = y <> deben aplicarse a celdas enteras está deshabilitada en Herramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular, al usar la cadena de búsqueda "*cast", la palabra "forecaster" será una coincidencia.
    ~ (tilde) Escapa (omite) el significado especial de un signo de interrogación, asterisco o tilde que sigue inmediatamente después del carácter de tilde.

    Por ejemplo, la cadena de búsqueda "why~?" coincide con "why?", pero no coincidirá con "why" ni "why~s".

    Las comparaciones con comodines no distinguen entre mayúsculas y minúsculas, por lo tanto, "A?" coincidirá tanto con "A1" como con "a1".

    Estos comodines se admiten tanto en Calc como en Microsoft Excel. Por lo tanto, si se necesita interoperabilidad entre las dos aplicaciones, opte por trabajar con comodines en lugar de expresiones regulares. Por el contrario, si la interoperabilidad no es necesaria, considere usar expresiones regulares para capacidades de búsqueda más potentes.

    Ejemplos:

    Ejemplos básicos

    Fórmula Descripción Devuelve
    =SUMAR.SI(A1:A9; "<0") donde las celdas A1 a A9 contienen los números -1, 2, -3, 4, -5, 6, -7, 8 y -9 respectivamente. Aquí la función suma los números negativos en el rango de celdas A1:A9. −25
    =SUMAR.SI(A1:A9; F1) donde las celdas A1 a A9 contienen los números -1, 2, -3, 4, -5, 6, -7, 8 y -9 respectivamente y la celda F1 contiene la cadena ">= 0" (escrito sin las comillas dobles). Aquí la función suma los números no negativos en el rango de celdas A1:A9. 20
    =SUMAR.SI(B2:B4; "<"&F2; C2:C4) donde las celdas B2 a B4 contienen los números 7, 9 y 11 respectivamente; las celdas C2 a C4 contienen los números 4, 5 y 6 respectivamente; y la celda F2 contiene el número 10. Aquí, la función determina que los valores en las celdas B2 y B3 son menores que 10 y, por lo tanto, suma los valores en las celdas C2 y C3. 9
    =SUMAR.SI(D1:D9; "manzanas"; E1:E9) donde las celdas D1, D4, D5, D6 y D9 contienen la cadena "manzanas"; las celdas D2, D3, D7 y D8 contienen el texto "peras"; y las celdas E1 a E9 contienen los números 12, 19, 10, 27, 97, 73, 79, 71 y 40 respectivamente, que representan una cantidad de la fruta correspondiente. Aquí la función calcula la cantidad total de manzanas. 249

    Otros ejemplos

    Los ejemplos de esta subsección se basan en una pequeña base de datos de ventas de equipos deportivos, con los datos organizados como en la siguiente tabla.

    A B C D E
    1 Fecha Valor de las ventas Categoría Región Empleado/a
    2 2021-10-02 $1,508 Golf Este Hans
    3 2021-10-02 $410 Tennis Norte Kurt
    4 2021-10-02 $2,340 Navegación Sur Ute
    5 2021-10-03 $4,872 Tennis Este Brigitte
    6 2021-10-06 $3,821 Tennis Sur Fritz
    7 2021-10-06 $2,623 Tennis Este Fritz
    8 2021-10-07 $3,739 Golf Sur Fritz
    9 2021-10-08 $4,195 Golf Oeste Ute
    10 2021-10-10 $2,023 Golf Este Hans
    Fórmula Descripción Devuelve
    =SUMAR.SI(B2:B10; ">=4000") Aquí la función suma las entradas numéricas de los datos del Valor de ventas que sean mayores o iguales a $4,000. $9,067
    =SUMAR.SI(E2:E10; "ute"; B2:B10) Aquí, la función localiza las entradas para Ute en los datos de Empleado y suma las entradas numéricas correspondientes de los datos del Valor de ventas. $6,535
    =SUMAR.SI(CategoríaDatos; "golf"; B2:B10) donde el rango con nombre CategoríaDatos se ha creado para cubrir el rango de celdas C2:C10. Aquí, la función localiza las entradas para Golf en los datos de Categoría y suma las entradas numéricas correspondientes de los datos del Valor de ventas. $11,465
    =SUMAR.SI(D2:D10; F1; B2:B10) donde la celda F1 contiene el texto ">=sur" (escrito sin las comillas dobles). Aquí, la función localiza las entradas para Sur y Oeste en los datos de Región y suma las entradas numéricas correspondientes de los datos del Valor de ventas. $14,095
    =SUMAR.SI(A2:A10; FECHA(2021; 10; 2); B2:B10) Aquí, la función ubica las entradas para 2021-10-02 en la columna Fecha y suma las entradas numéricas correspondientes a los datos del Valor de ventas. $4,258
    =SUMAR.SI(A2:A10; ">="&FECHA(2021; 10; 7); B2:B10) Aquí, la función ubica las entradas con fecha de 2021-10-07 o posterior en la columna Fecha y suma las entradas numéricas correspondientes a los datos del Valor de ventas. $9,957
    =SUMAR.SI(D2:D10; "????"; B2:B10) Este ejemplo solo funcionará como se describe aquí, si los comodines están habilitados. Aquí, la función localiza las entradas de cuatro caracteres en los datos de Región (Este y Oeste) y suma las entradas numéricas correspondientes a los datos del Valor de ventas. $15,221
    =SUMAR.SI(E2:E10; "^f.*"; B2:B10) Este ejemplo solo funcionará como se describe aquí, si las expresiones regulares están habilitadas. Aquí, la función localiza las entradas en los datos de Empleado que empiezan por la letra "f" o "F" (Fritz) y suma las entradas numéricas correspondientes a los datos del Valor de ventas. $10,183
    =SUMAR.SI(E2:E10; "(?-i)ute"; B2:B10) Este ejemplo solo funcionará como se describe aquí, si las expresiones regulares están habilitadas. El modificador de modo "(?-i)" dentro de la expresión regular, cambia a una coincidencia que distingue entre mayúsculas y minúsculas, por lo que no se encuentran entradas en los datos de "Empleado". Compare esto con el segundo ejemplo de esta tabla. $0

    Funciones de LibreOffice relacionadas:

    CONTAR.SI

    SUMA

    SUMAR.SI.CONJUNTO

    Norma ODF:

    Sección 6.16.62, parte 2

    Funciones equivalentes de Excel:

    SUMIF